VBA100本ノック 33本目：マクロ記録の改修
マクロの記録から作成したVBAを使いやすいように改修して処理速度アップする問題です。
ツイートでの見やすさを考慮して、ブック・シート指定等を適宜省略しています。
マクロVBAを初心者向けの基本から上級者向けの高度な内容までサンプルコードを掲載し解説しています。エクセル関数・機能・基本操作の入門解説からマクロVBAまでエクセル全般を網羅しています。
出題
出題ツイートへのリンク
#VBA100本ノック 33本目
「このVBAはマクロの記録から作ったのですが、件数の数値を変更してから実行しなければならず、データ件数も多くて何分も時間がかかりとても困っています。なんとかしてもらえないでしょうか?」
こう頼まれました。VBAを書いて対応してあげましょう。
※VBAソースはリプにて
処理方法は問いません。
要件を満たし結果が同じであればどのような方法でも構いません。
サンプルファイルです。
https://excel-ubara.com/vba100sample/VBA100_33.xlsm
https://excel-ubara.com/vba100sample/VBA100_33.zip
「このVBAはマクロの記録から作ったのですが、件数の数値を変更してから実行しなければならず、データ件数も多くて何分も時間がかかりとても困っています。なんとかしてもらえないでしょうか?」
こう頼まれました。VBAを書いて対応してあげましょう。
※VBAソースはリプにて
Sub Macro1()
Sheets("データ").Select
For i = 2 To 1001
Range("D" & i).Select
ActiveCell.FormulaR1C1 = _
"=IFERROR(VLOOKUP(RC[-2],マスタ!C[-3]:C[-1],2,FALSE),"""")"
Range("E" & i).Select
ActiveCell.FormulaR1C1 = _
"=IFERROR(VLOOKUP(RC[-3],マスタ!C[-4]:C[-2],3,FALSE),"""")"
Range("F" & i).Select
ActiveCell.FormulaR1C1 = _
"=RC[-1]*RC[-3]"
Range("D" & i & ":F" & i).Select
Selection.Copy
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
Application.CutCopyMode = False
Next
Range("A1").Select
End Sub
処理方法は問いません。
要件を満たし結果が同じであればどのような方法でも構いません。
https://excel-ubara.com/vba100sample/VBA100_33.xlsm
https://excel-ubara.com/vba100sample/VBA100_33.zip
VBA作成タイム
この下に頂いた回答へのリンクと解説を掲載しています。
途中まででも良いので、できるだけ自分でVBAを書いてみましょう。
他の人の回答および解説を見て、書いたVBAを見直してみましょう。
頂いた回答
解説
元々が微妙なコードではありますが、
多少なりともVBAが書ける人に渡すVBAとして書き直すという観点で書いていきます。
・Option Explicit
・インデント
・最終行の取得
・Applicationのプロパティ
ここまでは必須ですね。
最初のコードにある数千件程度ならこれだけでも十分な場合は多いでしょう。
さらに件数が増えることを考え、全行一括入力（Ctrl+Enter）を教えておきたい。
マクロの記録を見る限り、Ctrl+Enterを知らない可能性があります。
VBAと同時に、シート操作もしっかり伝えたいところです。
各種プロパティ等、伝えたいことは山盛りですね。
せっかく自分でマクロ記録からVBAを書いているので、なんとか次の段階に進んでほしい。
この依頼者には、まだ難しいかもしれません。
直ぐには書けるようにはならないと思いますが、まずは読んで理解してもらえることを願って。
今回は特に補足はありません。
多少なりともVBAが書ける人に渡すVBAとして書き直すという観点で書いていきます。
・Option Explicit
・インデント
・最終行の取得
・Applicationのプロパティ
ここまでは必須ですね。
最初のコードにある数千件程度ならこれだけでも十分な場合は多いでしょう。
Sub VBA100_33_01()
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
Dim i As Long
With Sheets("データ")
.Select
For i = 2 To .Cells(.Rows.Count, 2).End(xlUp).Row
.Cells(i, 4).FormulaR1C1 = _
"=IFERROR(VLOOKUP(RC[-2],マスタ!C[-3]:C[-1],2,FALSE),"""")"
.Cells(i, 5).FormulaR1C1 = _
"=IFERROR(VLOOKUP(RC[-3],マスタ!C[-4]:C[-2],3,FALSE),"""")"
.Cells(i, 6).FormulaR1C1 = _
"=RC[-1]*RC[-3]"
.Range("D" & i & ":F" & i).Value = .Range("D" & i & ":F" & i).Value
Next
End With
Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
Range("A1").Select
End Sub
マクロの記録を見る限り、Ctrl+Enterを知らない可能性があります。
VBAと同時に、シート操作もしっかり伝えたいところです。
各種プロパティ等、伝えたいことは山盛りですね。
Sub VBA100_33_02()
Dim cnt As Long
With Sheets("データ")
.Select
cnt = .Range("B1").CurrentRegion.Rows.Count - 1
.Range("D2").Resize(cnt).Value = "=IFERROR(VLOOKUP(B2,マスタ!A:C,2,FALSE),"""")"
.Range("E2").Resize(cnt).Value = "=IFERROR(VLOOKUP(B2,マスタ!A:C,3,FALSE),"""")"
.Range("F2").Resize(cnt).Value = "=C2*E2"
.Range("D2:F2").Resize(cnt).Value = .Range("D2:F2").Resize(cnt).Value
.Range("A1").Select
End With
End Sub
この依頼者には、まだ難しいかもしれません。
直ぐには書けるようにはならないと思いますが、まずは読んで理解してもらえることを願って。
今回は特に補足はありません。
補足
補足はありません。
サイト内関連ページ
第16回．繰り返し処理（For Next）
・For Next ステートメント ・For Next 例文 ・For Next をステップ イン実行で目で見て確認しましょう。 ・１行置きに処理する場合 ・Exit For ・For～Nextのネスト（入れ子） ・最後に一言
第18回．最終行の取得（End,Rows.Count）・エクセルVBAにおける最終行取得の必要性 ・.End(xlDown)：Ctrl+↓ ・.End(xlUp)：Ctrl+↑ ・Endプロパティの方向（↑↓←→）について ・セルの行数を取得するRowプロパティ ・Cells(Rows.Count, 1).End(xlUp).Rowを日本語に訳す ・EndプロパティがRangeオブジェクトを返す ・Endプロパティの問題点 ・最終行に関するサイト内のページ
第38回．セルに計算式を設定（Formula）・計算式を設定できるプロパティ ・Valueプロパティ ・Formulaプロパティ , FormulaLocalプロパティ ・FormulaR1C1プロパティ , FormulaR1C1Localプロパティ ・R1C1参照形式 ・Localが付くプロパティについて ・それぞれの違い（Localは除く） ・何故、こんなに多くのプロパティが存在しているのか ・R1C1形式を使うメリット ・たった1行のVBAで複数のセルに計算式を入れる
第82回．RangeのResizeプロパティ・Resizeプロパティの構文 ・Resizeの使用例 ・Resizeのまとめ
同じテーマ「VBA100本ノック」の記事
・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
31本目：入力規則・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
32本目：Excel終了とテキストファイル出力・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
33本目：マクロ記録の改修34本目：配列の左右回転
・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
35本目：条件付き書式・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
36本目：列の並べ替え・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
37本目：グラフの色設定・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
38本目：1シートを複数シートに振り分け・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
39本目：数値リストの統合（マージ）・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
40本目：複数ブックの統合・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
新着記事NEW ・・・新着記事一覧を見る
ブール型（Boolean）のis変数・フラグについて｜VBA技術解説(2024-04-05)
テキストの内容によって図形を削除する｜VBA技術解説(2024-04-02)
ExcelマクロVBA入門目次｜エクセルの神髄(2024-03-20)
VBA10大躓きポイント（初心者が躓きやすいポイント）｜VBA技術解説(2024-03-05)
テンキーのスクリーンキーボード作成｜ユーザーフォーム入門(2024-02-26)
無効な前方参照か、コンパイルされていない種類への参照です。｜エクセル雑感(2024-02-17)
初級脱出10問パック｜VBA練習問題(2024-01-24)
累計を求める数式あれこれ｜エクセル関数応用(2024-01-22)
複数の文字列を検索して置換するSUBSTITUTE｜エクセル入門(2024-01-03)
いくつかの数式の計算中にリソース不足になりました。｜エクセル雑感(2023-12-28)
アクセスランキング ・・・ ランキング一覧を見る
1.最終行の取得（End,Rows.Count）｜VBA入門
2.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
3.RangeとCellsの使い方｜VBA入門
4.ひらがな⇔カタカナの変換｜エクセル基本操作
5.繰り返し処理（For Next)｜VBA入門
6.変数宣言のDimとデータ型｜VBA入門
7.ブックを閉じる・保存（Close,Save,SaveAs）｜VBA入門
8.並べ替え（Sort）｜VBA入門
9.セルのクリア（Clear,ClearContents）｜VBA入門
10.Findメソッド（Find,FindNext,FindPrevious）｜VBA入門
- ホーム
- マクロVBA入門編
- VBA100本ノック
- 33本目：マクロ記録の改修
このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。