ExcelマクロVBA技術解説 | 条件式のいろいろな書き方:TrueとFalseの判定とは | Excelマクロの問題点と解決策、エクセルVBAの技術的解説



最終更新日:2017-06-15

条件式のいろいろな書き方:TrueとFalseの判定とは

条件式の書き方で、VBAプログラムは大きく様相が変わってきます、

VBAを習い始めは、
比較演算子で比較した結果が
正しければTrue、
間違っていればFalse
という事で理解するはずです。

しかし、いろいろなサンプルコードを見ていると、
「あれっ」比較演算子が無い・・・
というようなIfステートメントやSelect Caseに出くわします。


IfやSelect Caseにおける、True判定、False判定について、もう少し詳しく解説します。


まず、VBAにおけるTrueの正体は何か、
論理値として書かれたTrue,Falseを数値変換してみましょう。
これには、CLng関数CInt関数、もしくは計算します。

MsgBox CLng(True)
MsgBox CInt(True)
MsgBox True + 0

上記のいずれでも同じですが、メッセージボックスには、
-1
と表示されます。
ではFalseは、

MsgBox CLng(False)
MsgBox CInt(False)
MsgBox False + 0

こちらは、
0
と表示されます。
つまり、True,Falseの正体は、-1,0という事になります。
※ちなみに、Excelシート上では、True=1,False=0です。

しかし、上記のTrueとFalseの値は、論理値として書かれたTrue,Falseの値であり、
IfやSelect Caseでの、True判定とは違うものです。
Ifの条件式が成立する場合の結果を見てみましょう。

Dim a
Dim b
a = 1
b = 1
MsgBox CLng(a = b)

結果は、
-1
と表示されます。
論理値Trueと同じです。
では、条件が成立しない場合は、

Dim a
Dim b
a = 1
b = 2
MsgBox CLng(a = b)

結果は、
0
と表示されます。
論理値Falseと同じです。

では逆の事をしてみましょう。
数値を論理値に変換してみます。
これには、CBool関数を使います。

Dim a
Dim b
a = -1
b = 0
MsgBox CBool(a)
MsgBox CBool(b)

順に、
True
False

と表示されます。
論理値を数値変換した時の反対になっていますので、当然納得です。

では、今度は、全く別の数値で、CBool関数を使ってみましょう。

Dim a
Dim b
a = -2
b = 2
MsgBox CBool(a)
MsgBox CBool(b)

順に、
True
True

と表示されます。
Trueは-1なはずなのに、-2も2もTrueと変換されました。

ここまで進むと、
変数に入っている数値をIf判定できるのではないかと気づきます。

Dim a
a = 0
If a Then
  MsgBox "True判定"
Else
  MsgBox "False判定"
End If

結果は、
False判定
と表示されます。
これは、False=0なので納得です。
それでは、

Dim a
a = 2
If a Then
  MsgBox "True判定"
Else
  MsgBox "False判定"
End If

結果は、
True判定
と表示されます。
つまり、
CBool(2)はTrueなので、True判定になるということです。

結論としては、
数値であれば、そのままIfの条件式とすることが出来るという事です。
その時の判定は、
0ならFalse
0以外はTrue

になるという事です。

ここまで理解すると、以下のような書き方が出来ます。

Dim a
On Error Resume Next
a = 1 / 0
If Err Then
  MsgBox "エラー"
End If

結果は、
エラー
と表示されます。
Errオブジェクトの既定のプロパティはNumberで、エラーが無い場合はNumberは0が返されます。
ここではErr.Numberは11となりますので、11を論理値として判定すればTrueになるという事です。
つまり、エラーが無ければ0が返されるのでFalse、エラーがあれば0以外が返されるのでTrue判定となるという事です。
もちろん、
Err.Number <> 0
と書くのが省略しない正しい書き方です。
でも、Errと書けば、なんとなくErrだったらと直感的にわかり易いということです、

以下のような使い方もできます。

Dim a
a = "Excel2013"
If InStr(a, "ce") Then
  MsgBox "文字列は含まれます"
End If

