テーブル名変更と列追加（ALTER TABLE）とテーブル自動作成

公開日：2019-11-25　最終更新日：2021-04-28

テーブル名変更と列追加（ALTER TABLE）とテーブル自動作成

エクセルVBAでデータベースを扱うためのSQL入門です。
前回までにテーブルを作成したり、削除したりできるようになりました。
今回は作成したテーブルの名称変更とカラム（列）を追加するSQLを解説します。
そして、エクセルのシートにテーブル情報を記入して、そこからテーブルを自動作成するVBAも紹介します。

テーブル名変更：ALTER TABLE RENAME TO

ALTER TABLE table_name RENAME TO new_table_name

table_name を new_table_name に変更します。
SQLでテーブル名を変更できないDBもあります。


  
    
      Sub AlterTableRename()

　　Dim clsDB As New clsSQLite

　　clsDB.DataBase = "C:\SQLite3\sample.db"

　　

　　Dim sSql As String

      　　sSql = "ALTER TABLE m_customer RENAME TO m_cust"

　　If Not clsDB.ExecuteNonQuery(sSql) Then

　　　　MsgBox clsDB.ErrMsg

　　　　Exit Sub

　　End If

　　

　　Set clsDB = Nothing

End Sub

※前回までに作成したクラスを使ったVBAサンプルになります。

・データベースで使う用語や記号について・カラムのデータ型・テーブル作成：CREATE TABLE ・テーブル削除：DROP TABLE ・ADODB.ConnectionのExecuteメソッド・クラスを拡張修正・VBAでADOを使う為のクラスの全VBA ・テーブルの作成/削除の最後に

new_table_nameがすでに存在している場合はエラーになります。

カラム（列）追加：ALTER TABLE ADD COLUMN

ALTER TABLE table_name ADD [ COLUMN ] column_definition

[ COLUMN ] は省略可能です。
column_definition

列定義の基本は、列名とデータ型になりますが、型以外の各種制約をキーワードで指定できます。
詳細は前回の、テーブルの作成/削除（CREATE TABLE,DROP TABLE）を参照してください。


  
    
      Sub AlterTableAdd()

　　Dim clsDB As New clsSQLite

　　clsDB.DataBase = "C:\SQLite3\sample.db"

　　

　　Dim sSql As String

      　　sSql = "ALTER TABLE m_cust ADD COLUMN address TEXT"

　　If Not clsDB.ExecuteNonQuery(sSql) Then

　　　　MsgBox clsDB.ErrMsg

　　　　Exit Sub

　　End If

　　

　　Set clsDB = Nothing

End Sub

※COLUMNは省略可能です。

一つのALTER TABLEで複数のカラム（列）を追加することはできません。
追加するカラム（列）ごとにALTER TABLEが必要になります。


  
    
      Sub AlterTableAdd2()

　　Dim clsDB As New clsSQLite

　　clsDB.DataBase = "C:\SQLite3\sample.db"

　　

　　Dim sSql As String

      　　sSql = sSql & "ALTER TABLE m_cust ADD address2 TEXT;"

      　　sSql = sSql & "ALTER TABLE m_cust ADD address3 TEXT;"

　　If Not clsDB.ExecuteNonQuery(sSql) Then

　　　　MsgBox clsDB.ErrMsg

　　　　Exit Sub

　　End If

　　

　　Set clsDB = Nothing

End Sub

SQLでは、複数の文（コマンド）の場合は、文（コマンド）の終りとして;（セミコロン）が必要になります。

SQLの半角空白と改行とセミコロン

半角空白

キーワードの区切りとして半角空白は必ず必要です。
CREATE□TABLE□table_name□・・・

半角空白を□と表記しています。

この半角空白は複数連続していても構いません、実行に影響はありません。
CREATE□□TABLE□□table_name□・・・

また、()括弧や,カンマ、記号演算子(=や<>)の前後の半角空白はあってもなくても構いません。
CREATE TABLE m_customer(id,name)
CREATE TABLE m_customer□(□id□,□name□)
どちらの記述でも同じですので、見やすさを考えて記述してください。

改行/TAB

