ExcelマクロVBAサンプル集 | CSVの出力(書き出し)方法




CSVの出力(書き出し)方法


シート内容をCSV出力(書き出し)する方法です。

CSVの読込は、

CSVの読込方法」「CSVの読込方法(改)

こちらを参照して下さい。


2通りの方法を紹介します。

まずは、エクセルの機能をそのまま利用します。

Sub CSV出力(ByVal sht As Worksheet, Optional ByVal rngStart As Range = Nothing)
  Dim varFile As Variant
  
  varFile = Application.GetSaveAsFilename(InitialFileName:=sht.Name & ".csv", _
                      FileFilter:="CSVファイル(*.csv),*.csv", _
                      FilterIndex:=1, _
                      Title:="保存ファイルの指定")
  If varFile = False Then
    Exit Sub
  End If
    
  sht.Select
  sht.Copy
  

  '不要な先頭の行列を削除します。
  If Not rngStart Is Nothing Then
    If rngStart.Row > 1 Then
      Range(Rows(1), Rows(rngStart.Row - 1)).Delete
    End If
    If rngStart.Column > 1 Then
      Range(Columns(1), Columns(rngStart.Column - 1)).Delete
    End If
  End If
  
  ActiveWorkbook.SaveAs Filename:=varFile, FileFormat:=xlCSV, CreateBackup:=False
  ActiveWindow.Close
  
  MsgBox ("CSV出力しました。" & vbLf & vbLf & varFile)
End Sub


引数で、ワークシートと開始セルを指定できるようにしています。

これにより、どのシートからも使えるようになります。


Application.GetSaveAsFilename

保存ファイルを選択するダイアログを表示します。

シート名+「.csv」を初期のファイル名にしています。

拡張子は、csvのみ指定しています。

開始セルより上の行、左の列は削除して、CSVに出力されないようにしています。

処理の流れは、

保存ファイルの選択

シートの新規ブックへのコピー

不要な行列の削除

名前を付けて保存

これは簡単です。

しかし、これでは、いろいろ不都合な場合があります。

他システム、特にDB等へアップロードする場合には、このままでは出来ない事があるのです。

例えば、日付は、表示形式のままの文字列で出力されてしまいます。

また数値もカンマ付の場合は、"12,345"のように、文字列として出力されます。

CSV出力前に、当該シートの書式を全て直してから行えばよいのですが、

書式の変更も面倒なら、また元に戻す必要があり、何かと不都合です。


このような場合は、直接CSVを出力するようにします。

Sub CSV出力(ByVal sht As Worksheet, Optional ByVal rngStart As Range = Nothing)
  Dim varFile As Variant
  Dim FSO As New FileSystemObject
  Dim TS As TextStream
  Dim lngRowMin As Long, lngRowMax As Long
  Dim lngColMin As Long, lngColMax As Long
  Dim i As Long

  
  varFile = Application.GetSaveAsFilename(InitialFileName:=sht.Name & ".csv", _
                      FileFilter:="CSVファイル(*.csv),*.csv", _
                      FilterIndex:=1, _
                      Title:="保存ファイルの指定")
  If varFile = False Then
    Exit Sub
  End If
    
  '開始行列、終了行列を取得
  If rngStart Is Nothing Then
    lngRowMin = 1
    lngColMin = 1
  Else
    lngRowMin = rngStart.Row
    lngColMin = rngStart.Column
  End If
  lngRowMax = 最終行取得(sht)
  lngColMax = 最終列取得(sht)
  
  Set TS = FSO.CreateTextFile(Filename:=varFile, Overwrite:=True)
  
  For i = lngRowMin To lngRowMax
    TS.WriteLine CSV_EditRec(sht, i, lngColMin, lngColMax)
  Next
  
  TS.Close
  Set TS = Nothing
  Set FSO = Nothing

  MsgBox ("CSV出力しました。" & vbLf & vbLf & varFile)
End Sub


