Excelユーザーフォーム入門 | 第10回.標準モジュールとフォーム間のデータ受け渡しU | Excelマクロのユーザーフォームの基礎、エクセルVBAの入門解説



最終更新日:2013-06-04

第10回.標準モジュールとフォーム間のデータ受け渡しU


1.シートのセルを使う
2.標準モジュールのグローバル変数を使う
3.標準モジュールからフォームのコントロールを操作する
4.Subプロシージャーの引数を使う
5.Functionプロシージャーの戻り値を使う。

2.3.を解説しました。


では、いよいよ4.5.を解説しましょう。

ここが、本題です。


4.Subプロシージャーの引数を使う

まずは、フォームモジュールに以下を作成します。

Option Explicit
Private ActiveRow As Long
Public Sub doModal(ByVal argRow As Long)
  ActiveRow = argRow
  With Worksheets("顧客マスタ")
    Me.txtコード.Text = .Cells(ActiveRow, 1)
    Me.txt漢字名称.Text = .Cells(ActiveRow, 2)
    Me.txtカナ名称.Text = .Cells(ActiveRow, 3)
  End With
  Me.Show
End Sub

プロシージャー名のdoModalのModalは、

フォーム表示(モーダル)方法の名称よりとっていますが、

モーダル・モードレスについては、先々で解説します。

そして、

標準モジュールでは、

Sub FormShow()
  Call frmSample.doModal(ActiveCell.Row)
End Sub

要点としては、

doModalの引数で値を受け取り、処理後に自身を表示(Me.Show)している所です。


5.Functionプロシージャーの戻り値を使う

「OK」ボタンを押されたか、「閉じる」ボタンを押されたかを、標準モジュールで判断してみましょう。

フォームモジュールを以下に変更します。

Option Explicit

Private ActiveRow As Long
Private blnOk As Boolean

Public Function doModal(ByVal argRow As Long) As Boolean
  ActiveRow = argRow
  With Worksheets("顧客マスタ")
    Me.txtコード.Text = .Cells(ActiveRow, 1)
    Me.txt漢字名称.Text = .Cells(ActiveRow, 2)
    Me.txtカナ名称.Text = .Cells(ActiveRow, 3)
  End With
  blnOk = False
  Me.Show
  doModal = blnOk
End Function

Private Sub btnOk_Click()
  Dim lastRow As Long
  With Worksheets("顧客マスタ")
    lastRow = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
    .Cells(lastRow, 1) = Me.txtコード.Text
    .Cells(lastRow, 2) = Me.txt漢字名称.Text
    .Cells(lastRow, 3) = Me.txtカナ名称.Text
  End With
  blnOk = True
  Unload Me
End Sub

Private Sub btnCancel_Click()
  blnOk = False
  Unload Me
End Sub

そして、標準モジュールで、

Sub FormShow()
  If frmSample.doModal(ActiveCell.Row) = True Then
    MsgBox "「OK」が押されました。"
  Else
    MsgBox "「閉じる」が押されました。"
  End If
End Sub

最初のSubだったdoModalFunctionに変更しただけですね、

それに伴い、ボタンの判断をする為に、

Private blnOk As Boolean

この変数を使うようにしました。

ただ、ちょっと気を付けてもらいたいのは、

Unload Me

この後でフォームのコントロールを参照するのは、本当は問題があります。

上記では問題なく動きますが、やはり、あまり良くありません。

そこで、

Unload Me この代わりに、

Me.Hide (Hideはフォームを非表示にしてShowの次のステートメントに進みます)として、

標準モジュールに戻ってから、Unloadした方が良いでしょう。

出来上がりとしては、

Option Explicit

Private ActiveRow As Long
Private blnOk As Boolean

Public Function doModal(ByVal argRow As Long) As Boolean
  ActiveRow = argRow
  With Worksheets("顧客マスタ")
    Me.txtコード.Text = .Cells(ActiveRow, 1)
    Me.txt漢字名称.Text = .Cells(ActiveRow, 2)
    Me.txtカナ名称.Text = .Cells(ActiveRow, 3)
  End With
  blnOk = False
  Me.Show
  doModal = blnOk
