Excelマクロの記録で覚えるVBA | 第18回.オートフィルタ | Excelマクロの自動記録を使って、エクセルVBAの初心者向け入門解説



最終更新日:2013-02-18

第18回.オートフィルタ


フィルタをやりましょう。


まあ、表計算らしい機能ではあります。




では、マクロの記録です、データは何でも良いでしょう。


1.マクロの記録

2.フィルタ

3.1のみ選択・・・たまたま1のデータを入れただけです。

4.記録終了


作成れたマクロは、


Sub Macro1()
'
' Macro1 Macro
'

'
  Selection.AutoFilter
  ActiveSheet.Range("$A$1:$C$4").AutoFilter Field:=1, Criteria1:="1"
End Sub


2003の場合は、

Selection.AutoFilter
Selection.AutoFilter Field:=1, Criteria1:="1"

と記録されます。


Selection.AutoFilter
これでフィルタが適用されます。


ActiveSheet.Range("$A$1:$C$4").AutoFilter Field:=1, Criteria1:="1"
Field:=1

は1番目のフィールドの指定

2番目のフィールドなら、Field:=2となります。


Criteria1:="1"
値が"1"のみフィルタ設定しています。

条件がAND等で複数になる場合には、2番目はCriteria2となります。

複数条件の指定は、次回にでもやります。



これ省略すると、


Sub Macro1()
  ActiveSheet.Range("$A$1:$C$4").AutoFilter Field:=1, Criteria1:="1"
End Sub


これだけで、フィルタが適用されて、1番目のフィールドが"1"のみ表示されます。


では、フィルタを解除するのは、


マクロの記録をしてみましょう。


Sub Macro2()
'
' Macro2 Macro
'

'
  Selection.AutoFilter
End Sub


あれ、フィルタを適用するときと同じですね。


そう、フィルタが適用されていなければ適用し、適用されていれば、解除します。


では、今どちらかわからないと困る場合がありますよね、


それには、


Sub Macro3()
  If ActiveSheet.AutoFilterMode = True Then
    MsgBox "適用されています"
  Else
    MsgBox "適用されていません"
  End If
End Sub


このように、

ActiveSheet.AutoFilterMode

で判断できます。



まだ、問題があります。


すでに、他のフィールドで絞り込みされていると、


ActiveSheet.Range("$A$1:$C$4").AutoFilter Field:=1, Criteria1:="1"

これだけでは、他のフィールドの絞り込みがそのままになってしまい、

予想外の結果になってしまいます。


この場合は、

1.一度、フィルタを解除してから行う。

2.全てのフィールドの絞り込みを解除する。

どちらかの方法になります。


1.一度、フィルタを解除してから行う


Sub Macro4()
  If ActiveSheet.AutoFilterMode Then
    ActiveSheet.AutoFilter
  End If
  ActiveSheet.Range("$A$1:$C$4").AutoFilter Field:=1, Criteria1:="1"

End Sub


ActiveSheet.AutoFilter
解除するには、

ActiveSheet.AutoFilterMode = False

でもできます。


2.全てのフィールドの絞り込みを解除する


Sub Macro4()

  Dim i As Long
  If ActiveSheet.AutoFilterMode = True Then
    For i = 1 To ActiveSheet.AutoFilter.Filters.Count
      If ActiveSheet.AutoFilter.Filters(i).On = True Then
        ActiveSheet.Range("$A$1:$C$4").AutoFilter Field:=i
      End If
    Next i
  End If

  ActiveSheet.Range("$A$1:$C$4").AutoFilter Field:=1, Criteria1:="1"

End Sub


えーと、ひょっとして、

For〜Next

って、初めて出てきたかもしれませんね。


すでに説明している、

Do While〜Loop

と同じです、


書き直すと、


