VBA練習問題
VBA100本ノック 91本目:時間計算(残業時間の月間合計)

VBAを100本の練習問題で鍛えます
公開日:2021-02-19 最終更新日:2021-02-22

VBA100本ノック 91本目:時間計算(残業時間の月間合計)


出退勤データから、個人別・月別の月間残業時間数を計算する問題です。


ツイッター連動企画です。
ツイートでの見やすさを考慮して、ブック・シート指定等を適宜省略しています。

VBAテスト用のサンプルデータは、VBA100本ノックの目次ページ からもダウンロードできます。
マクロVBAを初心者向けの基本から上級者向けの高度な内容までサンプルコードを掲載し解説しています。エクセル関数・機能・基本操作の入門解説からマクロVBAまでエクセル全般を網羅しています。


出題

出題ツイートへのリンク

#VBA100本ノック 91本目
「勤怠」に複数月の勤怠データが入っています。
9:00~18:00の休憩1hの実動8hです。
id・月ごとに残業時間を算出し「残業」に一覧出力。
残業:単純に1日8hを超える時間数。ただし9時前出勤は9時とする。
日々1分単位、月間30分単位で切り捨て。
※時間計算の練習問題です。

マクロ VBA 100本ノック

マクロ VBA 100本ノック

マクロ VBA 100本ノック


サンプルファイルです。
https://excel-ubara.com/vba100sample/VBA100_91.xlsm
https://excel-ubara.com/vba100sample/VBA100_91.zip


VBA作成タイム

この下に頂いた回答へのリンクと解説を掲載しています。
途中まででも良いので、できるだけ自分でVBAを書いてみましょう。


他の人の回答および解説を見て、書いたVBAを見直してみましょう。


頂いた回答

解説

100本ノックで時間計算は初です。
1日=1なので時間は小数になります。
小数を扱う場合は小数誤差の発生を考慮したいところです。
特にDate型は注意した方が良さそうです。
時間計算で分単位なら分の整数で扱うのが最も確実です。
分はInt(…*24*60)で求まりますが、あえてVBA関数を使いました。

Sub VBA100_91_01()
  Dim ws勤怠 As Worksheet: Set ws勤怠 = Worksheets("勤怠")
  Dim ws残業 As Worksheet: Set ws残業 = Worksheets("残業")
  Dim 開始9 As Double: 開始9 = TimeSerial(9, 0, 0)
  Dim 拘束9 As Double: 拘束9 = TimeSerial(9, 0, 0)
  
  Dim i As Long, outRow As Long
  Dim id As Variant, yyyymm As Variant
  Dim startTime As Double, overTime As Double, tMinute As Long
  
  ws残業.Range("A1").CurrentRegion.Offset(1).ClearContents
  ws残業.Columns("C").NumberFormat = "[h]:mm"
  outRow = 2
  
  For i = 2 To ws勤怠.Cells(ws勤怠.Rows.Count, 1).End(xlUp).Row
    startTime = ws勤怠.Cells(i, 3).Value2
    If ws勤怠.Cells(i, 3).Value2 < 開始9 Then startTime = 開始9
    
    overTime = ws勤怠.Cells(i, 4).Value2 - startTime - 拘束9
    If overTime > 0 Then
      tMinute = tMinute + Hour(overTime) * 60 + Minute(overTime)
    End If
    
    id = ws勤怠.Cells(i, 1)
    yyyymm = Format(ws勤怠.Cells(i, 2), "yyyymm")
    
    If ws勤怠.Cells(i + 1, 1) <> id Or Format(ws勤怠.Cells(i + 1, 2), "yyyymm") <> yyyymm Then
      ws残業.Cells(outRow, 1) = id
      ws残業.Cells(outRow, 2) = yyyymm
      tMinute = Int(tMinute / 30) * 30
      ws残業.Cells(outRow, 3) = TimeSerial(0, tMinute, 0)
      tMinute = 0
      outRow = outRow + 1
    End If
  Next
End Sub


分の整数になっていれば計算において小数誤差は気にしなくて済みます。
最後にシートに出力する時も、VBA関数を使って時間に変換しています。
補足はありません。記事にはVBAコードを掲載しています。


補足

補足はありません。


サイト内関連ページ

第46回.VBA関数(日付,DateAdd)
・日付時刻に関するVBA関数の一覧 ・DateAdd関数の構文 ・DateAdd関数の使用例
時間計算で困ったときの確実な対処方法
・日付・時刻のシリアル値とは ・Excelにおける小数の問題 ・どんな時に問題が発生するか ・確実な時間計算方法 ・TIME関数の制限について ・単純化した結論
時間に関する関数の扱い方
ツイッターに出した時間関数のお題です。さて問題です。=HOUR(TIME(23,58,59)+TIME(1,1,1)) これはいくつになるでしょうか。お題「文字列のセルだけ結合」https://twitter.com/yamaoka_ss/status/1257637479319912454 時間に関する関数の解説…




同じテーマ「VBA100本ノック」の記事

88本目:クロスABC分析作成
89本目:2つのフォルダの統合
90本目:セルに重なっている画像の削除
91本目:時間計算(残業時間の月間合計)
92本目:セルの色を16進で返す関数
93本目:複数ブックを連結して再分割
94本目:表範囲からHTMLのtableタグを作成
95本目:図形のテキストを検索するフォーム作成
96本目:Accessデータを取得(マスタ結合&抽出)
97本目:Accessデータを取得(グループ集計)
98本目:席替えルールが守られているか確認


新着記事NEW ・・・新着記事一覧を見る

ExcelマクロVBA入門目次|エクセルの神髄(2024-03-20)
VBA10大躓きポイント(初心者が躓きやすいポイント)|VBA技術解説(2024-03-05)
テンキーのスクリーンキーボード作成|ユーザーフォーム入門(2024-02-26)
無効な前方参照か、コンパイルされていない種類への参照です。|エクセル雑感(2024-02-17)
初級脱出10問パック|VBA練習問題(2024-01-24)
累計を求める数式あれこれ|エクセル関数応用(2024-01-22)
複数の文字列を検索して置換するSUBSTITUTE|エクセル入門(2024-01-03)
いくつかの数式の計算中にリソース不足になりました。|エクセル雑感(2023-12-28)
VBAでクリップボードへ文字列を送信・取得する3つの方法|VBA技術解説(2023-12-07)
難しい数式とは何か?|エクセル雑感(2023-12-07)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.RangeとCellsの使い方|VBA入門
3.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
4.繰り返し処理(For Next)|VBA入門
5.変数宣言のDimとデータ型|VBA入門
6.ブックを閉じる・保存(Close,Save,SaveAs)|VBA入門
7.並べ替え(Sort)|VBA入門
8.条件分岐(IF)|VBA入門
9.セルのクリア(Clear,ClearContents)|VBA入門
10.マクロとは?VBAとは?VBAでできること|VBA入門




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。



このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
本文下部へ