SQL文字列に含まれる改行(CrLf)やタブ(Tab)は半角空白と同じ効果があります。
ただし、これらは半角空白の代わりに使うというより、SQL文字列を見やすく整形する目的で適宜使用してください。

；（セミコロン）

SQLは、CREATE TABLEやALTER TABLEで一つの文（コマンド）を構成しています。
1つのコマンドは、それだけで処理が完結するように作られています。
この点が、手続き型のプログラミング言語とは大きく異なります。

文（コマンド）の最後は；（セミコロン）で終わります。
すべての文の終りの；（セミコロン）は省略できますので、1文だけの場合はセミコロンは無くても構いません。
複数の文を区切るためには必須となります。
したがって、
可能な限り文の終りとしてセミコロンを書いたほうが良いのですが、そもそも複数の文をまとめて実行すること自体そんなに多くないはずです。
したがって、あまり気にする必要性も無いと思います。

テーブル自動作成

VBAにSQLを直接書くのは、使い回しやメンテナンスの面で不便になります。
DBのGUIツール（SQLiteなら「DB Browser for SQLite」等）で見ることはでき、
そのテーブル定義から、自動でCREATE TABLEのSQLを取得することもできます。
ですが、使い勝手や管理面で、別途テーブル定義があると便利に使えます。
そこで、エクセルのワークシートにテーブル定義を記述しておき、
そのシート情報を基にCREATE TABLEのSQLが作成できると便利です。

※4行目は「折り返して全体を表示」にしています。

このようなシートを用意しておきVBAでSQLを自動作成します。


  
    
      Sub CreateTableFromSheet()

      　　Dim clsDB As New clsSQLite

      　　clsDB.DataBase = "C:\SQLite3\sample.db"

      　　

      　　Dim ws As Worksheet

      　　Dim tblName As String

      　　Dim sSql As String

      　　

      　　Set ws = ActiveSheet

      　　tblName = ws.Range("B2") 'テーブル名

      　　

      　　'テーブル削除

      　　sSql = "DROP TABLE " & tblName

      　　Call clsDB.ExecuteNonQuery(sSql)

      　　

      　　'テーブル追加

      　　sSql = CreateSql(ws, tblName)

      　　If Not clsDB.ExecuteNonQuery(sSql) Then

      　　　　MsgBox clsDB.ErrMsg

      　　　　Exit Sub

      　　End If

      　　

      　　Set clsDB = Nothing

      End Sub


      Function CreateSql(ByVal ws As Worksheet, _

      　　　　　　　　　 ByVal tblName As String) As String

      　　Const sRow As Long = 4

      　　Dim sSql As String

      　　Dim i As Long, j As Long

      　　Dim maxRow As Long, maxCol As Long

      　　Dim pkCol As Long, aiCol As Long, dfCol As Long

      　　Dim isAutoInc As Boolean, strPk As String

      　　With ws

      　　　　maxRow = .Cells(.Rows.Count, 2).End(xlUp).Row

      　　　　maxCol = .Cells(sRow, .Columns.Count).End(xlToLeft).Column

      　　　　pkCol = Application.Match("PRIMARY KEY", .Rows(sRow), 0)

      　　　　aiCol = Application.Match("AUTOINCREMENT", .Rows(sRow), 0)

      　　　　dfCol = Application.Match("DEFAULT", .Rows(sRow), 0)

      　　　　sSql = "CREATE TABLE " & tblName & " (" & vbCrLf

      　　　　For i = sRow + 1 To maxRow

      　　　　　　sSql = sSql & IIf(i = sRow + 1, " ", ",")

      　　　　　　sSql = sSql & """" & .Cells(i, 2) &
      """ " & .Cells(i, 3)

      　　　　　　If .Cells(i, aiCol) <> "" Then isAutoInc = True

      　　　　　　For j = 4 To maxCol

      　　　　　　　　If .Cells(i, j) <> "" Then

      　　　　　　　　　　If isAutoInc Or j <> pkCol Then

      　　　　　　　　　　　　sSql = sSql & " " & .Cells(sRow, j)

      　　　　　　　　　　　　If j = dfCol Then

      　　　　　　　　　　　　　　sSql = sSql & " " & .Cells(i, j)

      　　　　　　　　　　　　End If

      　　　　　　　　　　End If

      　　　　　　　　　　If Not isAutoInc And j = pkCol Then

      　　　　　　　　　　　　If strPk <> "" Then strPk = strPk & ","

      　　　　　　　　　　　　strPk = strPk & .Cells(i, 2)

      　　　　　　　　　　End If

      　　　　　　　　End If

      　　　　　　Next

      　　　　　　sSql = sSql & vbCrLf

      　　　　Next

      　　　　If strPk <> "" Then

      　　　　　　sSql = sSql & ",PRIMARY KEY (" & strPk & ")" & vbCrLf

      　　　　End If

      　　　　sSql = sSql & ");"

      　　End With

      　　CreateSql = sSql

      End Function