Private Function CSV_EditRec(ByVal sht As Worksheet, _
                i As Long, _
                lngColMin As Long, _
                lngColMax As Long) As String
  Dim strRec As String
  Dim strCol As String
  Dim j As Long

  strRec = ""
  For j = lngColMin To lngColMax
    Select Case True
      Case IsNumeric(sht.Cells(i, j))
        strCol = CStr(CDbl(sht.Cells(i, j)))
      Case IsDate(sht.Cells(i, j))
        If InStr(sht.Cells(i, j), "-") Then
          strCol = sht.Cells(i, j)
        Else
          strCol = Format(sht.Cells(i, j), "yyyy/mm/dd")
        End If
      Case InStr(sht.Cells(i, j), ","), InStr(sht.Cells(i, j), """")
        strCol = """" & sht.Cells(i, j) & """"
      Case Else
        strCol = sht.Cells(i, j)
    End Select
    If strRec = "" Then
      strRec = strCol
    Else
      strRec = strRec & "," & strCol
    End If
  Next
  CSV_EditRec = strRec
End Function


Function 最終行取得(ByVal sht As Worksheet) As Long
  Dim ary As Variant
  Dim i As Long, j As Long
  ary = sht.Range(sht.Cells(1, 1), sht.Cells.SpecialCells(xlLastCell))
  Do
    For i = UBound(ary, 1) To LBound(ary, 1) Step -1
      j = 1
      For j = LBound(ary, 2) To UBound(ary, 2)
        If ary(i, j) <> "" Then
          最終行取得 = i
          Exit Function
        End If
      Next j
    Next i
  Loop
End Function

Function 最終列取得(ByVal sht As Worksheet) As Long
  Dim ary As Variant
  Dim i As Long, j As Long
  ary = sht.Range(sht.Cells(1, 1), sht.Cells.SpecialCells(xlLastCell))
  Do
    For i = UBound(ary, 2) To LBound(ary, 2) Step -1
      j = 1
      For j = LBound(ary, 1) To UBound(ary, 1)
        If ary(j, i) <> "" Then
          最終列取得 = i
          Exit Function
        End If
      Next j
    Next i
  Loop
End Function


かなり長いですが、

「最終行取得」、「最終列取得」は以前に作成済のモジュールです。

行列がでこぼこに入力されている場合でも、正しく最終判定をする為に使用しています。

通常の一覧なら、End(xlUp)等でも良いでしょう。


FileSystemObjectを使用していますが、昔からある、

Open ファイル For Output As #1

でも良いです。

処理内容は単純です。

要は、


Function CSV_EditRec

の内容だけでしょう。

セルの値を判定し、データ内容によって、編集処理を分けています。

ここでは、数値、日付、「"」や「,」を含む文字列、その他、の4通りです。

日付の場合は、「-」の入った電話番号が日付判定される場合があるので、除外しています。

「CSV_EditRec」での編集は、CSVの使い道により、変更を加える必要があります。

例えば、日付は、「#2011/05/17#」のようにする必要がある場合もでてくるでしょう。

いずれにせよ、上記モジュールはかなり汎用的に作成してありますので、

コピペで、いろいろ使い回しが可能です。






  • >
  • >
  • >
  • CSVの出力(書き出し)方法

  • この記事がお役に立ちましたら「いいね」「Bookmark」をお願いいたします。


    ★同じテーマ「ExcelマクロVBAサンプル集」の記事★
    CSVの読み込み方法
    CSVの読み込み方法(改)
    UTF-8でCSVの読み書き(ADODB.Stream)
    ADOでマスタ付加と集計(SQL)
    ADOでマスタ更新(SQL)
    ADOでCSVの読み込み(SQL)
    ユーザー定義関数でフリガナを取得する(GetPhonetic)


    ★新着記事★ ・・・ 新着記事一覧を見る
    フォルダー・ファイル(ブック)・シートの文字制限|ExcelマクロVBA技術解説(12月8日)
    ハイパーリンクからファイルのフルパスを取得する|ExcelマクロVBAサンプル集(12月4日)
    Excel2003(xls)を2007以降(xlsx,xlsm)に変換する(HasVBProject)|ExcelマクロVBAサンプル集(12月3日)
    シートに数式を設定する時のセル参照の指定方法|ExcelマクロVBA技術解説(11月21日)
    プログラミングの基本〜ロジックの組み立て|ExcelマクロVBA技術解説(11月18日)
    数式内の不要なシート名を削除する(HasFormula)|ExcelマクロVBAサンプル集(11月14日)
    ユーザー操作を制限する(Locked,Protect,ScrollArea)|ExcelマクロVBA技術解説(11月5日)
    Rangeオブジェクト.Valueの省略について|ExcelマクロVBA技術解説(11月5日)


    ★アクセスランキング★ ・・・ ランキング一覧を見る
    1.CSVの読み込み方法|ExcelマクロVBAサンプル集
    2.空白セルを正しく判定する方法(IsEmpty,IsError,HasFormula)|ExcelマクロVBA技術解説
    3.セルの参照範囲を可変にする(OFFSET,COUNTA,MATCH)|エクセル関数超技
    4.徹底解説(VLOOKUP,MATCH,INDEX,OFFSET)|エクセル関数超技
    5.最終行の取得(End,Rows.Count)|ExcelマクロVBA入門
    6.ひらがな⇔カタカナの変換|エクセル基本操作
    7.CSVの出力(書き出し)方法|ExcelマクロVBAサンプル集
    8.ピボットテーブル(PivotTable)|ExcelマクロVBA入門
    9.複数条件で検索し、複数データを取得する方法|エクセル関数超技
    10.ハイパーリンクを絶対パスで保存する方法|エクセル基本操作



    当サイトには多くのエクセル関数、エクセルVBA情報があります。
    問題が解決しなかったときは他の記事も検索してみてください。 ▲「CSVの出力(書き出し)方法」のトップへ戻る