VBAサンプル集
CSVの読み込み方法

ExcelマクロVBAの実用サンプル、エクセルVBA集と解説
最終更新日:2020-07-02

CSVの読み込み方法


エクセルのマクロVBAでのCSVの読込方法としては。
・テキストファイルとして読み込む
・ワークブックとして読み込む
・クエリーテーブルを使う
・ADOを使う
・Power Queryを使う
大別するとこのようになります。


この記事を書いた当初は、
エクセルのマクロVBAでCSVの読み込みについてネットで検索したところ、これなら、というのがなかなか見つかりませんでした。
そこで、エクセルのマクロVBAでのCSVの読み込みについて、ここにまとめて解説することにしました。

昨今は他システムとの連携も増えてきたこともあるのでしょう、VBAでのCSV読み込みの記事も大分増えてきました。
しかし、それぞれに一長一短もあり、正しく読めていないものも多数存在しています。
まず、ネットですぐ見つかるものから順次解説していきます。

もっとも簡単かつ良くあるCSV読み込みVBAコード

Sub CSV入力1()
  Dim varFileName As Variant
  Dim intFree As Integer
  Dim strRec As String
  Dim strSplit() As String
  Dim i As Long, j As Long


  varFileName = Application.GetOpenFilename(FileFilter:="CSVファイル(*.csv),*.csv", _
                        Title:="CSVファイルの選択")
  If varFileName = False Then
    Exit Sub
  End If

  intFree = FreeFile '空番号を取得
  Open varFileName For Input As #intFree 'CSVファィルをオープン
  
  i = 0
  Do Until EOF(intFree)
    Line Input #intFree, strRec '1行読み込み
    i = i + 1
    strSplit = Split(strRec, ",") 'カンマ区切りで配列へ
    For j = 0 To UBound(strSplit)
      Cells(i, j + 1) = strSplit(j)
    Next
    '配列をそのまま入れる方法も、ただし全て文字列として入力される
    'Range(Cells(i, 1), Cells(i, UBound(strSplit) + 1)) = strSplit
  Loop
  
  Close #intFree
End Sub


・ダイアログを表示する
・CSVファイルをオープンする
・1行ずつ読み込む
・「,」で区切って配列にする
・セルに入れる
このような流れとなっています。
セルに入れる際に、配列をまとめて入れた場合は、全て文字列として入ります。
どちらが良いかは、ケースバイケースでしょう。
また、
「Line Input」
ではなく、
「Input」
で、列数分の変数を指定しているものも見かけます。
列数が決まっている場合は、その方法も有効です。
しかし、いずれにしても不都合があります。
データの入っているエクセルをCSV出力して、
上記プログラムで取り込みしてみて下さい。
どうでしょう、同じ表が再現されたでしょうか。
もし何も問題がなかったとしたら、かなり幸運です。
,」も「"」も、データ中に存在していなかったということです。

,」「"」に対応したCSV読み込みVBAコード

,」も「"」がある場合は、上記プログラムでは処理できません。
では、これらに対処したプログラムが以下になります。

Sub CSV入力2()
  Dim varFileName As Variant
  Dim intFree As Integer
  Dim strRec As String
  Dim strSplit() As String
  Dim i As Long, j As Long, k As Long
  Dim lngQuote As Long
  Dim strCell As String


  varFileName = Application.GetOpenFilename(FileFilter:="CSVファイル(*.csv),*.csv", _
                        Title:="CSVファイルの選択")
  If varFileName = False Then
    Exit Sub
  End If

  intFree = FreeFile '空番号を取得
  Open varFileName For Input As #intFree 'CSVファィルをオープン
  
  i = 0
  Do Until EOF(intFree)
    Line Input #intFree, strRec '1行読み込み
    i = i + 1
    j = 0
    lngQuote = 0
    strCell = ""
    For k = 1 To Len(strRec)
      Select Case Mid(strRec, k, 1)
        Case "," '「"」が偶数なら区切り、奇数ならただの文字
          If lngQuote Mod 2 = 0 Then
            Call PutCell(i, j, strCell, lngQuote)
          Else
            strCell = strCell & Mid(strRec, k, 1)
          End If
        Case """" '「"」のカウントをとる
          lngQuote = lngQuote + 1
          strCell = strCell & Mid(strRec, k, 1)
        Case Else
          strCell = strCell & Mid(strRec, k, 1)
      End Select
    Next
    '最終列の処理
    Call PutCell(i, j, strCell, lngQuote)
  Loop
  Close #intFree
End Sub

Sub PutCell(ByRef i As Long, ByRef j As Long, ByRef strCell As String, ByRef lngQuote As Long)
  j = j + 1
  '「""」を「"」で置換
  strCell = Replace(strCell, """""", """")
  '前後の「"」を削除
  If Left(strCell, 1) = """" And Right(strCell, 1) = """" Then
    strCell = Mid(strCell, 2, Len(strCell) - 2)
  End If
  Cells(i, j) = strCell
  strCell = ""
  lngQuote = 0
