ExcelマクロVBA入門 | 第35回.セルの書式(罫線,Border) | Excelマクロの基礎と応用、エクセルVBAの入門・初級・初心者向け解説



最終更新日:2013-05-15

第35回.セルの書式(罫線,Border)


マクロで罫線を引く事はた度々あります。


そして、マクロの記録を使用して作成したマクロの最悪のケースとなっています。



以下、2010で、A1セル〜B5セルに格子線を引いた時のマクロの記録です。

Sub Macro1()
  Range("A1:B5").Select
  Selection.Borders(xlDiagonalDown).LineStyle = xlNone
  Selection.Borders(xlDiagonalUp).LineStyle = xlNone
  With Selection.Borders(xlEdgeLeft)
    .LineStyle = xlContinuous
    .ColorIndex = xlAutomatic
    .TintAndShade = 0
    .Weight = xlThin
  End With
  With Selection.Borders(xlEdgeTop)
    .LineStyle = xlContinuous
    .ColorIndex = xlAutomatic
    .TintAndShade = 0
    .Weight = xlThin
  End With
  With Selection.Borders(xlEdgeBottom)
    .LineStyle = xlContinuous
    .ColorIndex = xlAutomatic
    .TintAndShade = 0
    .Weight = xlThin
  End With
  With Selection.Borders(xlEdgeRight)
    .LineStyle = xlContinuous
    .ColorIndex = xlAutomatic
    .TintAndShade = 0
    .Weight = xlThin
  End With
  With Selection.Borders(xlInsideVertical)
    .LineStyle = xlContinuous
    .ColorIndex = xlAutomatic
    .TintAndShade = 0
    .Weight = xlThin
  End With
  With Selection.Borders(xlInsideHorizontal)
    .LineStyle = xlContinuous
    .ColorIndex = xlAutomatic
    .TintAndShade = 0
    .Weight = xlThin
  End With
End Sub


うんざりするほど長いマクロです。


しかし、これは、以下のマクロで済んでしまいます

Sub Macro2()
Range("A1:B5").Borders.LineStyle = xlContinuous
End Sub


マクロを多少なりとも扱うなら、少なくとも、マクロの記録で作成された、


前出のマクロをそのまま使うような事だけはしないで下さい。



セル(Rangeオブジェクト)の罫線は、Bordersコレクションになります。


Bordersコレクションは、Bordersオブシェクトの集まりです。

(コレクションについての詳細は後々)


Range.Bordersでセルの罫線を扱います。


マクロでの指定


Range.Borders.プロパティ = 設定値


または、


Range.Borders(index).プロパティ = 設定値


Indexには、以下を指定します。

xlDiagonalDown 範囲内の各セルの左上隅から右下への罫線
xlDiagonalUp 範囲内の各セルの左下隅から右上への罫線
xlEdgeBottom 範囲内の下側の罫線
xlEdgeLeft 範囲内の左端の罫線
xlEdgeRight 範囲内の右端の罫線
xlEdgeTop 範囲内の上側の罫線
xlInsideHorizontal 範囲外の罫線を除く、範囲内のすべてのセルの水平罫線
xlInsideVertical 範囲外の罫線を除く、範囲内のすべてのセルの垂直罫線


Range.Borders.プロパティ


とした場合は、


xlEdgeBottom、xlEdgeLeft、xlEdgeRight、xlEdgeTop、xlInsideHorizontal、xlInsideVertical


に全て、同一の設定をしたことになります。


Bordersには、以下のプロパティがあります。

プロパティ プロパティの説明 プロパティの設定値 設定値の説明
LineStyle 罫線の種類 xlNone または xlLineStyleNone なし
xlContinuous 実線
xlDash 破線
xlDashDot 一点鎖線
xlDashDotDot ニ点鎖線
xlDot 点線
xlDouble 2 本線
xlLineStyleNone 線なし
xlSlantDashDot 斜破線
Color 罫線の色 RGB値を表す長整数
ColorIndex 罫線の色 現在のカラー パレットのインデックス
Weight 罫線の太さ xlHairline 細線 (最も細い罫線)
xlMedium 普通
xlThick 太線 (最も太い罫線)
xlThin 極細
TintAndShade 罫線の色色明るく、または暗く 2007以降


