ツイッター出題回答
VBAで漢数字を算用数字に変換

ExcelマクロVBAとエクセル関数についての私的雑感
最終更新日:2022-07-14

VBAで漢数字を算用数字に変換


ツイッターで出題された問題に挑戦しました。


漢数字を算用数字に変換するVBAを作成するお題です。


出題ツイート

【お題】
VBAで漢数字を算用数字に変換してください。

例:千八百万六千五百→18,006,500

カンマはあってもなくてもよいです。オプションで選べるとなおよし。皆さんどんな解答作りますか?


エクセル Excel サンプル画像
https://twitter.com/Kabura_net14831/status/1546078899955965952


筆者の回答したVBA

ちょっと無理矢理感はありますが・・・
工夫は4桁の単位ごとに配列に入れて処理していくあたりでしょうか。



Function Str2Num(ByVal s As String, Optional ByVal aComma As Boolean = True) As String
  Dim aryU: aryU = Array("無量大数", "不可思議", "那由他", "阿僧祇", "恒河沙", "極", "載", "澗", "正", "溝", "穣", "杼", "垓", "京", "兆", "億", "万")
  Dim aryS: ReDim aryS(UBound(aryU) + 1)
  Dim i As Long, p As Long
  
  s = Replace(s, ChrW(&H79ED), "杼")
  s = Replace(s, ChrW(&HD855) & ChrW(&HDF71), "杼")
  
  For i = 0 To UBound(aryU)
    p = InStr(s, aryU(i))
    If p > 0 Then
      aryS(i) = ToNum(Left(s, p - 1))
      s = Mid(s, p + Len(aryU(i)))
    Else
      aryS(i) = "0000"
    End If
  Next
  aryS(UBound(aryS)) = ToNum(s)
  
  Str2Num = Omit0(Join(aryS, ""))
  If aComma Then Str2Num = EditComma(Str2Num)
End Function

Function ToNum(ByVal s As String) As String
  Dim aryU: aryU = Array("千", "百", "十", "九", "八", "七", "六", "五", "四", "三", "二", "一")
  Dim aryN: aryN = Array(1000, 100, 10, 9, 8, 7, 6, 5, 4, 3, 2, 1)
  Dim rtn As Long, i As Long, p As Long, t As String
  rtn = 0: t = ""
  For i = 1 To Len(s)
    p = WorksheetFunction.Match(Mid(s, i, 1), aryU, 0) - 1
    If aryN(p) >= 10 Then
      If t = "" Then t = 1
      rtn = rtn + (t * aryN(p))
      t = ""
    Else
      t = t & aryN(p)
    End If
  Next
  ToNum = Format(rtn + IIf(t = "", 0, t), "0000")
End Function

Function Omit0(ByVal s As String) As String
  Dim i As Long
  For i = 1 To Len(s)
    If Omit0 <> "" Or Mid(s, i, 1) <> "0" Then
      Omit0 = Mid(s, i)
      Exit Function
    End If
  Next
  '後日追記:以下のような方法もある
'  s = Trim(Replace(s, "0", " "))
'  Omit0 = Replace(s, " ", "0")
End Function

Function EditComma(ByVal s As String) As String
  Dim i As Long
  For i = Len(s) To 1 Step -1
    If (Len(s) - i) Mod 3 = 0 And EditComma <> "" Then
      EditComma = "," & EditComma
    End If
    EditComma = Mid(s, i, 1) & EditComma
  Next
End Function



「杼」の漢字が少々厄介なことになっているようです。

𥝱 ・・・ サロゲートペア:ChrW(&HD855) & ChrW(&HDF71)
秭 ・・・ UNICODE:ChrW(&H79ED)
杼 ・・・ sjisにあるのでVBEで直接記述可能

サロゲートペアに対応した文字列関数を以下のページで紹介しています。
サロゲートペアに対応した自作関数(Len,Left,Mid,Right)
ツイッターで、サロゲートペアに対応した文字列関数の話しになりました。シート関数のLEFTとRIGHTはサロゲートペアに対応しているようですが、MIDとLENは対応していません。そして、VBA関数の、Len,Left,Mid,Right、これらは一切サロゲートペアに対応していません。
AscW関数のサロゲート対応版も載せています。




同じテーマ「ツイッター出題回答 」の記事

ツイッターで出されたVBAのお題(悪魔のCSV)をやってみた
「VBAで導関数を求めよ」ツイッターのお題をやってみた
ツイッターのお題「君の名は?」
ツイッターのお題「CSV編集」
アルファベットの26進(ツイッターお題)
ナンバープレート数字遊び:ツイッターお題
サロゲートペアに対応した自作関数(Len,Left,Mid,Right)
迷路にネコが挑戦したら、どうなるかな…
迷路ネコが影分身の術を体得したら…
VBAで漢数字を算用数字に変換


新着記事NEW ・・・新着記事一覧を見る

TOROW関数(配列を横1行の配列にして返す)|エクセル入門(2022-10-31)
TOCOL関数(配列を縦1列の配列にして返す)|エクセル入門(2022-10-31)
CHOOSECOLS関数(配列から複数の指定された列を返す)|エクセル入門(2022-10-29)
CHOOSEROWS関数(配列から複数の指定された行を返す)|エクセル入門(2022-10-29)
WorksheetFunctionの効率的な使い方とスピル新関数の利用|VBA入門(2022-10-27)
VSTACK関数(配列を縦方向に順に追加・結合)|エクセル入門(2022-10-25)
HSTACK関数(配列を横方向に順に追加・結合)|エクセル入門(2022-10-25)
LAMBDA以降の新関数の問題と解説(配列操作関数編)|エクセル入門(2022-10-24)
LAMBDA以降の新関数の問題と解説(ヘルパー関数編)|エクセル入門(2022-10-24)
LAMBDA以降の新関数の問題集|エクセル入門(2022-10-24)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.RangeとCellsの使い方|VBA入門
3.変数宣言のDimとデータ型|VBA入門
4.繰り返し処理(For Next)|VBA入門
5.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
6.Excelショートカットキー一覧|Excelリファレンス
7.並べ替え(Sort)|VBA入門
8.マクロって何?VBAって何?|VBA入門
9.エクセルVBAでのシート指定方法|VBA技術解説
10.ExcelマクロVBAの基礎を学習する方法|エクセルの神髄




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。



このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
本文下部へ