結果は、
文字列は含まれます
と表示されます。
Instr関数は、文字列が含まれていなければ0を、含まれていればその位置を数値で返します。
上記では、InStr(a, "ce")は3を返しますので、True判定となります。
こちらももちろん、
InStr(a, "ce") > 0
と書くのが省略しない正しい書き方になります。
Errと同様に、InStrだけで、文字が含まれていればと直感的に理解できるものです。

これは、Excelを作った人が意図したものかどうかは知る由もありませんが、
関数やオブジェクト等の戻り値は、
正しい時は0、エラーや見つからない時は0以外を返すようになっています。
これを理解すれば、条件式を簡略化した書き方が出来るようになります。

これは、自分でFunctionを作った時にも使えます。
戻り値の型をBooleanにするだけでなく、
エラーコードを返すようなFunctionを作った時には、
正しければ0を、間違っている場合は0以外を返すように作れば、
条件式が書きやすくなるという事です。

ここまで理解できれば、IFやSelect Caseの書き方の幅も大分広がると思います。
ですが、以下のような使い方は、やめた方がよいでしょう。

c = a = b

このような書き方を見かけることがありますが、これはいかがなものか
これは、以下の書き方を、極端に短く書いてしまったものです。

If a = b Then
  c = True
Else
  c = False
End If

VBAコードは短ければ良いというものではありません。
わかり易さというものも、極めて重要な要素です。
ただし、そのわかり易さというのは人それぞれで、その人のVBAスキルに依存するものです。
まずは自分にとってわかり易いVBAコードを書くようにして下さい。
そしてその先では、VBAコードを共有する人たちにとってわかり易いコードを書くようにして下さい。




同じテーマ「ExcelマクロVBA技術解説」の記事

データクレンジングと名寄せ
マクロとは、VBAとは
コーディングとデバッグ
オブジェクトとプロパティの真実
WorksheetFunctionについて
RangeとCellsの深遠
Offset、Resizeを使いこなそう

新着記事 ・・・新着記事一覧を見る

大量VlookupをVBAで高速に処理する方法について|ExcelマクロVBA技術解説(12月12日)
オセロを作りながらマクロVBAを学ぼう|ExcelマクロVBAサンプル集(11月26日)
ScreenUpdating=False時にエラー停止後にシートが固まったら|ExcelマクロVBA技術解説(11月21日)
データクレンジングと名寄せ|ExcelマクロVBA技術解説(10月20日)
SUMIFの間違いによるパフォーマンスの低下について|エクセル関数超技(6月17日)
条件式のいろいろな書き方:TrueとFalseの判定とは|ExcelマクロVBA技術解説(6月15日)
空白セルを正しく判定する方法2|ExcelマクロVBA技術解説(5月6日)
フルパスをディレクトリ、ファイル名、拡張子に分ける|ExcelマクロVBA技術解説(4月15日)
テキストボックスの各種イベント|Excelユーザーフォーム入門(4月9日)
フォルダ(サブフォルダも全て)削除する、Optionでファイルのみ削除|ExcelマクロVBAサンプル集(4月4日)

アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|ExcelマクロVBA入門
2.RangeとCellsの使い分け方|ExcelマクロVBA入門
3.変数とデータ型(Dim)|ExcelマクロVBA入門
4.Range以外の指定方法(Cells,Rows,Columns)|ExcelマクロVBA入門
5.セルのコピー&値の貼り付け(PasteSpecial)|ExcelマクロVBA入門
6.定数と型宣言文字(Const)|ExcelマクロVBA入門
7.マクロって何?VBAって何?|ExcelマクロVBA入門
8.CSVの読み込み方法|ExcelマクロVBAサンプル集
9.徹底解説(VLOOKUP,MATCH,INDEX,OFFSET)|エクセル関数超技
10.ひらがな⇔カタカナの変換|エクセル基本操作



  • >
  • >
  • >
  • 条件式のいろいろな書き方:TrueとFalseの判定とは

  • このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


    記述には細心の注意をしたつもりですが、
    間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
    なお、掲載のVBAコードは自己責任で使ってください。万一データ破損等の損害が発生しても責任は負いません。

    ↑ PAGE TOP