Sub Macro4()

  Dim i As Long
  If ActiveSheet.AutoFilterMode = True Then
    i = 1
    Do While i <= ActiveSheet.AutoFilter.Filters.Count
      If ActiveSheet.AutoFilter.Filters(i).On = True Then
        ActiveSheet.Range("$A$1:$C$4").AutoFilter Field:=i
      End If
      i = i + 1
    Loop
  End If
  ActiveSheet.Range("$A$1:$C$4").AutoFilter Field:=1, Criteria1:="1"

End Sub


つまり、Forでは自分でカウントアップする必要がなくなります。


For i = 1 to 10

 ・・・

Next

i = 1

Do While i <= 10

 ・・・

 i = i + 1

Loop

これらは、10回繰り返し処理することになります。


ActiveSheet.AutoFilter.Filters.Count
これは、フィルタのフィールドの数です。

つまり、フィルタのフィールドの数分の繰り返し処理をしています。


ActiveSheet.AutoFilter.Filters(i).On = True

絞り込みがされている場合は、

True

絞り込みがされていない場合は、

False

になります。


ActiveSheet.Range("$A$1:$C$4").AutoFilter Field:=i
Criteria

を指定していないので、全て選択になります。



フィルタでは、表示形式によって抽出されますので注意が必要です。


特に、数値・日付の場合は、表示形式の違いで抽出されない場合があります。


これは、手作業でやっても同じことなのですが、マクロでは大問題です。


次回は、オートフィルタの続きとして、


表示形式の違いによる、注意点、対処方法等を紹介しましょう。






同じテーマ「Excelマクロの記録で覚えるVBA」の記事

第19回.オートフィルタ2
第20回.ジャンプのセル選択
第21回.条件付き書式
第22回.シートの移動コピー
第23回.セルの結合
第24回.印刷
第25回.開く・保存・閉じる

新着記事 ・・・新着記事一覧を見る

SUMIFの間違いによるパフォーマンスの低下について|エクセル関数超技(6月17日)
条件式のいろいろな書き方:TrueとFalseの判定とは|ExcelマクロVBA技術解説(6月15日)
空白セルを正しく判定する方法2|ExcelマクロVBA技術解説(5月6日)
フルパスをディレクトリ、ファイル名、拡張子に分ける|ExcelマクロVBA技術解説(4月15日)
テキストボックスの各種イベント|Excelユーザーフォーム入門(4月9日)
フォルダ(サブフォルダも全て)削除する、Optionでファイルのみ削除|ExcelマクロVBAサンプル集(4月4日)
最後の空白(や指定文字)以降の文字を取り出す|エクセル関数超技(3月26日)
先頭の数値、最後の数値を取り出す|エクセル関数超技(3月26日)
Excelファイルを開かずにシート名をチェック|ExcelマクロVBAサンプル集(3月23日)
数式の参照しているセルを取得する|ExcelマクロVBAサンプル集(3月18日)

アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|ExcelマクロVBA入門
2.RangeとCellsの使い方|ExcelマクロVBA入門
3.徹底解説(VLOOKUP,MATCH,INDEX,OFFSET)|エクセル関数超技
4.Range以外の指定方法(Cells,Rows,Columns)|ExcelマクロVBA入門
5.変数とデータ型(Dim)|ExcelマクロVBA入門
6.セルのコピー&値の貼り付け(PasteSpecial)|ExcelマクロVBA入門
7.セルの参照範囲を可変にする(OFFSET,COUNTA,MATCH)|エクセル関数超技
8.ひらがな⇔カタカナの変換|エクセル基本操作
9.定数と型宣言文字(Const)|ExcelマクロVBA入門
10.CSVの読み込み方法|ExcelマクロVBAサンプル集



  • >
  • >
  • >
  • オートフィルタ

  • このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


    記述には細心の注意をしたつもりですが、
    間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
    なお、掲載のVBAコードは自己責任で使ってください。万一データ破損等の損害が発生しても責任は負いません。

    ↑ PAGE TOP