VBAサンプル集
アメブロの記事本文をVBAでバックアップする№5

ExcelマクロVBAの実用サンプル、エクセルVBA集と解説
公開日:2013年5月以前 最終更新日:2013-06-02

アメブロの記事本文をVBAでバックアップする№5


さーて、いよいよ大詰め、記事本文のバックアップです。


以下のプロシージャーを追加して下さい。



Sub 記事取得()
  Dim i As Long
  Dim strPath As String
  Dim strTheme As String
  Dim strEntry As String
  Dim objFSO As New FileSystemObject
  Dim OutTS As TextStream
  Dim objIE As New InternetExplorer
  Dim objITEM As Object
  objIE.Visible = False
  strPath = ThisWorkbook.Path & "\HTML\"
  With Worksheets("記事一覧")
    For i = 4 To .Cells(.Rows.Count, 1).End(xlUp).Row
      objIE.navigate .Cells(i, 3).Hyperlinks(1).Address
      Call untilReady(objIE)
      .Cells(i, 2) = objIE.Document.getElementById("entry_title").Value
      .Cells(i, 5) = objIE.Document.getElementById("entry_created_datetime").Value
      strTheme = objIE.Document.getElementById("theme_id").Value
      For Each objITEM In objIE.Document.getElementsByTagName("option")
        If objITEM.Value = strTheme Then
          .Cells(i, 4) = objITEM.innertext
          Exit For
        End If
      Next
      strEntry = objIE.Document.getElementById("entry_text").Value
      Set OutTS = objFSO.CreateTextFile( _
            Filename:=strPath & "\entry_" & .Cells(i, 1) & ".html", _
            Overwrite:=True)
      OutTS.Write strEntry
      OutTS.Close
    Next
  End With
  objIE.Quit
  Set objIE = Nothing
End Sub


一覧取得とは別プロシージャーにしました。


一覧取得の中に組み込んで、プログラムを複雑にするより、

このように、機能毎に分割した方が良いでしょう。

また、このように分割することで、

記事本文のみ再取得するといった使い方もできるようになります。

前回までとは違い

getElementById

これで取得しています。

HTMLソースを見て頂ければわかりますが、

テキストボックス等には、IDが付いていますので、直接取得可能なのです。

IDが

entry_title : タイトル
theme_id : テーマ
entry_created_datetime : 日時
entry_text : 記事本文


となっています。

タイトルと日時は問題ないとおもいます。

問題は、テーマです。

テーマは、テーマのIDが取得できますが、ただのIDです。

そこで、ドロップダウンこれがoptionなので、

このoptionの中から、当該IDと同じものを見つけます。

その見つかったテキストが、テーマの文字列となります。

後は、FileSystemObjectで、このエクセルファイルと同一フォルダにある、

サブフォルダ"HTML"に取得した、記事本文(entry_text)を出力しています。

FileSystemObjectを事前バインディングで使っているので、

「ツール」→「参照設定」、「Microsoft Scripting Runtime」にチェックを付けて下さい。

これで完成しました。

指定月のすべての記事一覧を取得し、記事本文のバックアップが完成です。

次回は、最終回として、改善すべき点等の考察をします。

アメブロの記事本文をVBAでバックアップする №1 №2 №3 №4 №5 №6



同じテーマ「マクロVBAサンプル集」の記事

アメブロの記事本文をVBAでバックアップする№1
数独(ナンプレ)を解くVBAに挑戦№1
数独(ナンプレ)を解くアルゴリズムの要点とパフォーマンスの検証№1
ナンバーリンク(パズル)を解くVBAに挑戦№1
ナンバーリンクを解くVBAのパフォーマンス改善№1
オセロを作りながらマクロVBAを学ぼう
他ブックへのリンクエラーを探し解除
Excelシートの複雑な計算式を解析するVBA
Excel将棋:マクロVBAの学習用(№1)
Excel囲碁:万波奈穂先生に捧ぐ
Excel囲碁:再起動後も続けて打てるように改造


新着記事NEW ・・・新着記事一覧を見る

ExcelマクロVBA入門目次|エクセルの神髄(2024-03-20)
VBA10大躓きポイント(初心者が躓きやすいポイント)|VBA技術解説(2024-03-05)
テンキーのスクリーンキーボード作成|ユーザーフォーム入門(2024-02-26)
無効な前方参照か、コンパイルされていない種類への参照です。|エクセル雑感(2024-02-17)
初級脱出10問パック|VBA練習問題(2024-01-24)
累計を求める数式あれこれ|エクセル関数応用(2024-01-22)
複数の文字列を検索して置換するSUBSTITUTE|エクセル入門(2024-01-03)
いくつかの数式の計算中にリソース不足になりました。|エクセル雑感(2023-12-28)
VBAでクリップボードへ文字列を送信・取得する3つの方法|VBA技術解説(2023-12-07)
難しい数式とは何か?|エクセル雑感(2023-12-07)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.RangeとCellsの使い方|VBA入門
3.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
4.繰り返し処理(For Next)|VBA入門
5.変数宣言のDimとデータ型|VBA入門
6.ブックを閉じる・保存(Close,Save,SaveAs)|VBA入門
7.並べ替え(Sort)|VBA入門
8.条件分岐(IF)|VBA入門
9.セルのクリア(Clear,ClearContents)|VBA入門
10.マクロとは?VBAとは?VBAでできること|VBA入門




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。



このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
本文下部へ