End Sub


かなり、長いですね。
これでもかなり整理して短くしています。
これなら、ほぼCSVを正確に取り込めるはずです。
詳しい説明は省略します。
このプログラムを見て、理解できない場合は、使用しないほうがよいでしょう。

そのような方には、以下の方法を紹介します。
きわめて簡単で、間違いがない方法です。

CSVをExcelブックとして開くVBA

CSVをブックとして読み込む方法です。
ほとんどの方のPCでは、CSVをダブルクリックすれば、エクセルが起動されるはずです。
CSVはエクセルでそのまま開くことが可能です。

Sub CSV入力3()
  Dim varFileName As Variant


  varFileName = Application.GetOpenFilename(FileFilter:="CSVファイル(*.csv),*.csv", _
                    Title:="CSVファイルの選択")
  If varFileName = False Then
    Exit Sub
  End If
  
  Workbooks.Open Filename:=varFileName
  ActiveSheet.Cells.Copy ThisWorkbook.ActiveSheet.Cells
  ActiveWorkbook.Close SaveChanges:=False
End Sub


CSVをブックとして読み込み、シート全体をコピーしています。
これなら、簡単ですし、間違いなく正しく読み込めます。
入門としては、これが最もお勧めです。
この方法で一番問題となるのは、数値の頭0が消えてしまう事です。
CSVの中が、
001
だとしても、セルには
1
として入力されてしまう事です。
逆の見方をすれば、数値の頭0が消えて問題ないのなら、これで十分だという事です。
そして多くの場合、数値の頭0が消えることに問題はないでしょう。

ID等のコードが数値の場合に0で始まっている時くらいではないでしょうか。
しかし、このような場合は、IDコードの桁数は一定であることが多いので、
後からVBAまたは関数で桁数をそろえるように頭に0を埋めてやれば済むことになります。

クエリーテーブルを使ったCSV読み込みVBAコード

Sub CSV入力4()
  Dim varFileName As Variant


  varFileName = Application.GetOpenFilename(FileFilter:="CSVファイル(*.csv),*.csv", _
                    Title:="CSVファイルの選択")
  If varFileName = False Then
    Exit Sub
  End If
  
  With ActiveSheet.QueryTables.Add(Connection:="text;" & varFileName, Destination:=Range("A11"))
'    .Name = "temp"
'    .FieldNames = True
'    .RowNumbers = False
'    .FillAdjacentFormulas = False
'    .PreserveFormatting = True
'    .RefreshOnFileOpen = False
'    .RefreshStyle = xlInsertDeleteCells
'    .SavePassword = False
'    .SaveData = True
'    .AdjustColumnWidth = True
'    .RefreshPeriod = 0
'    .TextFilePromptOnRefresh = False
    .TextFilePlatform = 932 'Shift_Jis
'    .TextFileStartRow = 1
'    .TextFileParseType = xlDelimited
'    .TextFileTextQualifier = xlTextQualifierDoubleQuote
'    .TextFileConsecutiveDelimiter = False
'    .TextFileTabDelimiter = False
'    .TextFileSemicolonDelimiter = False
    .TextFileCommaDelimiter = True
'    .TextFileSpaceDelimiter = False
'    .TextFileColumnDataTypes = Array(1, 1, 1)
'    .TextFileTrailingMinusNumbers = True
    .Refresh BackgroundQuery:=False

    .Delete
  End With
End Sub


コメント行が大量にありますが、これは、CSVを読み込むだけなら、
指定の必要が無いと思われるプロパティです。
出力先のシートにデータがある場合は、
そのデータは消されずに、セル位置が移動されますので、注意してください。

文字コードがUTF8の場合
.TextFilePlatform = 65001 'UTF8
このように、932の代わりに65001を指定してください。

その他のCSV読み込み方法

どの方法を使用するかは人(組織)それぞれですし、CSVのデータ内容にもよるでしょう。
ただ、エクセルは標準でCSVを扱えますので、
ブックとして、読み込んでから処理する方法が、最もお勧めです。
何か特殊な事情があり、この方法が使えない場合のみ他の方法を考えましょう。
ただ、読み込むCSVに、「,」も「"」がないのなら、
最初のプログラムは融通が利いて、扱いやすいと思います。
以下のページでは、
上記の「CSV入力2」のVBAサンプルをさらに改造したバージョンや他の方法も紹介しています。
・改行がLF(10)にも対応したバージョン
・文字コードUTF-8にも対応したバージョン
・ADOを使用した方法
これらに対応したCSV読み込み方法について参考にしてください。

