ExcelマクロVBAサンプル集 | アメブロの記事本文をVBAでバックアップする2 | Excelマクロの実用サンプル、エクセルVBA集と解説



最終更新日:2013-06-02

アメブロの記事本文をVBAでバックアップする2


記事のバックアップの前に、まずは記事の一覧を取得します。

前回作成した表示モジュールに、以下を追加して下さい。


これを動かすためには、事前にInternetExplorerアメブロにログインしておいて下さい。、
(ログインしたら、InternetExplorerは閉じてしまって良いです)

アメブロへのログイン機能は付けていません。

Sub 一覧取得()
  Const cnsUri As String = "http://blog.ameba.jp/ucs/entry/srventrylist.do?pageID=【NO】&entry_ym=【yyyymm】"
  Dim i As Long
  Dim j As Long
  Dim strID As String
  Dim strUri As String
  Dim strHref As String
  Dim objIE As New InternetExplorer
  Dim objITEM As Object
  With Worksheets("記事一覧")
    strUri = Replace(cnsUri, "【NO】", 1)
    strUri = Replace(strUri, "【yyyymm】", .Cells(1, 2))
    objIE.navigate strUri
    Call untilReady(objIE)
    i = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
    For Each objITEM In objIE.Document.getElementsByTagName("h2")
      strHref = objITEM.getElementsByTagName("a")(0)
      j = InStr(strHref, "entry-")
      If j > 0 Then
        strID = Replace(Mid(strHref, j + 6), ".html", "")
        .Cells(i, 1) = strID
        .Hyperlinks.Add Anchor:=.Cells(i, 2), _
                Address:=strHref, _
                TextToDisplay:=objITEM.innertext
        i = i + 1
      End If
    Next
  End With
  objIE.Quit
  Set objIE = Nothing
  Set objITEM = Nothing
End Sub


VBE(Visual Basic Editor)の、ツール参照設定

ここで、Microsoft Scripting Runtime これにチェックを付けて下さい。

では、コードの説明です。

まず、

Const cnsUri As String = "http://blog.ameba.jp/ucs/entry/srventrylist.do?pageID=【NO】&entry_ym=【yyyymm】"

これは、アメブロの「記事の編集」のページURLです。

記事の編集は、月毎になっています、

entry_ym=【yyyymm】

この部分が、entry_ym=201306 このようになります。

これは、実際にご自身のページで確認してもらえれば良いと思います。

問題は、pageID=【NO】 この部分です。

WEB画面では、1ページ目の時は、この部分はないのですが、

2ページ目からは、pageID=2 このようになっている事が確認できるはずです。

そこで、pageID=1 とすると、見事1ページ目が表示されます。

プログラムでは、最終的には、この数値を1からカウントアップさせますが、

上では、コードを理解しやすいように、1固定にしています。

従って、上のコードは、その月の1ページ目だけの記事一覧を取得しています。

少し難しいのは、

For Each objITEM In objIE.Document.getElementsByTagName("h2")
  strHref = objITEM.getElementsByTagName("a")(0)
    j = InStr(strHref, "entry-")
    If j > 0 Then


この部分でしょう。

ここは、WEBで実際のページをHTMLのソース表示をして確認するしかありません。

記事一覧の部分は、

<h2><a href="http://ameblo.jp/・・・

となっていますので、

For Each objITEM In objIE.Document.getElementsByTagName("h2")

これで、h2タグで必要なデータを取得しています。

いきなり、aタグで取得すると、関係ない部分が多すぎるので、h2タグで先にに絞り込んでいるのです。

そして、

strHref = objITEM.getElementsByTagName("a")(0)

これで、実際のaタグを取得しています。

さらに、

j = InStr(strHref, "entry-")
If j > 0 Then

これにより、間違いなく、記事へのリンクである事を確認しています。

後は、ID部分を文字列操作で取り出してシートに出力

aタグのテキストがタイトルなので、それもシートにハイパーリンクを付けて出力しています。

これで、指定月の1ページ目の記事一覧が取得できました。

さて、1ページだけでは仕方ないので、

当該月のすべてのページを取得するようにします。

アメブロの記事本文をVBAでバックアップする 1 2 3 4 5 6




同じテーマ「ExcelマクロVBAサンプル集」の記事

数独(ナンプレ)を解くVBAに挑戦5
数独(ナンプレ)を解くアルゴリズムの要点とパフォーマンスの検証4
ナンバーリンク(パズル)を解くVBAに挑戦8
ナンバーリンクを解くVBAのパフォーマンス改善3

新着記事 ・・・新着記事一覧を見る

空白セルを正しく判定する方法2|ExcelマクロVBA技術解説(5月6日)
フルパスをディレクトリ、ファイル名、拡張子に分ける|ExcelマクロVBA技術解説(4月15日)
テキストボックスの各種イベント|Excelユーザーフォーム入門(4月9日)
フォルダ(サブフォルダも全て)削除する、Optionでファイルのみ削除|ExcelマクロVBAサンプル集(4月4日)
最後の空白(や指定文字)以降の文字を取り出す|エクセル関数超技(3月26日)
先頭の数値、最後の数値を取り出す|エクセル関数超技(3月26日)
Excelファイルを開かずにシート名をチェック|ExcelマクロVBAサンプル集(3月23日)
数式の参照しているセルを取得する|ExcelマクロVBAサンプル集(3月18日)
CSVの読み込み方法(改の改)|ExcelマクロVBAサンプル集(3月17日)
変数とプロシージャーの命名について|ExcelマクロVBA技術解説(2月12日)

アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|ExcelマクロVBA入門
2.ひらがな⇔カタカナの変換|エクセル基本操作
3.RangeとCellsの使い方|ExcelマクロVBA入門
4.Range以外の指定方法(Cells,Rows,Columns)|ExcelマクロVBA入門
5.徹底解説(VLOOKUP,MATCH,INDEX,OFFSET)|エクセル関数超技
6.変数とデータ型(Dim)|ExcelマクロVBA入門
7.セルの参照範囲を可変にする(OFFSET,COUNTA,MATCH)|エクセル関数超技
8.セルのコピー&値の貼り付け(PasteSpecial)|ExcelマクロVBA入門
9.CSVの読み込み方法|ExcelマクロVBAサンプル集
10.定数と型宣言文字(Const)|ExcelマクロVBA入門



  • >
  • >
  • >
  • アメブロの記事本文をVBAでバックアップする2

  • このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


    記述には細心の注意をしたつもりですが、
    間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
    なお、掲載のVBAコードは自己責任で使ってください。万一データ破損等の損害が発生しても責任は負いません。




    ↑ PAGE TOP