VBA練習問題
VBA100本ノック 30本目:名札作成(段組み)

VBAを100本の練習問題で鍛えます
公開日:2020-11-21 最終更新日:2021-02-22

VBA100本ノック 30本目:名札作成(段組み)


名簿から段組みした名札を作成する問題です。


ツイッター連動企画です。
ツイートでの見やすさを考慮して、ブック・シート指定等を適宜省略しています。

VBAテスト用のサンプルデータは、VBA100本ノックの目次ページ からもダウンロードできます。
マクロVBAを初心者向けの基本から上級者向けの高度な内容までサンプルコードを掲載し解説しています。エクセル関数・機能・基本操作の入門解説からマクロVBAまでエクセル全般を網羅しています。


出題

出題ツイートへのリンク

#VBA100本ノック 30本目
古臭いですが名札を作ることになりました。
「名簿」シートのB列に役職、C列に名前が入っています。
「名簿」から「名札」を作成してください。
「名札」はレイアウト・書式を作成済みですが、行数は毎回変わるので3行目以降は1,2行目からコピーしてください。
※画像参照

マクロ VBA 100本ノック

マクロ VBA 100本ノック


サンプルファイルです。
https://excel-ubara.com/vba100sample/VBA100_30.xlsm
https://excel-ubara.com/vba100sample/VBA100_30.zip


VBA作成タイム

この下に頂いた回答へのリンクと解説を掲載しています。
途中まででも良いので、できるだけ自分でVBAを書いてみましょう。


他の人の回答および解説を見て、書いたVBAを見直してみましょう。


頂いた回答

解説

今回は、私が顧客から依頼された場合にどう書くかを意識してみました。
その顧客は、自分でも多少はVBAが出来て、後々のメンテは顧客自身がするという条件で。
つまり、この処理で躓いている顧客に渡す雛形のVBAという事です。

Sub VBA100_30_01()
  Dim ws名簿 As Worksheet
  Dim ws名札 As Worksheet
  Set ws名簿 = Worksheets("名簿")
  Set ws名札 = Worksheets("名札")
  Const c行数 As Long = 2 '1名札行数
  Const c列数 As Long = 2 '段組み数
  
  Dim rng雛形 As Range
  With ws名札
    .Range(.Rows(c行数 + 1), .Rows(.Rows.Count)).Delete
    .Rows(1).Resize(c行数).ClearContents
    Set rng雛形 = .Rows(1).Resize(c行数)
  End With
  
  Dim oRow As Long, oCol As Long, i As Long
  oRow = 1: oCol = 1
  For i = 2 To ws名簿.Range("A1").CurrentRegion.Rows.Count
    If oCol = 1 Then
      rng雛形.Copy Destination:=ws名札.Cells(oRow, 1)
      ws名札.Rows(oRow).Resize(c行数).ClearContents
    End If
    ws名札.Cells(oRow, oCol).Value = ws名簿.Cells(i, 2).Value
    ws名札.Cells(oRow + 1, oCol).Value = ws名簿.Cells(i, 3).Value
    oCol = oCol + 1
    If oCol > c列数 Then
      oRow = oRow + c行数
      oCol = 1
    End If
  Next
End Sub


続いて、とりあえず動けば良いということにして、省略できるものは全て省略してみました。
2行2列を決め打ちして、かつ、配列を使ったらどうなるかというサンプルです。

Sub VBA100_30_02()
  Dim wsIn: Set wsIn = Worksheets("名簿")
  Dim wsOut: Set wsOut = Worksheets("名札")
  
  Dim cnt, ary, i, c
  With wsIn
    cnt = .Cells(.Rows.Count, 3).End(xlUp).Row - 1
    ReDim ary(1 To Int(cnt / 2 + 0.5) * 2, 1 To 2)
    For i = 2 To cnt + 1
      c = (i Mod 2) + 1
      ary(i - 1 - (c - 1), c) = .Cells(i, 2)
      ary(i - (c - 1), c) = wsIn.Cells(i, 3)
    Next
  End With
  
  With wsOut
    .Rows("3:" & wsOut.Rows.Count).Delete
    .Rows(1).Resize(2).ClearContents
    .Rows("1:2").Copy .Rows("1:" & UBound(ary, 1))
    .Range("A1").Resize(UBound(ary, 1), 2) = ary
  End With
End Sub


VBAの書き方は様々です。
どれが良いかは、どのような場面で誰が使うかによって大きく変わってくると思います。
今回は補足はありません。
記事にはVBAソースを掲載しています。


補足

今回は補足はありません。


サイト内関連ページ

第15回.四則演算と注釈(コメント)|VBA入門
エクセルは表計算ソフトですから、計算が出来なくては話になりません。四則演算(加減剰余)は必須です。この四則演算で使う算術演算の演算子は、ワークシートの演算子と同じです。あわせて、注釈(コメント)の書き方も覚えましょう。
第111回.静的配列|VBA入門
・配列とは ・静的配列と動的配列 ・配列の宣言 ・多次元配列 ・要素の下限の変更 ・配列について
第112回.動的配列(ReDim)|VBA入門
・ReDimステートメント ・要素数の変更について ・配列について
第114回.セル範囲⇔配列(マクロVBA高速化必須テクニック)|VBA入門
・セル範囲⇔配列の基本VBA ・使用例 ・配列およびマクロVBAの高速化に関するページ




同じテーマ「VBA100本ノック」の記事

27本目:ハイパーリンクのURL
28本目:シートをブックに分割
29本目:画像の挿入
30本目:名札作成(段組み)
31本目:入力規則
32本目:Excel終了とテキストファイル出力
33本目:マクロ記録の改修
34本目:配列の左右回転
35本目:条件付き書式
36本目:列の並べ替え
37本目:グラフの色設定


新着記事NEW ・・・新着記事一覧を見る

ExcelマクロVBA入門目次|エクセルの神髄(2024-03-20)
VBA10大躓きポイント(初心者が躓きやすいポイント)|VBA技術解説(2024-03-05)
テンキーのスクリーンキーボード作成|ユーザーフォーム入門(2024-02-26)
無効な前方参照か、コンパイルされていない種類への参照です。|エクセル雑感(2024-02-17)
初級脱出10問パック|VBA練習問題(2024-01-24)
累計を求める数式あれこれ|エクセル関数応用(2024-01-22)
複数の文字列を検索して置換するSUBSTITUTE|エクセル入門(2024-01-03)
いくつかの数式の計算中にリソース不足になりました。|エクセル雑感(2023-12-28)
VBAでクリップボードへ文字列を送信・取得する3つの方法|VBA技術解説(2023-12-07)
難しい数式とは何か?|エクセル雑感(2023-12-07)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.RangeとCellsの使い方|VBA入門
3.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
4.繰り返し処理(For Next)|VBA入門
5.変数宣言のDimとデータ型|VBA入門
6.ブックを閉じる・保存(Close,Save,SaveAs)|VBA入門
7.並べ替え(Sort)|VBA入門
8.条件分岐(IF)|VBA入門
9.セルのクリア(Clear,ClearContents)|VBA入門
10.マクロとは?VBAとは?VBAでできること|VBA入門




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。



このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
本文下部へ