End Function

Private Sub btnOk_Click()
  Dim lastRow As Long
  With Worksheets("顧客マスタ")
    lastRow = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
    .Cells(lastRow, 1) = Me.txtコード.Text
    .Cells(lastRow, 2) = Me.txt漢字名称.Text
    .Cells(lastRow, 3) = Me.txtカナ名称.Text
  End With
  blnOk = True
  Me.Hide
End Sub

Private Sub btnCancel_Click()
  blnOk = False
  Me.Hide
End Sub

Sub FormShow()
  If frmSample.doModal(ActiveCell.Row) = True Then
    MsgBox "「OK」が押されました。"
  Else
    MsgBox "「閉じる」が押されました。"
  End If
  Unload frmSample
End Sub


以上の方法で、どれが良いと言う事もありませんが、

これらの方法を組み合わせて、いろいろな処理を実現します。

ただし、4.5.の方法でまずは作成する事をお勧めします。

どうしてもうまく行かない場合に、2.3.の方法を考えましょう。

プログラムの品質を考えた時、

グローバル変数を使ったり、

他のオブジェクトのコントロールを操作するのは

あまり良い方法とは言えませんので。





同じテーマ「Excelユーザーフォーム入門」の記事

第11回.コンボボックス(ComboBox)の追加
第12回.リストボックス(ListBox)の追加
第13回.チェックボックス(CheckBox)の追加
第14回.オプションボタン(OptionButton)の追加
第15回.ここまでの整理
第16回.アクティブコントロールに色を付ける
第17回.Enterキーで次のコントロールに移動する

新着記事 ・・・新着記事一覧を見る

空白セルを正しく判定する方法2|ExcelマクロVBA技術解説(5月6日)
フルパスをディレクトリ、ファイル名、拡張子に分ける|ExcelマクロVBA技術解説(4月15日)
テキストボックスの各種イベント|Excelユーザーフォーム入門(4月9日)
フォルダ(サブフォルダも全て)削除する、Optionでファイルのみ削除|ExcelマクロVBAサンプル集(4月4日)
最後の空白(や指定文字)以降の文字を取り出す|エクセル関数超技(3月26日)
先頭の数値、最後の数値を取り出す|エクセル関数超技(3月26日)
Excelファイルを開かずにシート名をチェック|ExcelマクロVBAサンプル集(3月23日)
数式の参照しているセルを取得する|ExcelマクロVBAサンプル集(3月18日)
CSVの読み込み方法(改の改)|ExcelマクロVBAサンプル集(3月17日)
変数とプロシージャーの命名について|ExcelマクロVBA技術解説(2月12日)

アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|ExcelマクロVBA入門
2.ひらがな⇔カタカナの変換|エクセル基本操作
3.RangeとCellsの使い方|ExcelマクロVBA入門
4.Range以外の指定方法(Cells,Rows,Columns)|ExcelマクロVBA入門
5.徹底解説(VLOOKUP,MATCH,INDEX,OFFSET)|エクセル関数超技
6.変数とデータ型(Dim)|ExcelマクロVBA入門
7.セルの参照範囲を可変にする(OFFSET,COUNTA,MATCH)|エクセル関数超技
8.セルのコピー&値の貼り付け(PasteSpecial)|ExcelマクロVBA入門
9.CSVの読み込み方法|ExcelマクロVBAサンプル集
10.定数と型宣言文字(Const)|ExcelマクロVBA入門



  • >
  • >
  • >
  • 標準モジュールとフォーム間のデータ受け渡しU

  • このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


    記述には細心の注意をしたつもりですが、
    間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
    なお、掲載のVBAコードは自己責任で使ってください。万一データ破損等の損害が発生しても責任は負いません。




    ↑ PAGE TOP