ExcelマクロVBA技術解説 | Dictionary(ディクショナリー)連想配列の使い方について | Excelマクロの問題点と解決策、エクセルVBAの技術的解説



最終更新日:2013-05-30

Dictionary(ディクショナリー)連想配列の使い方について

エクセル掲示板で、

Dictionaryオブジェクトについて簡単な使用例を上げて解説して欲しいです。検討お願いしますm(_ _)m

と頂いたので、分かる範囲内で解説します。

実際は、私はあまり使う事はありません。


なぜなら、配列処理で可能ですので、特にDictionaryを使う必要がないからです。

しかし、便利な時もあるので、一応は押さえておきたい機能ではあります。

Dictionary(ディクショナリー)は名前の通り、辞書機能です。

この辞書には、重複は許されません。

また、この辞書には、キーとデータの2つが存在します。

そこで、最も簡単な例として、重複を除く場合の使い方で解説します。


このような表があったとして、

KEY(A列)で重複をなくして、他のシートにコピーする場合を想定しました。

Sub sample1()
  Dim myDic As New Dictionary
  Dim i As Long
  
  With Worksheets("Sheet1")
    For i = 2 To .Cells(.Rows.Count, 1).End(xlUp).Row
      myDic(.Cells(i, 1).Value) = .Cells(i, 2).Value
    Next i
  End With
  With Worksheets("Sheet2")
    For i = 0 To myDic.Count - 1
      .Cells(i + 1, 1).Value = myDic.Keys(i)
      .Cells(i + 1, 2).Value = myDic.Items(i)
    Next i
  End With
  Set myDic = Nothing
End Sub


まず、

Dim myDic As New Dictionary

これを使う為には、

「ツール」→「参照設定」で、

Microsoft Scripting Runtime

これを参照設定して下さい。

参照設定しない場合は、

Dim myDic As Object
Set myDic = CreateObject("Scripting.Dictionary")

として下さい。

コードの説明は、さほど必要がないようにも思えます。

太字部分だけになります。

myDic(.Cells(i, 1).Value) = .Cells(i, 2).Value

これで、Dictionaryに、キーが.Cells(i, 1).Valueで、値が.Cells(i, 2).Value

が追加されます。

既に同一キーが存在していた場合は、値が上書きされます。

myDic.Keys(i)

これで、Dictionaryから指定位置のキーを取り出します。

myDic.Items(i)

これで、Dictionaryから指定位置のデータを取り出します。

myDic(.Cells(i, 1).Value) = .Cells(i, 2).Value

これは上書きになっていますが、上書きしたくない場合もあります。

その場合は、

Sub sample2()
  Dim myDic As New Dictionary
  Dim i As Long

  With Worksheets("Sheet1")
    For i = 2 To .Cells(.Rows.Count, 1).End(xlUp).Row
      If Not myDic.Exists(.Cells(i, 1).Value) Then
        myDic.Add .Cells(i, 1).Value, .Cells(i, 2).Value
      End If

    Next i
  End With
  With Worksheets("Sheet2")
    For i = 0 To myDic.Count - 1
      .Cells(i + 1, 1).Value = myDic.Keys(i)
      .Cells(i + 1, 2).Value = myDic.Items(i)
    Next i
  End With
  Set myDic = Nothing
End Sub


sample1との大きな違いは、太字の部分だけです。

しかし、ここの違いが大きいのです。

myDic.Add .Cells(i, 1).Value, .Cells(i, 2).Value

これは、Dictionaryに、キーとデータを追加しますが、

この書き方の場合、既に存在している場合は、エラーとなってしまいます。

On Err で回避しているコードを見かける事がありますが、On Errは最終手段として使って下さい。

myDic.Exists(.Cells(i, 1).Value)

これで、キーがDictionaryに存在しているかの判定をしています。

存在している場合に、Trueが帰ってきます。

後は、sample1と全く同様になります。


では、最期に、sample1とsample2の合わせ技で、

