VBAサンプル集
時刻になったら音を鳴らして知らせる(OnTime)

ExcelマクロVBAの実用サンプル、エクセルVBA集と解説
公開日:2013年5月以前 最終更新日:2020-05-12

時刻になったら音を鳴らして知らせる(OnTime)


エクセル作業に夢中になって、時間を忘れて大慌てって事ありませんか。
えっ、無い、そうですか、ではさようなら・・・
あると言う人は以下のプログラムをどうぞ。


作成するシート

まず、以下ようなシートを作ります。

VBA マクロ 時刻になったら音を鳴らす Beep

標準モジュールのVBAコード

標準モジュールに以下を追加します。

Sub 時刻で起動()
  On Error Resume Next
  With ThisWorkbook.ActiveSheet
    Dim i As Long
    For i = 2 To .Cells(.Rows.Count, 1).End(xlUp).Row
      If .Cells(i, 1) <> "" And .Cells(i, 2) <> "" Then
        If .Cells(i, 2) >= Now And _
          .Cells(i, 3) <> "済" Then
          Application.OnTime .Cells(i, 2), "メッセージ表示"
          Exit For
        End If
      End If
    Next
  End With
End Sub

Private Sub メッセージ表示()
  Dim i As Long, j As Long
  On Error Resume Next
  With ThisWorkbook.ActiveSheet
    For i = 2 To .Cells(.Rows.Count, 1).End(xlUp).Row
      If .Cells(i, 1) <> "" And .Cells(i, 2) <> "" Then
        If .Cells(i, 2) <= Now And _
          .Cells(i, 3) <> "済" Then
          .Cells(i, 3) = "済"
          Beep
          MsgBox (.Cells(i, 1))
          Exit For
        End If
      End If
    Next
    Call 時刻で起動
  End With
End Sub

VBAコードの解説

Application.OnTime

Application.OnTime 起動時刻, "起動するマクロ"
これで、「起動時刻」になると、「起動するマクロ」が、起動されます。
詳しくは、以下を参照してください。
第120回.OnTimeメソッド|VBA入門
・OnTimeメソッドの構文 ・OnTimeメソッドの使用例 ・OnTimeメソッドの実践例

Beep

コンピューターのスピーカーからビープ音を鳴らします。
警告音の周波数と継続時間は、ハードウェアおよびシステム ソフトウェアに基づいており、コンピューターによって異なります。

沢山鳴らしたい時は、ダミーのカウントアップ等でループさせて、
一定時間をおいて、Beepを実行すれば何回も続けて鳴らす事ができます。
または、Application.Waitで待たせる方法でも良いです。
(現在の高速なPCでは、間隔をあけずに連続Beepでは1回しか鳴りません。)

この間に、他のブックを扱っていても問題はありません。
その為のプログラムですからね。
ただし、数式バーで入力中の時は、その状態が解除されるまで、この処理は待たされます。
セルへの入力終了直後に起動されることになります。

タイマー処理の注意点

このようなマクロを裏で動かしている場合は、
作業中のブックは普段以上に、こまめに保存して下さい。
このプログラムの異常で作業中のブックを道連れに死ぬことのないように、
上記VBAでは、念の為、On Error Resume Nextを入れています。

上記では、指定時刻にしていますが、
指定時間後にしたければ、
Now + Timevalue("1:0:0")、これなら1時間後になります。
これを、Application.OnTimeに指定すれば良いです。

ビープ音を変更したい場合

ビープ音が鳴らないと言う場合もあるかもしれません。
以前に私が使っていたノートPCもなりませんでした。
サウンドの設定等を見ても問題なし、コマンドプロンプトで「echo ^G」(^GはCtrl+G)では音がする。
もちろん原因はあるので解決すれば良いのですが、
不明な場合は、以下のようにAPIを使って音をならします。

Option Explicit

Public Declare PtrSafe Function Beep Lib "kernel32" (ByVal dwFreq As Long, ByVal dwDuration As Long) As Long
   
Sub 時刻で起動()
  On Error Resume Next
  With ThisWorkbook.ActiveSheet
    Dim i As Long
    For i = 2 To .Cells(.Rows.Count, 1).End(xlUp).Row
      If .Cells(i, 1) <> "" And .Cells(i, 2) <> "" Then
        If .Cells(i, 2) >= Now And _
          .Cells(i, 3) <> "済" Then
          Application.OnTime .Cells(i, 2), "メッセージ表示"
          Exit For
        End If
      End If
    Next
  End With