VBAでのCSVの扱い方まとめ
マクロVBAでCSVの読み書きする方法はいくつもあり、当サイトでも複数のページでそれぞれVBAコードを掲載しています。順次記事を掲載しているので、それぞれどのような特徴があるかが良く分からなくなってしまっているようです。そこで、CSVに関するページをまとめておきました。
CSVの読込方法
エクセルのVBAでのCSVの読込方法としては。・テキストファイルとして読み込む ・ワークブックとして読み込む ・クエリーテーブルを使う ・ADOを使う ・PowerQueryを使う 大別するとこのようになります。この記事を書いた当初は、エクセルのVBAでCSVの読み込みについてネットで検索したところ、
CSVの読み込み方法(改)
実施したいこと ・ファイル名を指定し、形式をカンマ区切り、文字列で開く、その際、改行コードLF、CRLF、CRいずれにも対応、セル内の","や改行についてはカラムで区切らない。掲示板で上記のリクエストを頂きました。ということで、対応ロジックを書いてみました。
CSVの読み込み方法(改の改)
CSVのVBAでの読込方法については複数の記事を掲載しており、人気記事として多くのアクセスがあります。掲載しているVBAコードは汎用的に書いてあり、ほぼそのまま使用できるものです。しかし、CSVは多くの形式(区切り文字、文字コード等)があり、今まで掲載したコードでは解決出来ないものがあります。
CSVの読み込み方法(ジャグ配列)
CSVのマクロVBAでの読込方法についての記事は、人気記事として多くのアクセスがあります。当初作成して以来、ご要望をいただいたり自身で使っている中で、対応できないCSVが出てくるたびに改良を重ねています。今回のVBAは、一旦ジャグ配列を使用したCSV読み込み方法になります。
CSVの読み込み方法(ジャグ配列)(改)
CSVのマクロVBAでの読込方法についての記事は、人気記事として多くのアクセスがあります。順次改定していくつかのバージョンが存在します。最新のジャグ配列(配列の配列)で読み込むVBAについて、UTF-8Nの文字コード判別の課題が残っていました。
CSVの出力(書き出し)方法
シート内容をCSV出力(書き出し)する方法です。CSVの読込は、VBAでのCSVの扱い方まとめ こちらを参照して下さい。以下では、2通りの方法を紹介します。エクセルの機能をそのまま利用します ※csv出力時日付がm/d/yyyyになってしまう場合の対処 日付がm/d/yyyyになってしまう場合に、yyyy/m/dにする場合には、
UTF-8でCSVの読み書き(ADODB.Stream)
VBAでUTF-8を扱う為には、ADODB.Streamを使う必要があります。以下のコードを使用するには、参照設定で、「MicrosoftActiveXDataObjects2.8Library」にチェックを付けて下さい。または、DimadoStAsNewADODB.Stream ここを DimadoStAsObject SetadoSt=CreateO…
ADOでCSVの読み込み(SQL)
VBAでADOを使用し、CSVデータを読み込みます。ADOではSQL文が必要になりますが、ここではSQL文の詳細については説明を省略します。ADO以外の方法については、「CSVの読み込み方法」を参考にして下さい。



同じテーマ「マクロVBAサンプル集」の記事

VBAでのCSVの扱い方まとめ
CSVの読み込み方法
CSVの読み込み方法(改)
CSVの読み込み方法(改の改)
CSVの読み込み方法(ジャグ配列)
CSVの読み込み方法(ジャグ配列)(改)
CSVの出力(書き出し)方法
UTF-8でCSVの読み書き(ADODB.Stream)
ADOでマスタ付加と集計(SQL)
ADOでマスタ更新(SQL)
ADOでCSVの読み込み(SQL)


新着記事NEW ・・・新着記事一覧を見る

Variantの数値型と文字列型の比較|エクセル雑感(7月1日)
VBAのVariant型について|VBA技術解説(6月30日)
VBAのString型の最大文字数について|エクセル雑感(6月20日)
VBAで表やグラフをPowerPointへ貼り付ける|VBAサンプル集(6月19日)
アクティブシート以外の表示(Window)に関する設定|VBA技術解説(6月17日)
マクロ記録での色のマイナス数値について|エクセル雑感(6月16日)
ツイッター投稿用に文字数と特定文字で区切る|エクセル雑感(6月15日)
日付の謎:IsDateとCDate|エクセル雑感(6月14日)
IFステートメントの判定|エクセル雑感(6月13日)
インクリメンタルサーチの実装|ユーザーフォーム入門(6月12日)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.RangeとCellsの使い方|VBA入門
3.変数宣言のDimとデータ型|VBA入門
4.マクロって何?VBAって何?|VBA入門
5.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
6.Range以外の指定方法(Cells,Rows,Columns)|VBA入門
7.繰り返し処理(For Next)|VBA入門
8.セルに文字を入れるとは(Range,Value)|VBA入門
9.とにかく書いてみよう(Sub,End Sub)|VBA入門
10.マクロはどこに書くの(VBEの起動)|VBA入門




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。



このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
本文下部へ