プロパティの設定値には、組み合わせの制限があります


それは、ワークシートの「セルの書式設定」で指定可能な組み合わせしか出来ないからです。


当然ですよね。


ですから、


マクロは、エクセルの基本操作を十分に理解していないと書けないのです



使用例.

Range("セル範囲").Borders(xlEdgeLeft).LineStyle = xlContinuous
Range("セル範囲").Borders(xlEdgeRight).LineStyle = xlContinuous
Range("セル範囲").Borders(xlEdgeLeft).Weight = xlThick
Range("セル範囲").Borders(xlEdgeRight).Weight = xlThick


上記では、セル範囲の左右に、太い実践を引いています。

  
 

Range.BorderAroundメソッド


罫線を扱う方法が、もう一つあります。


それが、Range.BorderAroundメソッドです。


これは、外枠に対して一度に罫線を引きます。


Range.BorderAround LineStyle, Weight, {ColorIndex | Color | ThemeColor}


{ColorIndex | Color | ThemeColor}は、いずれか1つのみ指定可能。


指定方法は、前記のプロパティと同様ですが、


こちらは、メソッド(オブジェクトに動作を与える)なので、


LineStyle, Weight, ColorIndex, Color, ThemeColor


これらは、引数になります。

 名前付き引数で指定します。

 
使用例.

Range("セル範囲").BorderAround LineStyle:=xlContinuous, Weight:=xlMedium, Color:=vbRed


上記では、セル範囲の外枠に、実線、太さ普通、赤色の罫線を引いています。






同じテーマ「ExcelマクロVBA入門」の記事

第36回.総合練習問題4
第37回.ブック・シートの指定
第38回.セルに計算式を設定(Formula)
第39回.セルのクリア(Clear)
第40回.セルのコピー・カット&ペースト(Copy,Cut,Paste)
第41回.セルのコピー&値の貼り付け(PasteSpecial)
第42回.セルをコピーするとは

新着記事 ・・・新着記事一覧を見る

空白セルを正しく判定する方法2|ExcelマクロVBA技術解説(5月6日)
フルパスをディレクトリ、ファイル名、拡張子に分ける|ExcelマクロVBA技術解説(4月15日)
テキストボックスの各種イベント|Excelユーザーフォーム入門(4月9日)
フォルダ(サブフォルダも全て)削除する、Optionでファイルのみ削除|ExcelマクロVBAサンプル集(4月4日)
最後の空白(や指定文字)以降の文字を取り出す|エクセル関数超技(3月26日)
先頭の数値、最後の数値を取り出す|エクセル関数超技(3月26日)
Excelファイルを開かずにシート名をチェック|ExcelマクロVBAサンプル集(3月23日)
数式の参照しているセルを取得する|ExcelマクロVBAサンプル集(3月18日)
CSVの読み込み方法(改の改)|ExcelマクロVBAサンプル集(3月17日)
変数とプロシージャーの命名について|ExcelマクロVBA技術解説(2月12日)

アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|ExcelマクロVBA入門
2.ひらがな⇔カタカナの変換|エクセル基本操作
3.RangeとCellsの使い方|ExcelマクロVBA入門
4.Range以外の指定方法(Cells,Rows,Columns)|ExcelマクロVBA入門
5.徹底解説(VLOOKUP,MATCH,INDEX,OFFSET)|エクセル関数超技
6.変数とデータ型(Dim)|ExcelマクロVBA入門
7.セルの参照範囲を可変にする(OFFSET,COUNTA,MATCH)|エクセル関数超技
8.セルのコピー&値の貼り付け(PasteSpecial)|ExcelマクロVBA入門
9.CSVの読み込み方法|ExcelマクロVBAサンプル集
10.定数と型宣言文字(Const)|ExcelマクロVBA入門



  • >
  • >
  • >
  • セルの書式(罫線,Border)

  • このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


    記述には細心の注意をしたつもりですが、
    間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
    なお、掲載のVBAコードは自己責任で使ってください。万一データ破損等の損害が発生しても責任は負いません。




    ↑ PAGE TOP