VBA練習問題解答
練習問題23(総合練習5)解答

Excelマクロ練習問題集、エクセルVBAの学習教材
公開日:2013年5月以前 最終更新日:2023-09-12

練習問題23(総合練習5)解答

マクロVBA練習問題23の解答ページです。


マクロVBA練習問題

・A2セルに日付、B2セルに名前を指定します。
 この条件に合うデータを、シート「練習23_データ」から抜出し、5行目以降に表示して下さい。
・名前は部分一致として下さい。
 つまり、「山」と指定した場合は、「山田」も「山口」も「木山も」対象にするということです。

※日付・名前の指定は、どちらか片方のみの場合もあれば、両方指定する場合もあります。
 どちらも指定されていなかった場合は、エラーとして、その旨メッセージ表示して下さい。

練習問題用のExcelファイル
シート「練習23」
  A  B  C
日付 名前  
     
     
日付 名前 売上
     

シート「練習23_データ」

  A   B  C
日付 名前 売上
2月1日 佐藤 60401
2月1日 鈴木 52356
2月1日 高橋 63710
2月1日 田中 31031
2月1日 渡辺 91167
2月1日 伊藤 35587
2月1日 山本 13380
2月1日 中村 10568
2月1日 小林 16088
2月1日 斎藤 48431
2月2日 佐藤 74483
2月2日 鈴木 37145
2月2日 高橋 25299
2月2日 田中 40721
2月2日 渡辺 74643
2月2日 伊藤 38452
2月2日 山本 26336
2月2日 中村 68897
2月2日 小林 54442
2月2日 斎藤 48827
2月3日 佐藤 73344
2月3日 鈴木 99534
2月3日 高橋 38550
2月3日 田中 47101
2月3日 渡辺 50946
2月3日 伊藤 88662
2月3日 山本 80139
2月3日 中村 83470
2月3日 小林 63135
2月3日 斎藤 51899
2月4日 佐藤 53329
2月4日 鈴木 50511
2月4日 高橋 62527
2月4日 田中 58765
2月4日 渡辺 20835
2月4日 伊藤 64537
2月4日 山本 57450
2月4日 中村 99263
2月4日 小林 70988
2月4日 斎藤 59704
2月5日 佐藤 98885
2月5日 鈴木 78962
2月5日 高橋 16117
2月5日 田中 44974
2月5日 渡辺 78055
2月5日 伊藤 51420
2月5日 山本 63214
2月5日 中村 35803
2月5日 小林 58097
2月5日 斎藤 38558

※上記表の全体を選択し、コピー(Ctrl+C)の後、エクセルのシートのA1セルに貼り付け(Ctrl+V)してください。

では、お考えください。
すぐに解答を見ずに、必ず自力で書けるとこまででも良いので書きましょう。

シンキングタイム

シンキングタイム開始


シンキングタイム終了

当サイトのコンテンツ
ExcelマクロVBA入門
VBA入門シリーズは、マクロVBAを実務で自在に使いこなし業務を効率化・自動化できるようになることを目的としています。始めはより詳しく丁寧に解説しつつ少しずつ難易度を上げることで無理なく学習を進められるようにしています。「マクロ」と「VBA」の違い マクロはエクセルの操作を自動化する機能であり、

書くべきマクロVBAが分からない時は、
ここでじっくり勉強してから再チャレンジしてください。

マクロVBA練習問題解答

では解答のマクロVBAコードです。
※.Valueは適宜省略しています。

Sub 練習問題23()
  Dim i As Long
  Dim j As Long
  Dim flg As Boolean
  Dim ws1 As Worksheet
  Dim ws2 As Worksheet
  Set ws1 = Worksheets("練習23")
  Set ws2 = Worksheets("練習23_データ")
  With ws1
    If .Cells(2, 1) = "" And _
      .Cells(2, 2) = "" Then
      MsgBox "条件を指定して下さい。"
      Exit Sub
    End If
    .Range("A4").CurrentRegion.Offset(1).ClearContents '出力範囲の消去
    j = 5
    For i = 2 To ws2.Cells(ws2.Rows.Count, 1).End(xlUp).Row
      flg = True
      If .Cells(2, 1) <> "" Then
        If .Cells(2, 1) <> ws2.Cells(i, 1) Then
          flg = False
        End If
      End If
      If .Cells(2, 2) <> "" Then
        If InStr(ws2.Cells(i, 2), .Cells(2, 2)) = 0 Then
          flg = False
        End If
      End If
      If flg = True Then
        'データのコピー
        .Range(.Cells(j, 1), .Cells(j, 3)).Value = ws2.Range(ws2.Cells(i, 1), ws2.Cells(i, 3)).Value
        j = j + 1
      End If
    Next
  End With
End Sub