End Sub

Private Sub メッセージ表示()
  Dim i As Long, j As Long
  On Error Resume Next
  With ThisWorkbook.ActiveSheet
    For i = 2 To .Cells(.Rows.Count, 1).End(xlUp).Row
      If .Cells(i, 1) <> "" And .Cells(i, 2) <> "" Then
        If .Cells(i, 2) <= Now And _
          .Cells(i, 3) <> "済" Then
          .Cells(i, 3) = "済"
          CallBeep 'ここを変更
          MsgBox (.Cells(i, 1))
          Exit For
        End If
      End If
    Next
    Call 時刻で起動
  End With
End Sub

Private Sub CallBeep()
  Call Beep(500, 1000) 'API
End Sub

これで鳴るようになります。
これでも鳴らなかったら、サウンドが壊れています。

API Beep

Beep(音の周波数, 鳴らすミリ秒)

第1引数が音の周波数、第2引数が鳴らすミリ秒です。
この周波数と、時間、間隔をいろいろ組み合わせると、簡単な音楽も作れ無いことはありません。
Beep音で音楽(Beep,Sleep)
時々検索されるので、Beep音で音楽を演奏してみましょう。プログラムはほぼAPIをCALLするだけです。まずは、シートです。こんな感じです。ドレミの周波数は結構適当なので、詳しい方は自分で調整して下さい。

時刻になったら音を鳴らして知らせる最後に

本来は、時間を意識して作業はするべきでしょうね。
この作業は、何時間で、何時まで、と決めてやるのが正しいでしょう。
でもね、人間だから気が付いたら時間が過ぎてたって事もありますからね。
特に集中していると、時間を忘れちゃいますよね。

タイマー関係の処理として以下も参考にしてください。
VBAでのタイマー処理(SetTimer,OnTime)
・Application.OnTime メソッド ・WindowsAPI:SetTimer関数 ・最後に



同じテーマ「マクロVBAサンプル集」の記事

ユーザー定義関数でフリガナを取得する(GetPhonetic)
ユーザー定義関数でハイパーリンクのURLを取得(Hyperlink)
カラーのコード取得(256RGB⇔16進変換)
時刻になったら音を鳴らして知らせる(OnTime)
指定文字、指定数式でジャンプ機能(Union)
「値の貼り付け」をショートカットに登録(OnKey)
「セルの結合」をショートカットに登録(OnKey)
半角カナのみ全角カナに変換する
計算式の元となる数値定数を消去する(Precedents)
Beep音で音楽(Beep,Sleep)
日付の検索(配列の使用)


新着記事NEW ・・・新着記事一覧を見る

ExcelマクロVBA入門目次|エクセルの神髄(2024-03-20)
VBA10大躓きポイント(初心者が躓きやすいポイント)|VBA技術解説(2024-03-05)
テンキーのスクリーンキーボード作成|ユーザーフォーム入門(2024-02-26)
無効な前方参照か、コンパイルされていない種類への参照です。|エクセル雑感(2024-02-17)
初級脱出10問パック|VBA練習問題(2024-01-24)
累計を求める数式あれこれ|エクセル関数応用(2024-01-22)
複数の文字列を検索して置換するSUBSTITUTE|エクセル入門(2024-01-03)
いくつかの数式の計算中にリソース不足になりました。|エクセル雑感(2023-12-28)
VBAでクリップボードへ文字列を送信・取得する3つの方法|VBA技術解説(2023-12-07)
難しい数式とは何か?|エクセル雑感(2023-12-07)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.RangeとCellsの使い方|VBA入門
3.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
4.繰り返し処理(For Next)|VBA入門
5.変数宣言のDimとデータ型|VBA入門
6.ブックを閉じる・保存(Close,Save,SaveAs)|VBA入門
7.並べ替え(Sort)|VBA入門
8.条件分岐(IF)|VBA入門
9.セルのクリア(Clear,ClearContents)|VBA入門
10.マクロとは?VBAとは?VBAでできること|VBA入門




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。



このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
本文下部へ