Excelマクロの記録で覚えるVBA | 第13回.罫線を引く | Excelマクロの自動記録を使って、エクセルVBAの初心者向け入門解説



最終更新日:2013-02-18

第13回.罫線を引く


前回までで、文字、数値を入れ、色も塗りました。


この辺で、罫線の引き方をやりましょう。



100マス計算の罫線を、一度全て消してください。


ではマクロの記録です。


1.マクロの記録

2.A1〜K11を選択

3.罫線の格子(外側、内側を細線)

4.記録終了


作成されたマクロは、


Sub Macro6()
'
' Macro6 Macro
'

'
  Range("A1:K11").Select
  Selection.Borders(xlDiagonalDown).LineStyle = xlNone
  Selection.Borders(xlDiagonalUp).LineStyle = xlNone
  With Selection.Borders(xlEdgeLeft)
    .LineStyle = xlContinuous
    .ColorIndex = 0
    .TintAndShade = 0
    .Weight = xlThin
  End With
  With Selection.Borders(xlEdgeTop)
    .LineStyle = xlContinuous
    .ColorIndex = 0
    .TintAndShade = 0
    .Weight = xlThin
  End With
  With Selection.Borders(xlEdgeBottom)
    .LineStyle = xlContinuous
    .ColorIndex = 0
    .TintAndShade = 0
    .Weight = xlThin
  End With
  With Selection.Borders(xlEdgeRight)
    .LineStyle = xlContinuous
    .ColorIndex = 0
    .TintAndShade = 0
    .Weight = xlThin
  End With
  With Selection.Borders(xlInsideVertical)
    .LineStyle = xlContinuous
    .ColorIndex = 0
    .TintAndShade = 0
    .Weight = xlThin
  End With
  With Selection.Borders(xlInsideHorizontal)
    .LineStyle = xlContinuous
    .ColorIndex = 0
    .TintAndShade = 0
    .Weight = xlThin
  End With
  Range("A1").Select
End Sub


驚くほどの長さですね、少し笑えます。


Borders

これで罫線を指定します。

()内の引数で、罫線の位置を指定し、

.LineStyle等で線の種類、太さ、色等を指定します。


Selection.Borders(xlDiagonalDown).LineStyle = xlNone
Selection.Borders(xlDiagonalUp).LineStyle = xlNone
これは、斜め線の指定です。

.LineStyle

は、線の種類です。

実践、点線等になります。

xlNone

は、罫線を引かない指定なので、不要です。


.LineStyle = xlContinuous
線の種類です。

実践、点線等になります。

xlContinuous
は実践になります。

指定できる種類は後述します。


.ColorIndex = 0
は、罫線の色指定です。

セルに色を塗る時と同じ指定です。

今回は、不要です。


.TintAndShade = 0
は、2007以降の機能です。

罫線の色指定で、2003までに無い色使いの場合になります。

今回は、不要です。


.Weight = xlThin
線の太さの指定です。

xlThin
は、細線になります。

指定できる種類は後述します。


そして、

Selection

Range("A1:K11")

で置き換えて、整理すると、


以下になります。


Sub Macro6()
  With Range("A1:K11")
    With .Borders(xlEdgeLeft)
      .LineStyle = xlContinuous
      .Weight = xlThin
    End With
    With .Borders(xlEdgeTop)
      .LineStyle = xlContinuous
      .Weight = xlThin
    End With
    With .Borders(xlEdgeBottom)
      .LineStyle = xlContinuous
      .Weight = xlThin
    End With
    With .Borders(xlEdgeRight)
      .LineStyle = xlContinuous
      .Weight = xlThin
    End With
    With .Borders(xlInsideVertical)
      .LineStyle = xlContinuous
      .Weight = xlThin
    End With
    With .Borders(xlInsideHorizontal)
      .LineStyle = xlContinuous
      .Weight = xlThin
    End With
  End With
End Sub


Withが二重になっています。


With Range("A1:K11")
  With .Borders(xlEdgeLeft)
下のWithは、

つまり、

Range("A1:K11").Borders(xlEdgeLeft)
ということになります。


実は、

.Weight

は、省略時が、

xlThin
なので、不要なのです。


