Excelユーザーフォーム入門 | 第16回.アクティブコントロールに色を付ける | Excelマクロのユーザーフォームの基礎、エクセルVBAの入門解説



最終更新日:2013-02-18

第16回.アクティブコントロールに色を付ける


フォーム内のどこにカーソルがあるか分かりづらい場合があります。

そこで、アクティブなコントロールのバックカラーを変えたり、

対応するラベルのフォントを変更したりして、アクティブなコントロールを解り易くします。


以下はサンプルコードになります。

まずは、モジュールレベル変数の定義と、

各コントロールのEnterイベントで呼び出すプロシージャーの作成です。

Private lastControl As Control
Private lastColor As Long

・・・他の記述は省略します

Private Sub setColor(ctl As Control)
  If Not lastControl Is Nothing Then
    lastControl.BackColor = lastColor
  End If
  lastColor = ctl.BackColor
  Set lastControl = ctl
  ctl.BackColor = RGB(255, 153, 204)
End Sub

続いて、各コントロールのEnterイベントです。

Private Sub txtコード_Enter()
  Call setColor(Me.txtコード)
End Sub
Private Sub txt漢字名称_Enter()
  Call setColor(Me.txt漢字名称)
End Sub
Private Sub txtカナ名称_Enter()
  Call setColor(Me.txtカナ名称)
End Sub
Private Sub cmb区分_Enter()
  Call setColor(Me.cmb区分)
End Sub
Private Sub lst都道府県_Enter()
  Call setColor(Me.lst都道府県)
End Sub
Private Sub opt企業_Enter()
  Call setColor(Me.opt企業)
End Sub
Private Sub opt個人_Enter()
  Call setColor(Me.opt個人)
End Sub
Private Sub chk休止_Enter()
  Call setColor(Me.chk休止)
End Sub
Private Sub btnOk_Enter()
  Call setColor(Me.btnOk)
End Sub
Private Sub btnCancel_Enter()
  Call setColor(Me.btnCancel)
End Sub


以上で完成です。

やり方はいろいろありますが、基本は同じです。

Enterイベントで色を変える、同時に、前コントロールの色を戻します。

色の戻しは、Exitイベントでやっても良いでしょう。

Private Sub txtコード_Enter()
  txtコード.BackColor = RGB(255, 153, 204)
End Sub
Private Sub txtコード_Exit(ByVal Cancel As MSForms.ReturnBoolean)
  txtコード.BackColor = vbWhite
End Sub

このような書き方になります。※対象のコントロール全てについて記述します。

全てのコントロールが対象ではなく、一部のコントロールでのみ色を変える場合は、

後のExitイベントを使った方が制御しやすいかもしれません。


では続いて、

対応するラベルのフォントを太字にしてみましょう

これは対応するラベルがどのラベルになるかが分からないとできません。

Tagプロパティに対応するラベル名を入れておく等の方法もありますが、

今回は、命名方法を以下にしてあります。

ラベル:lbl〇〇〇
テキストボックス:txt〇〇〇
コンボボックス:cmb〇〇〇
リストボックス:lst〇〇〇

従って、先頭のプリフィックスを変更すれば、対応するラベル名にすることが出来ます。

Private Sub setColor(ByRef ctl As Control)
  If Not lastControl Is Nothing Then
    lastControl.BackColor = lastColor
    Call setLabel(lastControl, False)
  End If
  Set lastControl = ctl
  lastColor = ctl.BackColor
  ctl.BackColor = RGB(255, 153, 204)
  Call setLabel(ctl, True)
End Sub
Private Sub setLabel(ByVal ctl As Control, ByVal blnBold As Boolean)
  On Error Resume Next
  Controls("lbl" & Mid(ctl.Name, 4)).Font.Bold = blnBold
End Sub

チェックボックスやオプションボタン等は、通常ラベルを付けませんし、

他のコントロールでも、必ずラベルを付けるとは限りませんので、

対応するラベルが無い時の対応として、

On Error Resume Next

これを入れてあります。


このような処理は、書き方もいろいろありますし、

工夫次第で、よりユーザーにやさしいフォームを作成する事が可能です。

いろいろ工夫しながら挑戦してみて下さい。





同じテーマ「Excelユーザーフォーム入門」の記事

第17回.Enterキーで次のコントロールに移動する
第18回.2段階コンボボックス
第19回.テキストボックス数値編集
第20回.テキストボックスの各種イベント
第1回.ユーザーフォームを挿入
第2回.フォームのプロパティ
第3回.コントロールの追加(コマンドボタン)

新着記事 ・・・新着記事一覧を見る

大量VlookupをVBAで高速に処理する方法について|ExcelマクロVBA技術解説(12月12日)
オセロを作りながらマクロVBAを学ぼう|ExcelマクロVBAサンプル集(11月26日)
ScreenUpdating=False時にエラー停止後にシートが固まったら|ExcelマクロVBA技術解説(11月21日)
データクレンジングと名寄せ|ExcelマクロVBA技術解説(10月20日)
SUMIFの間違いによるパフォーマンスの低下について|エクセル関数超技(6月17日)
条件式のいろいろな書き方:TrueとFalseの判定とは|ExcelマクロVBA技術解説(6月15日)
空白セルを正しく判定する方法2|ExcelマクロVBA技術解説(5月6日)
フルパスをディレクトリ、ファイル名、拡張子に分ける|ExcelマクロVBA技術解説(4月15日)
テキストボックスの各種イベント|Excelユーザーフォーム入門(4月9日)
フォルダ(サブフォルダも全て)削除する、Optionでファイルのみ削除|ExcelマクロVBAサンプル集(4月4日)

アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|ExcelマクロVBA入門
2.RangeとCellsの使い分け方|ExcelマクロVBA入門
3.変数とデータ型(Dim)|ExcelマクロVBA入門
4.Range以外の指定方法(Cells,Rows,Columns)|ExcelマクロVBA入門
5.セルのコピー&値の貼り付け(PasteSpecial)|ExcelマクロVBA入門
6.定数と型宣言文字(Const)|ExcelマクロVBA入門
7.マクロって何?VBAって何?|ExcelマクロVBA入門
8.CSVの読み込み方法|ExcelマクロVBAサンプル集
9.徹底解説(VLOOKUP,MATCH,INDEX,OFFSET)|エクセル関数超技
10.ひらがな⇔カタカナの変換|エクセル基本操作



  • >
  • >
  • >
  • アクティブコントロールに色を付ける

  • このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


    記述には細心の注意をしたつもりですが、
    間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
    なお、掲載のVBAコードは自己責任で使ってください。万一データ破損等の損害が発生しても責任は負いません。

    ↑ PAGE TOP