VBAサンプル集
全シートの画面キャプチャを取得する(keybd_event)

ExcelマクロVBAの実用サンプル、エクセルVBA集と解説
公開日:2013年5月以前 最終更新日:2013-05-14

全シートの画面キャプチャを取得する(keybd_event)

資料等の作成で、画面キャプチャすることがあると思います。

そこで、全シートの画面キャプチャを、新規シートに全て取得するプログラムです。

Alt+PrntScrnで、エクセルのウインドウのみキャプチャしています。



Option Explicit

Declare Sub keybd_event Lib "user32.dll" (ByVal bVk As Byte, _
                     ByVal bScan As Byte, _
                     ByVal dwFlags As Long, _
                     ByVal dwExtraInfo As Long)

Const KEYEVENTF_EXTENDEDKEY = &H1 'キー押下

Const KEYEVENTF_KEYUP = &H2     'キー解放

Sub Sample()
  Dim addSht As Worksheet
  Dim mySht As Variant
  Dim i As Long
  Dim lngRow As Long
  Dim lngHeight As Long
  'VBEから起動した場合の為に
  AppActivate Application.Caption
  '新規シートを追加
  Set addSht = ActiveWorkbook.Worksheets.Add
  '2行目から貼り付け
  lngRow = 2
  addSht.Cells(lngRow, 1).Select
  For Each mySht In ActiveWorkbook.Sheets
    If Not mySht Is addSht Then
      mySht.Select
      DoEvents

      'Alt+PrntScrn押下、解放
      keybd_event vbKeyMenu, 0, KEYEVENTF_EXTENDEDKEY, 0
      keybd_event vbKeySnapshot, 0, KEYEVENTF_EXTENDEDKEY, 0
      keybd_event vbKeySnapshot, 0, KEYEVENTF_EXTENDEDKEY Or KEYEVENTF_KEYUP, 0
      keybd_event vbKeyMenu, 0, KEYEVENTF_EXTENDEDKEY Or KEYEVENTF_KEYUP, 0

      DoEvents
      With addSht
        .Select
        .Paste
        Selection.ShapeRange.ScaleHeight 0.3, msoFalse, msoScaleFromTopLeft
        '画像の高さ分、行を下げる
        lngHeight = 0
        Do While lngHeight < Selection.Height
          lngHeight = lngHeight + Rows(lngRow).RowHeight
          lngRow = lngRow + 1
        Loop
        lngRow = lngRow + 1
        .Cells(lngRow, 1).Select
      End With
    End If
  Next
End Sub

少し長くなっていますが、

貼り付け位置を、画像が重ならないように、貼り付け位置を調整しています。

また、太字0.3は、画像の縮小率です、任意の数値を指定できます。

keybd_event

は、キー送信するAPIです。

SendKeysと同じですが、SendKeysでは、「PrntScrn」が送信できないために使用しています。

keybd_eventを使用しているため、前後の処理において、

処理が完全に終了しているかの判定が難しくなっています。

APIのSleepや、Application.Wait等で待たせる事で良いと思っていたのですが、

DoEvents
これで解決できるようです。

多分問題ないと思いますが、環境によってうまく動作しない場合は、

DoEventsと合わせて、SleepまたはWaitを追加して下さい。

Sleepは、

Private Declare Sub Sleep Lib "KERNEL32.dll" (ByVal dwMilliseconds As Long)
そして、

Sleep(1000)

これで1秒です。

Waitは、

Application.Wait Now + TimeValue("0:0:1")
これで1秒です。

Sleep、Waitの場合は、概ね1秒で大丈夫なようです。





同じテーマ「マクロVBAサンプル集」の記事

図をセル内に強制的に収める(Shape)
図を確認しながら消していく(Shape)
オートシェイプを他ブックの同じ位置に貼り付ける(Shapes,DrawingObjects)
全シートの画面キャプチャを取得する(keybd_event)
写真の取込方法について(Pictures.Insert,Shapes.AddPicture)
写真をサムネイルに変換して取り込む(Shapes.AddPicture)
円グラフの色設定(Chart,SeriesCollection)
棒グラフ・折れ線グラフのサンプルマクロ
人口ピラミッドのグラフをマクロで作成
グラフで特定の横軸の色を変更し基準線を引くマクロ
グラフのデータ範囲を自動拡張するマクロ


新着記事NEW ・・・新着記事一覧を見る

ExcelマクロVBA入門目次|エクセルの神髄(2024-03-20)
VBA10大躓きポイント(初心者が躓きやすいポイント)|VBA技術解説(2024-03-05)
テンキーのスクリーンキーボード作成|ユーザーフォーム入門(2024-02-26)
無効な前方参照か、コンパイルされていない種類への参照です。|エクセル雑感(2024-02-17)
初級脱出10問パック|VBA練習問題(2024-01-24)
累計を求める数式あれこれ|エクセル関数応用(2024-01-22)
複数の文字列を検索して置換するSUBSTITUTE|エクセル入門(2024-01-03)
いくつかの数式の計算中にリソース不足になりました。|エクセル雑感(2023-12-28)
VBAでクリップボードへ文字列を送信・取得する3つの方法|VBA技術解説(2023-12-07)
難しい数式とは何か?|エクセル雑感(2023-12-07)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.RangeとCellsの使い方|VBA入門
3.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
4.繰り返し処理(For Next)|VBA入門
5.変数宣言のDimとデータ型|VBA入門
6.ブックを閉じる・保存(Close,Save,SaveAs)|VBA入門
7.並べ替え(Sort)|VBA入門
8.条件分岐(IF)|VBA入門
9.セルのクリア(Clear,ClearContents)|VBA入門
10.マクロとは?VBAとは?VBAでできること|VBA入門




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。



このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
本文下部へ