ExcelマクロVBA練習問題解答 | 練習問題28(シートを別ブックにして値のみにする)回答 | Excelマクロ練習問題集、エクセルVBAの学習教材



最終更新日:2015-10-22

練習問題28(シートを別ブックにして値のみにする)回答

練習問題28の回答ページです、


問題

アクティブブックにはシートが複数(Sheet1,Sheet2,Sheet3)あります、

Sheet1だけを別ブックにして、計算式を抜き(値だけにする)にしてから保存して下さい。

作成したブックの保存先は、アクティブブックと同一フォルダとし、ブック名はシート名と同一にして下さい。


※Excelのファイルバージョンは、
  2007以降ならxlsx、2003以前ならxlsで作成して下さい。


では、お考えください。

すぐに回答を見ずに、必ず自力で書けるとこまででも良いので書きましょう。


・・
・・・
・・・・
・・・・・

当サイトのコンテンツ

ExcelマクロVBA入門

ここで、じっくり勉強して下さい。



・・
・・・
・・・・
・・・・・



では、回答です。

Sub 練習問題28()
  Dim wb1 As Workbook, ws1 As Worksheet
  Dim wb2 As Workbook, ws2 As Worksheet
  Set wb1 = ActiveWorkbook
  Set ws1 = wb1.Worksheets("Sheet1")
  ws1.Copy
  Set wb2 = ActiveWorkbook
  Set ws2 = wb2.ActiveSheet
  ws2.UsedRange.Value = ws2.UsedRange.Value
  If CInt(Application.Version) < 12 Then
    wb2.SaveAs ThisWorkbook.Path & "\" & ws2.Name & ".xls"
  Else
    wb2.SaveAs ThisWorkbook.Path & "\" & ws2.Name & ".xlsx"
  End If
  wb2.Close
End Sub


今回の肝は、

ws2.UsedRange.Value = ws2.UsedRange.Value

これで、当該シートの数式は消えて、値のみになります。

ここで、

ws2.Cells.Value = ws2.Cells.Value

でも良さそうですが、

Excel2007以降の形式では、多くのPCでメモリ不足が出てしまいます。

つまり、100万行*1万列以上の範囲指定は、ちょっときびしいですね。

また、

Cells.Copy
Cells.PasteSpecial Paste:=xlPasteValues


これでも良いのですが、.Copyではクリップボードが使用されますし、

何より、値だけにするなら、先の方がスマートだと思います。


また、若干余談になりますが・・・

オブジェクト変数(Workbook,Worksheet)の使い方は、人により好みで良いですが、

ここでは、全てオブジェクト変数に入れてから処理するようにしてみました。

Withを使った方が見やすいと感じる人も多いかと思います。

ただし、オブジェクト変数に入れることが基本だと覚えて置いて下さい。

例えば、
Worksheets("Sheet1").
このピリオドを入力しても、候補表示されませんが、
Set ws1 = wb1.Worksheets("Sheet1")
ws1.
このピリオドを入力した時点では候補表示されるようになります。
つまり、オブジェクト型が確定されている事になります。





同じテーマ「ExcelマクロVBA練習問題解答」の記事

練習問題29(ロット引き当て)回答
第19回.総合練習問題1回答
第26回.総合練習問題2回答
第30回.総合練習問題3回答
第36回.総合練習問題4回答
第43回.総合練習問題5回答
第50回.総合練習問題6回答

新着記事 ・・・新着記事一覧を見る

空白セルを正しく判定する方法2|ExcelマクロVBA技術解説(5月6日)
フルパスをディレクトリ、ファイル名、拡張子に分ける|ExcelマクロVBA技術解説(4月15日)
テキストボックスの各種イベント|Excelユーザーフォーム入門(4月9日)
フォルダ(サブフォルダも全て)削除する、Optionでファイルのみ削除|ExcelマクロVBAサンプル集(4月4日)
最後の空白(や指定文字)以降の文字を取り出す|エクセル関数超技(3月26日)
先頭の数値、最後の数値を取り出す|エクセル関数超技(3月26日)
Excelファイルを開かずにシート名をチェック|ExcelマクロVBAサンプル集(3月23日)
数式の参照しているセルを取得する|ExcelマクロVBAサンプル集(3月18日)
CSVの読み込み方法(改の改)|ExcelマクロVBAサンプル集(3月17日)
変数とプロシージャーの命名について|ExcelマクロVBA技術解説(2月12日)

アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|ExcelマクロVBA入門
2.ひらがな⇔カタカナの変換|エクセル基本操作
3.RangeとCellsの使い方|ExcelマクロVBA入門
4.Range以外の指定方法(Cells,Rows,Columns)|ExcelマクロVBA入門
5.徹底解説(VLOOKUP,MATCH,INDEX,OFFSET)|エクセル関数超技
6.変数とデータ型(Dim)|ExcelマクロVBA入門
7.セルの参照範囲を可変にする(OFFSET,COUNTA,MATCH)|エクセル関数超技
8.セルのコピー&値の貼り付け(PasteSpecial)|ExcelマクロVBA入門
9.CSVの読み込み方法|ExcelマクロVBAサンプル集
10.定数と型宣言文字(Const)|ExcelマクロVBA入門



  • >
  • >
  • >
  • 練習問題28(シートを別ブックにして値のみにする)回答

  • このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


    記述には細心の注意をしたつもりですが、
    間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
    なお、掲載のVBAコードは自己責任で使ってください。万一データ破損等の損害が発生しても責任は負いません。




    ↑ PAGE TOP