VBAサンプル集
半角カナのみ全角カナに変換する

ExcelマクロVBAの実用サンプル、エクセルVBA集と解説
公開日:2013年5月以前 最終更新日:2013-06-10

半角カナのみ全角カナに変換する


半角カナのみ全角カナに変換します。
ネットを探してみたところ、あるにはあるのですが、どうも中途半端。
直ぐに使えて、汎用性のあるプログラムが見つからなかったので、作ってみました。


ではプログラムです。

Sub sample()
  Dim objRange As Range
  For Each objRange In ActiveSheet.UsedRange
    Call 半角カナto全角カナ(objRange)
  Next
End Sub


Private Sub 半角カナto全角カナ(ByRef objRange As Range)
  Dim strIn As String  '元の文字列
  Dim strOut As String '変換後の文字列
  Dim strKana As String '変換対象のカナ

  Dim i As Integer
  
  '数式、文字列以外は対象外
  If objRange.HasFormula Or _
    VarType(objRange.Value) <> vbString Then
    Exit Sub
  End If
  
  strIn = objRange.Value
  strOut = ""
  strKana = ""
  For i = 1 To Len(strIn)
    '161(。)~223(゚)を半角カナと判定
    'カナ記号(。「」、・)を除く場合は、166(ヲ)~とする
    If Asc(Mid(strIn, i, 1)) >= 161 And _
      Asc(Mid(strIn, i, 1)) <= 223 Then
      strKana = strKana & Mid(strIn, i, 1) 'カナを変数に追加
    Else '半角カナ以外
      If strKana <> "" Then
        strOut = strOut & StrConv(strKana, vbWide) '全角変換
        strKana = ""
      End If
      strOut = strOut & Mid(strIn, i, 1)
    End If
  Next
  If strKana <> "" Then
    strOut = strOut & StrConv(strKana, vbWide) '全角変換
  End If
  objRange.Value = strOut 'セルのValueへ戻す
End Sub


Sub sample()
は、起動するマクロになります。
この部分で、セル範囲を変更することで、いろいろと対応出来るはずです。


Private Sub 半角カナto全角カナ(ByRef objRange As Range)
実際に、全角変換しているモジュールです。
引数をRangeオブジェクトにしています。
Value値だけでは、その後の判定ができません。

objRange.HasFormula
数式の設定されているセルの判定です。

VarType(objRange.Value) <> vbString
値が、文字列かどうかの判定です。

Asc(Mid(strIn, i, 1)) >= 161 And Asc(Mid(strIn, i, 1)) <= 223
半角カナ文字の判定です、カナ記号も含めています。

プログラム中のコメントにもありますが、
カナ記号(。「」、・)を除く場合は、166(ヲ)~として下さい。

StrConv(strKana, vbWide)
全角変換です。
この、vbWideを変更することで、ひらがなに変換したりすることができます。

これなら文句ないでしょう。
きっちり、半角カナのみ変換しています。

数式の判定と、連続しているカナ文字をまとめて変換していますので。
ネットで探してみたところ、みかけたものには、数式の判定をしていない為に、
実行したら、計算式が全部なくなってしまったりするものがあります。
また、あまり無いとは思いますが、
カナ文字の判定に不備があり、「パ゚」などの場合は、2つ目の「゚」が変換されなかったりしています。
このプログラムなら、コピペして、起動のプロシージャーだけ直せば、どこでも使用可能です。



同じテーマ「マクロVBAサンプル集」の記事

指定文字、指定数式でジャンプ機能(Union)
「値の貼り付け」をショートカットに登録(OnKey)
「セルの結合」をショートカットに登録(OnKey)
半角カナのみ全角カナに変換する
計算式の元となる数値定数を消去する(Precedents)
Beep音で音楽(Beep,Sleep)
日付の検索(配列の使用)
ストップウォッチ(1/100秒)(Timer)
ストップウォッチ改(1/100秒)(Timer)
重複の無いユニークなデータ作成
WEBデータの取得方法


新着記事NEW ・・・新着記事一覧を見る

VBA10大躓きポイント(初心者が躓きやすいポイント)|VBA技術解説(2024-03-05)
テンキーのスクリーンキーボード作成|ユーザーフォーム入門(2024-02-26)
無効な前方参照か、コンパイルされていない種類への参照です。|エクセル雑感(2024-02-17)
初級脱出10問パック|VBA練習問題(2024-01-24)
累計を求める数式あれこれ|エクセル関数応用(2024-01-22)
複数の文字列を検索して置換するSUBSTITUTE|エクセル入門(2024-01-03)
いくつかの数式の計算中にリソース不足になりました。|エクセル雑感(2023-12-28)
VBAでクリップボードへ文字列を送信・取得する3つの方法|VBA技術解説(2023-12-07)
難しい数式とは何か?|エクセル雑感(2023-12-07)
スピらない スピル数式 スピらせる|エクセル雑感(2023-12-06)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.RangeとCellsの使い方|VBA入門
3.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
4.繰り返し処理(For Next)|VBA入門
5.変数宣言のDimとデータ型|VBA入門
6.ブックを閉じる・保存(Close,Save,SaveAs)|VBA入門
7.並べ替え(Sort)|VBA入門
8.条件分岐(IF)|VBA入門
9.セルのクリア(Clear,ClearContents)|VBA入門
10.マクロとは?VBAとは?VBAでできること|VBA入門




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。



このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
本文下部へ