VBA100本ノック 27本目:ハイパーリンクのURL
ハイパーリンクのURLを取得する問題です。
ツイートでの見やすさを考慮して、ブック・シート指定等を適宜省略しています。
出題
出題ツイートへのリンク
#VBA100本ノック 27本目
WEBページからコピーしてシートに貼り付けたら、セルの文字列にハイパーリンクが付いてきました。
ハイパーリンクが付いているセルについて、
・右隣のセルにリンクのURLを出力
・ハイパーリンクを解除
※図は無視してください。
※対象シートは任意
WEBページからコピーしてシートに貼り付けたら、セルの文字列にハイパーリンクが付いてきました。
ハイパーリンクが付いているセルについて、
・右隣のセルにリンクのURLを出力
・ハイパーリンクを解除
※図は無視してください。
※対象シートは任意
VBA作成タイム
この下に頂いた回答へのリンクと解説を掲載しています。
途中まででも良いので、できるだけ自分でVBAを書いてみましょう。
他の人の回答および解説を見て、書いたVBAを見直してみましょう。
頂いた回答
解説
ハイパーリンクはシートに対して設定されています。
シートのHyperlinksで取得できます。
RangeにもHyperlinksがありますが、今回はシート全体なのでシートの方を使います。
ただし図のリンクもコレクションに入っているので区別する必要があります。
念の為に右セル上書きしないようにしてみました。
指定セル範囲の場合なら、RangeのHyperlinksを使うと良いと思います。
図のリンクだけならShapeにHyperlinkがありますが、今回は割愛します。
指定範囲だけの出力と、セルと一緒に図のリンクも同時に出力するVBAを記事補足に掲載しました。
シートのHyperlinksで取得できます。
RangeにもHyperlinksがありますが、今回はシート全体なのでシートの方を使います。
ただし図のリンクもコレクションに入っているので区別する必要があります。
念の為に右セル上書きしないようにしてみました。
Sub VBA100_27_01()
Dim ws As Worksheet
Set ws = ActiveSheet
Dim hpl As Hyperlink
For Each hpl In ws.Hyperlinks
If hpl.Type = msoHyperlinkRange Then
If hpl.Range.Offset(, 1) <> "" Then
hpl.Range.Offset(, 1).Insert shift:=xlToRight
hpl.Range.Offset(, 1).Clear
End If
hpl.Range.Offset(, 1).Value = hpl.Address
End If
Next
ws.Hyperlinks.Delete
End Sub
図のリンクだけならShapeにHyperlinkがありますが、今回は割愛します。
指定範囲だけの出力と、セルと一緒に図のリンクも同時に出力するVBAを記事補足に掲載しました。
補足
上記VBAでは右隣のセルに何か入っている場合はセルを挿入してみましたが、レイアウトがガチャガチャになってしまう場合もありそうです。
列挿入した方が良いかもしれません。
実際にはWEBからの貼り付けならA列だけに貼りつくような場合が結構多いかもしれません。
このあたりは工夫の余地がありそうですので、適宜変更してみてください。
HyperlinkのType
列挿入した方が良いかもしれません。
実際にはWEBからの貼り付けならA列だけに貼りつくような場合が結構多いかもしれません。
このあたりは工夫の余地がありそうですので、適宜変更してみてください。
HyperlinkのTypeはMsoHyperlinkType列挙です。
名前 | 値 | 説明 |
msoHyperlinkRange | 0 | Rangeオブジェクトに適用されます。 |
msoHyperlinkShape | 1 | Shapeオブジェクトに適用されます。 |
msoHyperlinkInlineShape | 2 | インライン図形に適用されます。 Microsoft Word でのみ使用されます。 |
選択セル範囲内のみ出力
Sub VBA100_27_02()
If TypeName(Selection) <> "Range" Then Exit Sub
Dim rng As Range, tRng As Range
Set tRng = Intersect(Selection.Worksheet.UsedRange, Selection)
If tRng Is Nothing Then Exit Sub
For Each rng In tRng
If rng.Hyperlinks.Count > 0 Then
rng.Offset(, 1).Value = rng.Hyperlinks(1).Address
rng.Hyperlinks.Delete
End If
Next
End Sub
選択範囲限定なので、右列は空いている前提で無条件で出力しています。
セルと図の両方のリンクを出力
Sub VBA100_27_03()
Dim ws As Worksheet
Set ws = ActiveSheet
Dim hpl As Hyperlink, rng As Range
For Each hpl In ws.Hyperlinks
Select Case hpl.Type
Case msoHyperlinkRange
Set rng = hpl.Range
Case msoHyperlinkShape
Set rng = hpl.Shape.TopLeftCell
Case Else
Set rng = Nothing 'ないはず
End Select
If Not rng Is Nothing Then
If rng.Offset(, 1) <> "" Then
rng.Offset(, 1).Insert shift:=xlToRight
rng.Offset(, 1).Clear
End If
rng.Offset(, 1).Value = hpl.Address
End If
Next
ws.Hyperlinks.Delete
End Sub
サイト内関連ページ
第95回.ハイパーリンク(Hyperlink)|VBA入門
・Hyperlinksコレクション ・Hyperlinkオブジェクト ・ハイパーリンクの追加 ・ハイパーリンクの削除 ・既に設定されているハイパーリンクの扱い方
ユーザー定義関数でハイパーリンクのURLを取得(Hyperlink)ネットから、何らかの一覧をエクセルにコピペすると、文字列や画像等に、リンクの設定がくっついてきます。URLが表記されていれば良いですが、表示されていない事の方が多いでしょう。そこで、VBAでユーザー定義関数を作成し、URLを取得できるようにします。
同じテーマ「VBA100本ノック」の記事
・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
25本目:マトリックス表をDB形式に変換・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
26本目:ファイル一覧作成・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
27本目:ハイパーリンクのURL28本目:シートをブックに分割
・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
29本目:画像の挿入・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
30本目:名札作成(段組み)・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
31本目:入力規則・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
32本目:Excel終了とテキストファイル出力・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
33本目:マクロ記録の改修・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
34本目:配列の左右回転・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
新着記事NEW ・・・新着記事一覧を見る
ブール型(Boolean)のis変数・フラグについて|VBA技術解説(2024-04-05)
テキストの内容によって図形を削除する|VBA技術解説(2024-04-02)
ExcelマクロVBA入門目次|エクセルの神髄(2024-03-20)
VBA10大躓きポイント(初心者が躓きやすいポイント)|VBA技術解説(2024-03-05)
テンキーのスクリーンキーボード作成|ユーザーフォーム入門(2024-02-26)
無効な前方参照か、コンパイルされていない種類への参照です。|エクセル雑感(2024-02-17)
初級脱出10問パック|VBA練習問題(2024-01-24)
累計を求める数式あれこれ|エクセル関数応用(2024-01-22)
複数の文字列を検索して置換するSUBSTITUTE|エクセル入門(2024-01-03)
いくつかの数式の計算中にリソース不足になりました。|エクセル雑感(2023-12-28)
アクセスランキング ・・・ ランキング一覧を見る
1.最終行の取得(End,Rows.Count)|VBA入門
2.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
3.RangeとCellsの使い方|VBA入門
4.ひらがな⇔カタカナの変換|エクセル基本操作
5.繰り返し処理(For Next)|VBA入門
6.変数宣言のDimとデータ型|VBA入門
7.ブックを閉じる・保存(Close,Save,SaveAs)|VBA入門
8.並べ替え(Sort)|VBA入門
9.セルのクリア(Clear,ClearContents)|VBA入門
10.Findメソッド(Find,FindNext,FindPrevious)|VBA入門
- ホーム
- マクロVBA入門編
- VBA100本ノック
- 27本目:ハイパーリンクのURL
このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。