VBA技術解説
シートに数式を設定する時のセル参照の指定方法

ExcelマクロVBAの問題点と解決策、VBAの技術的解説
最終更新日:2014-11-21

シートに数式を設定する時のセル参照の指定方法

シートに計算結果ではなく、計算式を設定する場合の、セル参照の記述方法について解説します、
マクロVBAでは多くの場合、計算結果をセルに入れる事が多いのですが、時に計算式を設定する必要があります、
その時の、セル参照の記述が以外に面倒なものです。


下の表で説明していきます。
D列の残高(D3~D12)の計算式(E列に表示してある計算式)を設定してみましょう。

マクロ VBA サンプル画像


まず、非常にベーシックな方法として、R1C1形式での設定があります。
これは、マクロの自動記録を使う人にはお馴染みのものでしょう。



Sub sample1()
  Dim i As Long
  For i = 3 To Cells(Rows.Count, 1).End(xlUp).Row
    Cells(i, 4).FormulaR1C1 = "=R[-1]C+RC[-2]-RC[-1]"
  Next
End Sub

FormulaR1C1またはFormulaR1C1Localについての詳しい解説は、
マクロVBA入門:第38回.セルに計算式を設定

セルに計算式(関数)を設定する場合のマクロVBAになります。マクロでは、セルに計算式を設定することは、そんなに多くないと思いますが、決して使わないわけではありません。しかし、この計算式の設定には何種類ものプロパティがあり、結構やっかいなのです。
こちらを参照してください。

しかし、R1C1はちょっと分かりづらいのでしょうか、
以下のような苦心作を見かけることも良くあります。

Sub sample2()
  Dim i As Long
  For i = 3 To Cells(Rows.Count, 1).End(xlUp).Row
    Cells(i, 4).Value = "=D" & i - 1 & "+B" & i & "-C" & i
  Next
End Sub

もちろん、これはこれで問題はありません。
文字列結合を多用しているので、行数が多いと若干遅いかもしれないという程度です。


しかし、この題材の場合は、そもそも1行ずつ設定する必要がありません。
D3に数式を入れたら、オートフィルまたはコピペで済みます。
まず
オートフィルなら



Sub sample3()
  Dim i As Long
  i = Cells(Rows.Count, 1).End(xlUp).Row
  Range("D3").FormulaR1C1 = "=R[-1]C+RC[-2]-RC[-1]"
  Range("D3").AutoFill Destination:=Range(Cells(3, 4), Cells(i, 4))
End Sub

コピペなら

Sub sample4()
  Dim i As Long
  i = Cells(Rows.Count, 1).End(xlUp).Row
  Range("D3").Value = "=D2+B3-C3"
  Range("D3").Copy Destination:=Range(Cells(4, 4), Cells(i, 4))
End Sub

少し書き方を変えてはいますが、マクロの自動記録を参考にして書くと、
大抵は、こんな感じになっているのではないかと想像して書いてみました。


しかしですね、そもそもオートフィルもコピペも必要がないのです。
ワークシートに数式を入れるとき、絶対参照・相対参照さえしっかり指定していれば、
対象セルを一括で選択しておき、Ctrl+Enterで一括入力ができることを知っていれば、
こんな簡単な記述で済んでしまいます。

Sub sample5()
  Dim i As Long
  i = Cells(Rows.Count, 1).End(xlUp).Row
  Range(Cells(3, 4), Cells(i, 4)).Value = "=R[-1]C+RC[-2]-RC[-1]"
End Sub

さらに、この方法ならR1C1形式を使うまでもなく、普通にセルに入れるように書けてしまいます。

Sub sample6()
  Dim i As Long
  i = Cells(Rows.Count, 1).End(xlUp).Row
  Range(Cells(3, 4), Cells(i, 4)).Value = "=D2+B3-C3"
End Sub

どう考えても、最後のVBAコードが一番わかり易いことは言うまでもないですね。
マクロはVBAの知識だけでなく、ワークシートの操作も同時に理解していることで、とても完結なコードが書けるようになります。




同じテーマ「マクロVBA技術解説」の記事

空白セルを正しく判定する方法2
Rangeオブジェクト.Valueの省略について
シート保護でユーザー操作を制限する
シートに数式を設定する時のセル参照の指定方法
標準モジュールとシートモジュールの違い
オートフィルタ(AutoFilter)の使い方まとめ
複雑な条件(複数除外等)のオートフィルター(AutoFilter)
クリップボードを使わないセルのCopy
Rangeの使い方:最終行まで選択を例に
フルパスをディレクトリ、ファイル名、拡張子に分ける
Colorプロパティの設定値一覧(カラー定数、XlRgbColor列挙)


新着記事NEW ・・・新着記事一覧を見る

VBA100本ノック 18本目:名前定義の削除|VBA練習問題100(11月6日)
VBA100本ノック 17本目:重複削除(ユニーク化)|VBA練習問題100(11月6日)
VBA100本ノック 16本目:無駄な改行を削除|VBA練習問題100(11月5日)
VBA100本ノック 15本目:シートの並べ替え|VBA練習問題100(11月4日)
VBA100本ノック 14本目:社外秘シート削除|VBA練習問題100(11月3日)
VBA100本ノック 13本目:文字列の部分フォント|VBA練習問題100(11月1日)
VBA100本ノック 12本目:セル結合を解除|VBA練習問題100(10月31日)
VBA100本ノック 11本目:セル結合の警告|VBA練習問題100(10月30日)
VBA100本ノック 10本目:行の削除|VBA練習問題100(10月29日)
VBA100本ノック 9本目:フィルターコピー|VBA練習問題100(10月28日)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.RangeとCellsの使い方|VBA入門
3.変数宣言のDimとデータ型|VBA入門
4.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
5.マクロって何?VBAって何?|VBA入門
6.Range以外の指定方法(Cells,Rows,Columns)|VBA入門
7.繰り返し処理(For Next)|VBA入門
8.セルに文字を入れるとは(Range,Value)|VBA入門
9.とにかく書いてみよう(Sub,End Sub)|VBA入門
10.マクロはどこに書くの(VBEの起動)|VBA入門




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。



このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
本文下部へ