ユーザーフォーム入門
ここまでの整理と全VBA

Excelマクロのユーザーフォームの基礎、エクセルVBAの入門解説
公開日:2013年5月以前 最終更新日:2019-12-17

第15回.ここまでの整理と全VBA


ユーザーフォーム入門として基礎から解説します。
一旦、ここまでの復習を兼ねて全VBAの整理をします。


ついでに、シートの当該行のダブルクリックでフォームが開くようにします。

ワークシート

Worksheets("顧客マスタ")

VBA マクロ ユーザーフォーム

シートモジュール

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
  If frmSample.doModal(ActiveCell.Row) = True Then
    MsgBox "「OK」が押されました。"
  Else
    MsgBox "「閉じる」が押されました。"
  End If
  Cancel = True
End Sub

ダブルクリック時のイベントプロシージャーを追加しました。

標準モジュール

Sub FormShow()
  If frmSample.doModal(ActiveCell.Row) = True Then
    MsgBox "「OK」が押されました。"
  Else
    MsgBox "「閉じる」が押されました。"
  End If
  Unload frmSample
End Sub

この「FormShow」を実行ボタンに登録します。

フォーム

frmSample

マクロ VBA サンプル画像

フォームモジュール

Option Explicit

Private ActiveRow As Long
Private blnOk As Boolean

Public Function doModal(ByVal argRow As Long) As Boolean
  Dim i As Integer
  ActiveRow = argRow
  With Worksheets("顧客マスタ")
    If .Cells(ActiveRow, 1) = "休止" Then
      Me.chk休止.Value = True
    Else
      Me.chk休止.Value = False
    End If
    Me.txtコード.Text = .Cells(ActiveRow, 2)
    Me.txt漢字名称.Text = .Cells(ActiveRow, 3)
    Me.txtカナ名称.Text = .Cells(ActiveRow, 4)
    For i = 0 To Me.cmb区分.ListCount - 1
      If Me.cmb区分.List(i) = .Cells(ActiveRow, 5) Then
        Me.cmb区分.ListIndex = i
        Exit For
      End If
    Next
    For i = 0 To Me.lst都道府県.ListCount - 1
      If Me.lst都道府県.List(i) = .Cells(ActiveRow, 6) Then
        Me.lst都道府県.Selected(i) = True
        Exit For
      End If
    Next
    If .Cells(ActiveRow, 8) = "個人" Then
      Me.opt個人.Value = True
    Else
      Me.opt企業.Value = True
    End If
  End With
  blnOk = False
  Me.Show
  doModal = blnOk
End Function

Private Sub UserForm_Initialize()
  Me.cmb区分.AddItem "Aランク"
  Me.cmb区分.AddItem "Bランク"
  Me.cmb区分.AddItem "Cランク"
  With Me.lst都道府県
    .ColumnCount = 2
    .ColumnWidths = "30;80"
    .ColumnHeads = True
    .RowSource = Worksheets("都道府県マスタ").Range("A2:B48").Address(External:=True)
  End With
  Me.chk休止.Value = False
  Me.opt企業.Value = True
End Sub

Private Sub btnOk_Click()
  With Worksheets("顧客マスタ")
    If Me.chk休止.Value = True Then
      .Cells(ActiveRow, 1) = "休止"
    Else
      .Cells(ActiveRow, 1) = ""
    End If
    .Cells(ActiveRow, 2) = Me.txtコード.Text
    .Cells(ActiveRow, 3) = Me.txt漢字名称.Text
    .Cells(ActiveRow, 4) = Me.txtカナ名称.Text
    .Cells(ActiveRow, 5) = Me.cmb区分.Text
    .Cells(ActiveRow, 6) = Me.lst都道府県.List(Me.lst都道府県.ListIndex, 0)
    .Cells(ActiveRow, 7) = Me.lst都道府県.List(Me.lst都道府県.ListIndex, 1)
    Select Case True
      Case Me.opt企業.Value
        .Cells(ActiveRow, 8) = "企業"
      Case Me.opt個人.Value
        .Cells(ActiveRow, 8) = "個人"
      Case Else
        .Cells(ActiveRow, 8) = ""
    End Select
  End With
  blnOk = True
  Me.Hide
End Sub

Private Sub btnCancel_Click()
  blnOk = False
  Me.Hide
End Sub


以上が、ここまでの完成形です。
入力内容のチェックやエラー処理は、ほとんど入れてありません。
全体の動作を確認する為に不要なコードは入れないようにしています。
まずは、全体の動きを理解することが肝要です。
次回以降は、各種イベントを使用して、いろいろな便利機能を組み込んでいきます。




同じテーマ「ユーザーフォーム入門」の記事

第12回.リストボックス(ListBox)の追加
第13回.チェックボックス(CheckBox)の追加
第14回.オプションボタン(OptionButton)の追加
第15回.ここまでの整理と全VBA
第16回.アクティブコントロールに色を付ける
第17回.Enterキーで次のコントロールに移動する
第18回.2段階のコンボボックス
第19回.数値専用のテキストボックス
第20回.テキストボックスの各種イベント
第21回.ユーザーフォームの各種イベント
第22回.コントロールの動的作成


新着記事NEW ・・・新着記事一覧を見る

ExcelマクロVBA入門目次|エクセルの神髄(2024-03-20)
VBA10大躓きポイント(初心者が躓きやすいポイント)|VBA技術解説(2024-03-05)
テンキーのスクリーンキーボード作成|ユーザーフォーム入門(2024-02-26)
無効な前方参照か、コンパイルされていない種類への参照です。|エクセル雑感(2024-02-17)
初級脱出10問パック|VBA練習問題(2024-01-24)
累計を求める数式あれこれ|エクセル関数応用(2024-01-22)
複数の文字列を検索して置換するSUBSTITUTE|エクセル入門(2024-01-03)
いくつかの数式の計算中にリソース不足になりました。|エクセル雑感(2023-12-28)
VBAでクリップボードへ文字列を送信・取得する3つの方法|VBA技術解説(2023-12-07)
難しい数式とは何か?|エクセル雑感(2023-12-07)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.RangeとCellsの使い方|VBA入門
3.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
4.繰り返し処理(For Next)|VBA入門
5.変数宣言のDimとデータ型|VBA入門
6.ブックを閉じる・保存(Close,Save,SaveAs)|VBA入門
7.並べ替え(Sort)|VBA入門
8.条件分岐(IF)|VBA入門
9.セルのクリア(Clear,ClearContents)|VBA入門
10.マクロとは?VBAとは?VBAでできること|VBA入門




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。



このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
本文下部へ