ExcelマクロVBAサンプル集 | ユーザー定義関数でフリガナを取得する(GetPhonetic) | Excelマクロの実用サンプル、エクセルVBA集と解説



最終更新日:2013-05-14

ユーザー定義関数でフリガナを取得する(GetPhonetic)



ワークシート関数の、「PHONETIC」では、

他のソフト等からコピペした漢字は取得できません。

そこで、VBAでユーザー定義関数を作成し、読みを取得できるようにします。


A列はメモ帳よりコピペしました。

B列に、ユーザー定義関数を指定して、振り仮名を取得しています。

C列は、B列の数式の内容です。

以下が、ユーザー定義関数になります。

Function GetPhonetic(セル As Range, _
            Optional ByVal 変換 As Integer = 8, _
            Optional ByVal 全て As Boolean = False)
  Dim strPhonetic As String
  GetPhonetic = StrConv(Application.GetPhonetic(セル), 変換)
  strPhonetic = GetPhonetic
  If 全て = True Then
    Do Until strPhonetic = ""
      strPhonetic = StrConv(Application.GetPhonetic(), 変換)
      If strPhonetic <> "" Then
        GetPhonetic = GetPhonetic & " ; " & strPhonetic
      End If
    Loop
  End If
End Function


標準モジュールに作成して下さい。


説明

Application.GetPhonetic(文字列)
これで文字列に対する、読み仮名を取得します。

Application.GetPhonetic()
のように、文字列を省略すると、次の読み候補が取得されます。
読み候補がなくなると、""が返されます。

StrConv(文字列, 変換方法)
文字列を変換方法で変換します。
変換方法には以下が指定可能です。

1(vbUpperCase):大文字に変換
2(vbLowerCase):小文字に変換
3(vbProperCase):各単語の先頭の文字を大文字に変換します。
4(vbWide):半角文字を全角文字に変換
8(vbNarrow):全角文字を半角文字に変換
16(vbKatakana):ひらがなをカタカナに変換
32(vbHiragana):カタカナをひらがなに変換
64(vbUnicode):Unicodeに変換
128(vbFromUnicode):Unicodeからシステムの既定のコードページに変換

ここでは、普通に考えて、8,16,32、くらいになるでしょう。

Optional ByVal
省略可能な引数になります。
省略した場合は、=の後の値を使用します。

第3引数に、Trueを指定した場合は、全ての読みを、" ; "で結合して表示しています。

全角カナで、読み候補も先頭のみなら

Function GetPhonetic(セル As Range)
  GetPhonetic = Application.GetPhonetic(セル)
End Function


このだけでOKです。

少しVBAが解る方は、

Do〜Loop等で処理し、値のみをセルに入れた方が、使い勝手は良いと思います。

例えば以下のように。

Sub SetPhonetic()
  Dim i As Integer
  i = 1 '開始行
  Do Until Cells(i, 1) = "" '空白行になるまで
    Cells(i, 2) = Application.GetPhonetic(Cells(i, 1))
    i = i + 1
  Loop
End Sub


いかがでしょうか。

当然のことながら、漢字の正しい読みなど、PCに解ろうはずもありません。

しかし、現在のPCは結構賢いです(笑)

そこそこ、正しく変換してくれます。

しかし、最後は、人間が目で確認することは、絶対に必要です。

ネットからコピーしたデータや、他ソフトで作成したデータ等から、

読みを取得したい場合等に利用すると、結構手間が省けます。





同じテーマ「ExcelマクロVBAサンプル集」の記事

ユーザー定義関数でハイパーリンクのURLを取得(Hyperlink)
カラーのコード取得、256RGB⇔16進変換
時刻になったら音を鳴らして知らせる(OnTime)
指定文字、指定数式でジャンプ機能(Union)
「値の貼り付け」をショートカットに登録(OnKey)
「セルの結合」をショートカットに登録(OnKey)
半角カナのみ全角カナに変換する

新着記事 ・・・新着記事一覧を見る

データクレンジングと名寄せ|ExcelマクロVBA技術解説(10月20日)
SUMIFの間違いによるパフォーマンスの低下について|エクセル関数超技(6月17日)
条件式のいろいろな書き方:TrueとFalseの判定とは|ExcelマクロVBA技術解説(6月15日)
空白セルを正しく判定する方法2|ExcelマクロVBA技術解説(5月6日)
フルパスをディレクトリ、ファイル名、拡張子に分ける|ExcelマクロVBA技術解説(4月15日)
テキストボックスの各種イベント|Excelユーザーフォーム入門(4月9日)
フォルダ(サブフォルダも全て)削除する、Optionでファイルのみ削除|ExcelマクロVBAサンプル集(4月4日)
最後の空白(や指定文字)以降の文字を取り出す|エクセル関数超技(3月26日)
先頭の数値、最後の数値を取り出す|エクセル関数超技(3月26日)
Excelファイルを開かずにシート名をチェック|ExcelマクロVBAサンプル集(3月23日)

アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|ExcelマクロVBA入門
2.RangeとCellsの使い方|ExcelマクロVBA入門
3.Range以外の指定方法(Cells,Rows,Columns)|ExcelマクロVBA入門
4.変数とデータ型(Dim)|ExcelマクロVBA入門
5.セルのコピー&値の貼り付け(PasteSpecial)|ExcelマクロVBA入門
6.定数と型宣言文字(Const)|ExcelマクロVBA入門
7.徹底解説(VLOOKUP,MATCH,INDEX,OFFSET)|エクセル関数超技
8.マクロって何?VBAって何?|ExcelマクロVBA入門
9.CSVの読み込み方法|ExcelマクロVBAサンプル集
10.ひらがな⇔カタカナの変換|エクセル基本操作



  • >
  • >
  • >
  • ユーザー定義関数でフリガナを取得する(GetPhonetic)

  • このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


    記述には細心の注意をしたつもりですが、
    間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
    なお、掲載のVBAコードは自己責任で使ってください。万一データ破損等の損害が発生しても責任は負いません。

    ↑ PAGE TOP