ExcelマクロVBAサンプル集 | CSVの読み込み方法(改) | Excelマクロの実用サンプル、エクセルVBA集と解説



最終更新日:2013-09-04

CSVの読み込み方法(改)


実施したいこと
・ファイル名を指定し、形式をカンマ区切り、文字列で開く、
 その際、改行コードLF、CRLF、CRいずれにも対応、
 セル内の","や改行についてはカラムで区切らない。

掲示板で上記のリクエストを頂きました。


ということで、対応ロジックを書いてみました。

CSVの読込方法」この中のVBAコードを改良したものです。

Sub CSV入力()
  Dim varFileName As Variant
  Dim objFSO As New FileSystemObject
  Dim inTS As TextStream
  Dim strRec As String
  Dim strSplit() As String
  Dim i As Long, j As Long, k As Long
  Dim lngQuate As Long
  Dim strCell As String
  Dim blnCrLf As Boolean
  
  varFileName = Application.GetOpenFilename(FileFilter:="CSVファイル(*.csv),*.csv", _
                        Title:="CSVファイルの選択")
  If varFileName = False Then
    Exit Sub
  End If

  Set inTS = objFSO.OpenTextFile(CStr(varFileName), ForReading)
  strRec = CStr(inTS.ReadAll)

  i = 1 'シートの1行目から出力
  j = 0 '列位置はPutCellでカウントアップ
  lngQuate = 0 'ダブルクォーテーションの数
  strCell = ""
  For k = 1 To Len(strRec)
    Select Case Mid(strRec, k, 1)
      Case vbLf, vbCr '「"」が偶数なら改行、奇数ならただの文字
        If lngQuate Mod 2 = 0 Then
          blnCrLf = False
          If k > 1 Then '改行としてのCrLfはCrで改行判定済なので無視する
            If Mid(strRec, k - 1, 2) = vbCrLf Then
              blnCrLf = True
            End If
          End If
          If blnCrLf = False Then
            Call PutCell(i, j, strCell, lngQuate)
            i = i + 1
            j = 0
            lngQuate = 0
            strCell = ""
          End If
        Else
          strCell = strCell & Mid(strRec, k, 1)
        End If
      Case "," '「"」が偶数なら区切り、奇数ならただの文字
        If lngQuate Mod 2 = 0 Then
          Call PutCell(i, j, strCell, lngQuate)
        Else
          strCell = strCell & Mid(strRec, k, 1)
        End If
      Case """" '「"」のカウントをとる
        lngQuate = lngQuate + 1
        strCell = strCell & Mid(strRec, k, 1)
      Case Else
        strCell = strCell & Mid(strRec, k, 1)
    End Select
  Next
  '最終列の処理
  If j > 0 And strCell <> "" Then
    Call PutCell(i, j, strCell, lngQuate)
  End If
    
  Set inTS = Nothing
  Set objFSO = Nothing
End Sub

Sub PutCell(ByRef i As Long, ByRef j As Long, ByRef strCell As String, ByRef lngQuate As Long)
  j = j + 1
  '「""」を「"」で置換
  strCell = Replace(strCell, """""", """")
  '前後の「"」を削除
  If Left(strCell, 1) = """" And Right(strCell, 1) = """" Then
    If Len(strCell) <= 2 Then
      strCell = ""
    Else
      strCell = Mid(strCell, 2, Len(strCell) - 2)
    End If
  End If
  Cells(i, j) = strCell
  strCell = ""
  lngQuate = 0
End Sub

※参照設定で、「Microsoft Scripting Runtime」にチェックを付けて下さい。

CrとLfの判定部分が、ちょっとまどろっこしい感じになっちゃいました。

Crだけってデータが実際にあるのか不明なのですが、これなら、大抵は大丈夫だろうと思いますし、

いろいろなパターンが出てきても、ロジックで対応可能になります。

ただですね、Cr、Lfのの組み合わせがめちゃくちゃだったりすると、どうなるか・・・

そのようなテストデータを用意するのが大変なので・・・

こういう場合に、正しく読めなかった等があれば、報告もらえれば対応しますね。




同じテーマ「ExcelマクロVBAサンプル集」の記事

CSVの読み込み方法(改の改)
CSVの出力(書き出し)方法
UTF-8でCSVの読み書き(ADODB.Stream)
ADOでマスタ付加と集計(SQL)
ADOでマスタ更新(SQL)
ADOでCSVの読み込み(SQL)
Excelファイルを開かずにシート名を取得

新着記事 ・・・新着記事一覧を見る

Excelファイルを開かずにシート名をチェック|ExcelマクロVBAサンプル集(3月23日)
数式の参照しているセルを取得する|ExcelマクロVBAサンプル集(3月18日)
CSVの読み込み方法(改の改)|ExcelマクロVBAサンプル集(3月17日)
変数とプロシージャーの命名について|ExcelマクロVBA技術解説(2月12日)
ファイルの一覧取得・削除(File)|Google Apps Script入門(1月24日)
フォルダの一覧取得・作成・削除(Folder)|Google Apps Script入門(1月24日)
フォルダとファイルを扱う(DriveApp)|Google Apps Script入門(1月24日)
スプレッドシートが非常に遅い、高速化するには|Google Apps Script入門(1月17日)
画像のトリミング(PictureFormat,Crop)|ExcelマクロVBAサンプル集(12月27日)
シート保護|Google Apps Script入門(12月24日)

アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|ExcelマクロVBA入門
2.RangeとCellsの使い方|ExcelマクロVBA入門
3.徹底解説(VLOOKUP,MATCH,INDEX,OFFSET)|エクセル関数超技
4.Range以外の指定方法(Cells,Rows,Columns)|ExcelマクロVBA入門
5.セルの参照範囲を可変にする(OFFSET,COUNTA,MATCH)|エクセル関数超技
6.セルのコピー&値の貼り付け(PasteSpecial)|ExcelマクロVBA入門
7.変数とデータ型(Dim)|ExcelマクロVBA入門
8.ひらがな⇔カタカナの変換|エクセル基本操作
9.CSVの読み込み方法|ExcelマクロVBAサンプル集
10.VBAのFindメソッドの使い方には注意が必要です|ExcelマクロVBA技術解説



  • >
  • >
  • >
  • CSVの読み込み方法(改)

  • このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


    記述には細心の注意をしたつもりですが、
    間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
    なお、掲載のVBAコードは自己責任で使ってください。万一データ破損等の損害が発生しても責任は負いません。

    ↑ PAGE TOP