そこで、さらに整理すると、

Sub Macro6()
  With Range("A1:K11")
    .Borders(xlDiagonalDown).LineStyle = xlNone
    .Borders(xlDiagonalUp).LineStyle = xlNone
    .Borders(xlEdgeLeft).LineStyle = xlContinuous
    .Borders(xlEdgeTop).LineStyle = xlContinuous
    .Borders(xlEdgeBottom).LineStyle = xlContinuous
    .Borders(xlEdgeRight).LineStyle = xlContinuous
    .Borders(xlInsideVertical).LineStyle = xlContinuous
    .Borders(xlInsideHorizontal).LineStyle = xlContinuous
  End With
End Sub


このようになります。


大分すっきりしましたね。


でも、実はもっと簡単に指定できるのです。


Sub Macro9()
  Range("A1:K11").Borders.LineStyle = xlContinuous
End Sub


これだけで格子の罫線が引けてしまうんです。


最初のマクロの記録が、なんだかなーってなりますよね。


Borders

に、引数を指定しないと、外側・内側の指定になるのです。


しかし、これは、格子で細線だからなんですよ。


いろいろな罫線を引くには、それなりに指定が必要ですので、


当初のマクロと同等の指定が必要になります。


しかし、最もよく使う、細線の格子が、この1行でできるのはありがだいです。



罫線の種類


xlContinuous : 実線
xlDash : 破線
xlDashDot : 一点鎖線
xlDashDotDot : 二点鎖線
xlDot : 点線
xlDouble : 二重線
xlSlantDashDot : 斜め斜線
xlLineStyleNone : 無し・・・xlNoneでもよい。


線の太さ


xlHairline : 極細
xlThin : 細
xlMedium : 中
xlThick : 太


罫線の種類と、太さを組み合わせて指定します。


全ての組み合わせが有効な訳ではありません。


セルの書式設定の罫線で指定できる組み合わせになります。






同じテーマ「Excelマクロの記録で覚えるVBA」の記事

第14回.行列を入れ替えて貼り付け
第15回.いろいろな消去
第16回.行の挿入・削除
第17回.並べ替え
第18回.オートフィルタ
第19回.オートフィルタ2
第20回.ジャンプのセル選択

新着記事 ・・・新着記事一覧を見る

Excelファイルを開かずにシート名をチェック|ExcelマクロVBAサンプル集(3月23日)
数式の参照しているセルを取得する|ExcelマクロVBAサンプル集(3月18日)
CSVの読み込み方法(改の改)|ExcelマクロVBAサンプル集(3月17日)
変数とプロシージャーの命名について|ExcelマクロVBA技術解説(2月12日)
ファイルの一覧取得・削除(File)|Google Apps Script入門(1月24日)
フォルダの一覧取得・作成・削除(Folder)|Google Apps Script入門(1月24日)
フォルダとファイルを扱う(DriveApp)|Google Apps Script入門(1月24日)
スプレッドシートが非常に遅い、高速化するには|Google Apps Script入門(1月17日)
画像のトリミング(PictureFormat,Crop)|ExcelマクロVBAサンプル集(12月27日)
シート保護|Google Apps Script入門(12月24日)

アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|ExcelマクロVBA入門
2.RangeとCellsの使い方|ExcelマクロVBA入門
3.徹底解説(VLOOKUP,MATCH,INDEX,OFFSET)|エクセル関数超技
4.Range以外の指定方法(Cells,Rows,Columns)|ExcelマクロVBA入門
5.セルの参照範囲を可変にする(OFFSET,COUNTA,MATCH)|エクセル関数超技
6.セルのコピー&値の貼り付け(PasteSpecial)|ExcelマクロVBA入門
7.変数とデータ型(Dim)|ExcelマクロVBA入門
8.ひらがな⇔カタカナの変換|エクセル基本操作
9.CSVの読み込み方法|ExcelマクロVBAサンプル集
10.VBAのFindメソッドの使い方には注意が必要です|ExcelマクロVBA技術解説




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
なお、掲載のVBAコードは自己責任で使ってください。万一データ破損等の損害が発生しても責任は負いません。

↑ PAGE TOP