ExcelマクロVBA練習問題解答 | 練習問題24(再帰呼出し)回答 | Excelマクロ練習問題集、エクセルVBAの学習教材



最終更新日:2015-10-22

練習問題24(再帰呼出し)回答

練習問題24の回答ページです、


問題

・以下の表の全組み合わせを作成して下さい。
 サンプルデータでは、組み合わせの数は、8*3*6*5=720通りです。

・各項目はカンマ(,)で区切って下さい。
・出力先は、新規シートを追加し、
 1行目に見出しとして"組み合わせ文字"と入れ、
 2行目より出力して下さい。

※組み合わせ文字
  項目A1,項目B1,項目C1,項目D1
  項目A1,項目B1,項目C1,項目D2
  ・・・
  項目A1,項目B1,項目C2,項目D1
  項目A1,項目B1,項目C2,項目D2
  ・・・
  項目A1,項目B2,項目C1,項目D1
  ・・・
  このように出力します。

  A    B    C    D
分類A 分類B 分類C 分類D
項目A1 項目B1 項目C1 項目D1
項目A2 項目B2 項目C2 項目D2
項目A3 項目B3 項目C3 項目D3
項目A4   項目C4 項目D4
項目A5   項目C5 項目D5
項目A6   項目C6  
項目A7      
項目A8      

※上記表の全体選択し、コピー(Ctrl+C)の後、エクセルのシートのA1セルに貼り付け(Ctrl+V)してください。


では、お考えください。

すぐに回答を見ずに、必ず自力で書けるとこまででも良いので書きましょう。


・・
・・・
・・・・
・・・・・

当サイトのコンテンツ

ExcelマクロVBA入門
マクロの記録で覚えるVBA

ここで、じっくり勉強して下さい。



・・
・・・
・・・・
・・・・・



では回答です。

Sub sample()
  Dim ary() As String
  Dim ws1 As Worksheet
  Dim ws2 As Worksheet
  Application.ScreenUpdating = False
  Set ws1 = ActiveSheet
  Set ws2 = Worksheets.Add
  ws2.Range("A1") = "組み合わせ文字"
  With ws1
    ReDim ary(1 To .Cells(1, Columns.Count).End(xlToLeft).Column)
    Call sample_sub(ws1, ws2, ary, 1)
  End With
  Application.ScreenUpdating = True
End Sub
Private Sub sample_sub(ByVal ws1 As Worksheet, ByVal ws2 As Worksheet, _
            ByRef ary() As String, ByVal n As Integer)
  Dim i As Integer
  With ws2
    For i = 2 To ws1.Cells(ws1.Rows.Count, n).End(xlUp).Row
      ary(n) = ws1.Cells(i, n)
      If n >= UBound(ary) Then
        .Cells(.Cells(.Rows.Count, 1).End(xlUp).Row + 1, 1) = Join(ary, ",")
      Else
        Call sample_sub(ws1, ws2, ary, n + 1) 'ここで自分自身を呼び出しています。
      End If
    Next
  End With
End Sub


かなり難しかったかもしれません。

ちなみに、(横の)項目数が固定の4つであれば、再帰呼出しも配列も使わずに、

以下のように書く事も可能です。

Sub sample()
  Dim ws1 As Worksheet
  Dim ws2 As Worksheet
  Dim i1 As Long, i2 As Long, i3 As Long, i4 As Long
  Dim j As Long
  Application.ScreenUpdating = False
  Set ws1 = ActiveSheet
  Set ws2 = Worksheets.Add
  ws2.Range("A1") = "組み合わせ文字"
  j = 2
  With ws1
    For i1 = 2 To .Cells(.Rows.Count, 1).End(xlUp).Row
      For i2 = 2 To .Cells(.Rows.Count, 2).End(xlUp).Row
        For i3 = 2 To .Cells(.Rows.Count, 3).End(xlUp).Row
          For i4 = 2 To .Cells(.Rows.Count, 4).End(xlUp).Row
            ws2.Cells(j, 1) = .Cells(i1, 1) & "," & _
                      .Cells(i2, 2) & "," & _
                      .Cells(i3, 3) & "," & _
                      .Cells(i4, 4)
            j = j + 1
          Next
        Next
      Next
    Next
  End With
  Application.ScreenUpdating = True
End Sub


この場合、項目数分のループが必要で、項目数不定では対応ができません。

先の再帰呼出しを使ったプログラムでは、項目数がいくつでも自動対応されます。

再帰呼出しは、頻繁に使うものではありませんが、通常のループ処理では困難な場合があります。

また、配列も必須テクニックです、合わせて、しかっりと習得して下さい。

以下を参考にして下さい。

マクロVBA技術解説.再帰呼出しについて(再帰プロシージャー)

マクロVBA入門.第111回.静的配列
マクロVBA入門.第112回.動的配列(ReDim)
マクロVBA入門.第113回.配列に関連する関数
マクロVBA入門.第114回.セル範囲⇔配列
マクロVBA技術解説.配列の使い方について





同じテーマ「ExcelマクロVBA練習問題解答」の記事

練習問題25(各種VBA関数)回答
練習問題26(全シート処理とハイパーリンク)回答
練習問題27(データ分割し別ブック保存)回答
練習問題28(シートを別ブックにして値のみにする)回答
練習問題29(ロット引き当て)回答
第19回.総合練習問題1回答
第26回.総合練習問題2回答

新着記事 ・・・新着記事一覧を見る

SUMIFの間違いによるパフォーマンスの低下について|エクセル関数超技(6月17日)
条件式のいろいろな書き方:TrueとFalseの判定とは|ExcelマクロVBA技術解説(6月15日)
空白セルを正しく判定する方法2|ExcelマクロVBA技術解説(5月6日)
フルパスをディレクトリ、ファイル名、拡張子に分ける|ExcelマクロVBA技術解説(4月15日)
テキストボックスの各種イベント|Excelユーザーフォーム入門(4月9日)
フォルダ(サブフォルダも全て)削除する、Optionでファイルのみ削除|ExcelマクロVBAサンプル集(4月4日)
最後の空白(や指定文字)以降の文字を取り出す|エクセル関数超技(3月26日)
先頭の数値、最後の数値を取り出す|エクセル関数超技(3月26日)
Excelファイルを開かずにシート名をチェック|ExcelマクロVBAサンプル集(3月23日)
数式の参照しているセルを取得する|ExcelマクロVBAサンプル集(3月18日)

アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|ExcelマクロVBA入門
2.RangeとCellsの使い方|ExcelマクロVBA入門
3.徹底解説(VLOOKUP,MATCH,INDEX,OFFSET)|エクセル関数超技
4.Range以外の指定方法(Cells,Rows,Columns)|ExcelマクロVBA入門
5.変数とデータ型(Dim)|ExcelマクロVBA入門
6.セルのコピー&値の貼り付け(PasteSpecial)|ExcelマクロVBA入門
7.セルの参照範囲を可変にする(OFFSET,COUNTA,MATCH)|エクセル関数超技
8.ひらがな⇔カタカナの変換|エクセル基本操作
9.定数と型宣言文字(Const)|ExcelマクロVBA入門
10.CSVの読み込み方法|ExcelマクロVBAサンプル集



  • >
  • >
  • >
  • 練習問題24(再帰呼出し)回答

  • このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


    記述には細心の注意をしたつもりですが、
    間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
    なお、掲載のVBAコードは自己責任で使ってください。万一データ破損等の損害が発生しても責任は負いません。

    ↑ PAGE TOP