A列のキーの存在個数をカウントするプログラムを掲載します。

解読してみて、Dictionaryの使い方を覚えて下さい。

Sub sample3()
  Dim myDic As New Dictionary
  Dim i As Long

  With Worksheets("Sheet1")
    For i = 2 To .Cells(.Rows.Count, 1).End(xlUp).Row
      If myDic.Exists(.Cells(i, 1).Value) Then
        myDic(.Cells(i, 1).Value) = myDic(.Cells(i, 1).Value) + 1
      Else
        myDic.Add .Cells(i, 1).Value, 1
      End If
    Next i
  End With
  With Worksheets("Sheet2")
    For i = 0 To myDic.Count - 1
      .Cells(i + 1, 1).Value = myDic.Keys(i)
      .Cells(i + 1, 2).Value = myDic.Items(i)
    Next i
  End With
  Set myDic = Nothing
End Sub



掲示板で、質問されましたので、追記です。

myDic(.Cells(i, 1).Value)

この、.Valueは省略しないで下さい。

Dictionaryの引数は、オブジェクトを受け入れるので、

.Valueを省略してしまうと、セルである、Rangeオブジェクトが格納されます。

セルの値ではなく、Rangeオブジェクトなので、

値が同じでも、セル位置が違えば、違うオブジェクトとして格納されます。




同じテーマ「ExcelマクロVBA技術解説」の記事

Dictionary(ディクショナリー)のパフォーマンスについて
VBAでのInternetExplorer自動操作
VBAでのSQLの基礎(SQL:Structured Query Language)
VBAで正規表現を利用する(RegExp)
VBAでメール送信する(CDO:Microsoft Collaboration Data Objects)
VBAでのOutlook自動操作
ADO(ActiveX Data Objects)の使い方の要点

新着記事 ・・・新着記事一覧を見る

データクレンジングと名寄せ|ExcelマクロVBA技術解説(10月20日)
SUMIFの間違いによるパフォーマンスの低下について|エクセル関数超技(6月17日)
条件式のいろいろな書き方:TrueとFalseの判定とは|ExcelマクロVBA技術解説(6月15日)
空白セルを正しく判定する方法2|ExcelマクロVBA技術解説(5月6日)
フルパスをディレクトリ、ファイル名、拡張子に分ける|ExcelマクロVBA技術解説(4月15日)
テキストボックスの各種イベント|Excelユーザーフォーム入門(4月9日)
フォルダ(サブフォルダも全て)削除する、Optionでファイルのみ削除|ExcelマクロVBAサンプル集(4月4日)
最後の空白(や指定文字)以降の文字を取り出す|エクセル関数超技(3月26日)
先頭の数値、最後の数値を取り出す|エクセル関数超技(3月26日)
Excelファイルを開かずにシート名をチェック|ExcelマクロVBAサンプル集(3月23日)

アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|ExcelマクロVBA入門
2.RangeとCellsの使い方|ExcelマクロVBA入門
3.Range以外の指定方法(Cells,Rows,Columns)|ExcelマクロVBA入門
4.変数とデータ型(Dim)|ExcelマクロVBA入門
5.セルのコピー&値の貼り付け(PasteSpecial)|ExcelマクロVBA入門
6.定数と型宣言文字(Const)|ExcelマクロVBA入門
7.徹底解説(VLOOKUP,MATCH,INDEX,OFFSET)|エクセル関数超技
8.マクロって何?VBAって何?|ExcelマクロVBA入門
9.CSVの読み込み方法|ExcelマクロVBAサンプル集
10.ひらがな⇔カタカナの変換|エクセル基本操作



  • >
  • >
  • >
  • Dictionary(ディクショナリー)連想配列の使い方について

  • このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


    記述には細心の注意をしたつもりですが、
    間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
    なお、掲載のVBAコードは自己責任で使ってください。万一データ破損等の損害が発生しても責任は負いません。

    ↑ PAGE TOP