このVBAを実行すると、自動的にテーブルが作成されます。

CREATE TABLE t_sales (
 "id" INTEGER PRIMARY KEY AUTOINCREMENT NOT NULL
,"code" TEXT NOT NULL
,"name" TEXT NOT NULL
,"address" TEXT
,"sales_date" TEXT
,"item_code" TEXT
,"item_name" TEXT
,"item_price" INTEGER
,"item_count" INTEGER
,"item_amount" INTEGER
,"comment" TEXT
);

このようなSQL文字列を作成し、そのSQLを発行しています。
文字列は見やすくなるように改行で整形しています。

列名はダブルクオーテーションで囲んでいます。

SQLiteでは、シングルクオーテーション、バッククオーテーション等も可
MySQLであれば`バッククォート、SQL ServerやAccessは[]角括弧で囲みます。
その他のDBでは概ねダブルクオーテーションで囲みます。

複数列の主キーにも対応しています。
ただし入力チェックは行っていませんのでSQL実行時にエラーとなる場合があります。
例．AUTOINCREMENTを複数行に設定しているような場合

このシートやVBAは、あくまで最低限の項目および機能に限定したサンプルになります。
表の上部にテーブルに関する情報（見積データ件数等）を入れたり、日本語での説明文を記載しておいたりするとより良いでしょう。
全体の見栄えや、必要な管理項目については適宜工夫してお使いください。

また、SQLiteにはありませんが、他のDBではデータ長の指定が必要になります。
INT(11)
VAECHAR(100)
これらの指定をするための列も必要になってきます。

テーブル名変更と列追加とテーブル自動作成の最後に

今回までで、テーブルが自由に作成できるようになりました。
次回からいよいよSQLの本題に入っていきます。
上で紹介したシートからテーブル自動作成を用意しておくと、今後もテストが行いやすくなります。

同じテーマ「SQL入門」の記事

SQLiteのインストール
 データベースに接続/切断
 テーブルの作成/削除（CREATE TABLE,DROP TABLE）
テーブル名変更と列追加（ALTER TABLE）とテーブル自動作成
データの挿入（INSERT）と全削除
 VBAクラスの全コード：データの挿入
 データの挿入：バルクインサート
 データの取得：条件指定（SELECT,WHERE）
VBAクラスの全コード：データの取得
 データの取得：集約集計、並べ替え（DISTINCT,GROUP,HAVING,ORDER）
SQL関数と演算子

アクセスランキング・・・ランキング一覧を見る

1.最終行の取得（End,Rows.Count）｜VBA入門
2.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
3.変数宣言のDimとデータ型｜VBA入門
4.繰り返し処理（For Next)｜VBA入門
5.RangeとCellsの使い方｜VBA入門
6.ブックを閉じる・保存（Close,Save,SaveAs）｜VBA入門
7.セルのクリア（Clear,ClearContents）｜VBA入門
8.メッセージボックス(MsgBox関数)｜VBA入門
9.条件分岐（Select Case）｜VBA入門
10.ブック・シートの選択（Select,Activate）｜VBA入門

ホーム
その他
SQL入門
テーブル名変更と列追加（ALTER TABLE）とテーブル自動作成

このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。

記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。

SQL入門
テーブル名変更と列追加（ALTER TABLE）とテーブル自動作成