flgの使い方が全てです。
ここでは2条件なので、Ifの多段階ネストでも対応できますが、
このようにflgを使い、各条件の判定を独立させることで、
条件数が多くなっても対応可能となります。
また、
.Range(.Cells(j, 1), .Cells(j, 3)).Value = ws2.Range(ws2.Cells(i, 1), ws2.Cells(i, 3)).Value
このようにすることで、値のみコピーが範囲指定で簡単にできます。



同じテーマ「マクロVBA練習問題解答」の記事

練習問題20(総合練習2)解答

マクロVBA練習問題20の解答ページです。マクロVBA練習問題 ・「元表」を下の「出来上がりサンプル」のようにして下さい。・月が変わったら1行挿入して、挿入した行に月の合計売上を入れて下さい。A列に、○月合計 B列に、売上の合計 それぞれ太字にして下さい。
練習問題21(総合練習3)解答
マクロVBA練習問題21の解答ページです。マクロVBA練習問題 ・A列の都道府県から重複を失くし(ユニークにして)、D列に入れて下さい。・都道府県別の合計売上をE列に入れて下さい。練習問題用のExcelファイル こちらからダウンロードできます。
練習問題22(総合練習4)解答
マクロVBA練習問題22の解答ページです。マクロVBA練習問題 ・シート「練習22」では、各伝票の1行から6行が横に並んでいます。これを、シート「練習22_回答」を新規追加し、各伝票の行を縦に並べて下さい。
練習問題23(総合練習5)解答
練習問題24(再帰呼出し)解答
マクロVBA練習問題24の解答ページです。マクロVBA練習問題 ・以下の表の全組み合わせを作成して下さい。サンプルデータでは、組み合わせの数は、8*3*6*5=720通りです。・各項目はカンマ(,)で区切って下さい。
練習問題25(各種VBA関数)解答
マクロ練習問題25の解答ページです。マクロVBA練習問題 ・以下の表において、課題に従って元データより回答欄に出力して下さい。※1問目なら、回答欄に"Excelマクロ(vba)練習"と出力する。
練習問題26(全シート処理とハイパーリンク)解答
マクロVBA練習問題26の解答ページです。マクロVBA練習問題 全シートのハイパーリンク付き一覧を先頭シートに作成します。現在のブックの先頭に新規シートを追加し、既存シートのシート名一覧をハイパーリンク付きで作成して下さい。
練習問題27(データ分割し別ブック保存)解答
マクロVBA練習問題27の解答ページです。マクロVBA練習問題 アクティブブックのアクティブシートのA列に担当、B列に支店が入っています。支店ごとのブックを作成して下さい。作成したブックの保存先は、アクティブブックと同一フォルダとして下さい。
練習問題28(シートを別ブックにして値のみにする)解答
マクロVBA練習問題28の解答ページです。マクロVBA練習問題 アクティブブックにはシートが複数(Sheet1,Sheet2,Sheet3)あります。Sheet1だけを別ブックにして、計算式を抜き(値だけに)にしてから保存して下さい。
練習問題29(ロット引き当て)解答
マクロVBA練習問題29の解答ページです。マクロVBA練習問題 入荷後の在庫を、注文に対して割り振ります。以下の表をみて下さい。この表において、F列と、H列~K列を埋めます。注文数に見合った、入荷数を割り振ります。
練習問題30(マトリックス→リスト形式)解答
マクロVBA練習問題30の解答ページです。マクロVBA練習問題 売上と仕入の、支店別年度別のマトリックス表があります。これをリスト形式(データベース形式)のデータに変換してください。以下の表をみて下さい。


新着記事NEW ・・・新着記事一覧を見る

ブール型(Boolean)のis変数・フラグについて|VBA技術解説(2024-04-05)
テキストの内容によって図形を削除する|VBA技術解説(2024-04-02)
ExcelマクロVBA入門目次|エクセルの神髄(2024-03-20)
VBA10大躓きポイント(初心者が躓きやすいポイント)|VBA技術解説(2024-03-05)
テンキーのスクリーンキーボード作成|ユーザーフォーム入門(2024-02-26)
無効な前方参照か、コンパイルされていない種類への参照です。|エクセル雑感(2024-02-17)
初級脱出10問パック|VBA練習問題(2024-01-24)
累計を求める数式あれこれ|エクセル関数応用(2024-01-22)
複数の文字列を検索して置換するSUBSTITUTE|エクセル入門(2024-01-03)
いくつかの数式の計算中にリソース不足になりました。|エクセル雑感(2023-12-28)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
3.RangeとCellsの使い方|VBA入門
4.ひらがな⇔カタカナの変換|エクセル基本操作
5.繰り返し処理(For Next)|VBA入門
6.変数宣言のDimとデータ型|VBA入門
7.ブックを閉じる・保存(Close,Save,SaveAs)|VBA入門
8.並べ替え(Sort)|VBA入門
9.セルのクリア(Clear,ClearContents)|VBA入門
10.Findメソッド(Find,FindNext,FindPrevious)|VBA入門




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。


このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
本文下部へ