エクセル関数応用
複数列の直積（デカルト積、クロスジョイン）

=LET(
    A,DROP(A:.A,1),
    B,DROP(B:.B,1),
    R_A, ROWS(A),
    R_B, ROWS(B),
    X, SEQUENCE(R_A * R_B),
    aIndex, INDEX(A, MOD(INT((X-1)/R_B), R_A) + 1),
    bIndex, INDEX(B, MOD(X-1, R_B) + 1),
    HSTACK(aIndex, bIndex)
)

=LET(
  A, DROP(A:.A,1),
  B, DROP(B:.B,1),
  C, DROP(C:.C,1),
  D, DROP(D:.D,1),
  X, SEQUENCE(ROWS(A)*ROWS(B)*ROWS(C)*ROWS(D)),
  aIndex, INDEX(A, MOD(INT((X-1)/(ROWS(B)*ROWS(C)*ROWS(D))), ROWS(A)) + 1),
  bIndex, INDEX(B, MOD(INT((X-1)/(ROWS(C)*ROWS(D))), ROWS(B)) + 1),
  cIndex, INDEX(C, MOD(INT((X-1)/ROWS(D)), ROWS(C)) + 1),
  dIndex, INDEX(D, MOD(X-1, ROWS(D)) + 1),
  HSTACK(aIndex, bIndex, cIndex, dIndex)
)

=LAMBDA(tbl,
  LET(
    cnt, BYCOL(tbl, LAMBDA(c, COUNTA(c))),
    T, PRODUCT(cnt),
    N, COLUMNS(tbl),
    Rev, INDEX(cnt, SEQUENCE(1, N, N, -1)),
    FD, HSTACK(1,DROP(SCAN(1, Rev, LAMBDA(a,v, a * v)), , -1)),
    FS, INDEX(FD, SEQUENCE(1, N, N, -1)),
    MAKEARRAY(
      T,N,
      LAMBDA(r,c,
        LET(
          X, r - 1,
          L_c, INDEX(cnt, c),
          D_c, INDEX(FS, c),
          Idx, MOD(INT(X / D_c), L_c) + 1,
          List, FILTER(INDEX(tbl, 0, c), INDEX(tbl, 0, c) <> ""),
          INDEX(List, Idx)
        )
      )
    )
  )
)(DROP(A:.D,1))

=LAMBDA(tbl,
  REDUCE(
    FILTER(TAKE(tbl,,1),TAKE(tbl,, 1)<>""),
    SEQUENCE(1,COLUMNS(tbl)-1,2),
    LAMBDA(acc,i,
      LET(
        nc,INDEX(tbl,,i),
        ncc, FILTER(nc,nc<>""),
        MAKEARRAY(
          ROWS(acc)*ROWS(ncc),
          COLUMNS(acc)+1,
          LAMBDA(r,c,
            IF(c<=COLUMNS(acc),
              INDEX(acc,QUOTIENT(r-1,ROWS(ncc))+1,c),
              INDEX(ncc, MOD(r-1,ROWS(ncc))+1,1)
            )
          )
        )
      )
    )
  )
)(DROP(A:.D,1))