SQL入門
VBAクラスの全コード:データの挿入

SQLの初心者向け入門解説、VBAからデータベースを扱うためのSQLを解説
最終更新日:2019-11-27

VBAクラスの全コード:データの挿入


SQL入門の「データの挿入(INSERT)と全削除」時点のVBAクラスの全コードです。


ADOを使ったDB接続のVBAクラスの全コード

クラスモジュール:clsSQLite



Option Explicit

'DB接続情報の定数
Private Const defConStr As String = "DRIVER=【DRIVER】;Database=【DATABASE】"
Private Const defDriver As String = "SQLite3 ODBC Driver"

'DB接続情報
Private pAdoCon As ADODB.Connection
Private pAdoCmd As ADODB.Command
Private pConStr As String
Private pDataBase As String
Private pDriver As String

'エラー情報
Private pErrNum As Long
Private pErrMsg As String
Private pErrPrc As String

'エラー情報プロパティ
Public Property Get ErrNum() As Long
  ErrNum = pErrNum
End Property
Public Property Get ErrMsg() As String
  ErrMsg = pErrMsg
End Property
Public Property Get ErrPrc() As String
  ErrPrc = pErrPrc
End Property

'DB接続設定プロパティ
Public Property Set AdoCon(arg As ADODB.Connection)
  Set pAdoCon = arg
End Property
Public Property Get AdoCon() As ADODB.Connection
  Set AdoCon = pAdoCon
End Property
Public Property Set AdoCmd(arg As ADODB.Command)
  Set pAdoCmd = arg
End Property
Public Property Get AdoCmd() As ADODB.Command
  Set AdoCmd = pAdoCmd
End Property
Public Property Let ConStr(arg As String)
  pConStr = arg
End Property
Public Property Get ConStr() As String
  ConStr = pConStr
End Property
Public Property Let DataBase(arg As String)
  pDataBase = arg
End Property
Public Property Get DataBase() As String
  DataBase = pDataBase
End Property
Public Property Let Driver(arg As String)
  pDriver = arg
End Property
Public Property Get Driver() As String
  Driver = pDriver
End Property

'CommandにSQLを設定
Public Function SetCommandText(sSql As String) As Boolean
  On Error GoTo Err_Exit
  
  Set Me.AdoCmd = New ADODB.Command
  Set Me.AdoCmd.ActiveConnection = Me.AdoCon
  Me.AdoCmd.CommandText = sSql
  
  SetCommandText = True
  Call resetErr
  Exit Function
  
Err_Exit:
  SetCommandText = False
  Call setErr(Err, "SetCommandText")
End Function

'SQL実行:CommandのParametersを使用
Public Function ExecuteCommand(vParam As Variant) As Boolean
  On Error GoTo Err_Exit
  
  Call Me.AdoCmd.Execute(Parameters:=vParam)
  
  ExecuteCommand = True
  Call resetErr
  Exit Function
  
Err_Exit:
  ExecuteCommand = False
  Call setErr(Err, "ExecuteCommand")
End Function

'SQL実行:影響を受けたレコード数を戻す
Public Function ExecuteNonQuery(sSql As String, _
                Optional RecordsAffected As Long) _
                As Boolean
  On Error GoTo Err_Exit
  
  '接続状態の退避と接続
  Dim isConnect As Boolean
  If Not Me.AdoCon Is Nothing Then isConnect = CBool(Me.AdoCon.State)
  If Not Me.DbOpen Then Exit Function
  
  'SQLの発行
  Call Me.AdoCon.Execute(sSql, RecordsAffected)
  
  '当初接続されていなかった時は切断
  If Not isConnect Then
    If Not Me.DbClose Then Exit Function
  End If
  
  ExecuteNonQuery = True
  Call resetErr
  Exit Function
  
Err_Exit:
  ExecuteNonQuery = False
  Call setErr(Err, "ExecuteNonQuery")
End Function

'SQL実行:レコードセットを戻す
Public Function ExecuteRecordset(sSql As String, _
                 adoRs As ADODB.Recordset) _
            As Boolean
  On Error GoTo Err_Exit
  
  '接続されていない場合は接続
  If Not Me.DbOpen Then Exit Function
  
  'SQLの発行
  Set adoRs = AdoCon.Execute(sSql)
  
  ExecuteRecordset = True
  Call resetErr
  Exit Function
  
Err_Exit:
  ExecuteRecordset = False
  Call setErr(Err, "ExecuteRecordset")
End Function

'DB接続
Public Function DbOpen() As Boolean
  On Error GoTo Err_Exit
  DbOpen = True
    
  '既に接続してたら無視
  If Not Me.AdoCon Is Nothing Then
    If Me.AdoCon.State = ObjectStateEnum.adStateOpen Then
      Exit Function
    End If
  End If
  
  'SQLiteに接続
  Set Me.AdoCon = New ADODB.Connection
  Me.AdoCon.Open getConStr
  
  Call resetErr
  Exit Function
  
Err_Exit:
  DbOpen = False
  Call setErr(Err, "dbOpen")
End Function

'DB切断
Public Function DbClose() As Boolean
  On Error GoTo Err_Exit
  DbClose = True
  
  '既に切断されていたら無視
  If Me.AdoCon Is Nothing Then Exit Function
  If Me.AdoCon.State = ObjectStateEnum.adStateClosed Then Exit Function
  
  'SQLiteを切断
  Me.AdoCon.Close
  
  Call resetErr
  Exit Function
  
Err_Exit:
  DbClose = False
  Call setErr(Err, "dbOpen")
End Function

'初期処理
Private Sub Class_Initialize()
  Me.Driver = defDriver
  Me.ConStr = defConStr
End Sub

'終了処理
Private Sub Class_Terminate()
  Call Me.DbClose
End Sub

'DB接続文字列
Private Function getConStr() As String
  getConStr = Me.ConStr
  getConStr = Replace(getConStr, "【DRIVER】", Me.Driver)
  getConStr = Replace(getConStr, "【DATABASE】", Me.DataBase)
End Function

'エラー情報設定
Private Sub setErr(objErr As ErrObject, _
          ErrPrc As String)
  pErrNum = objErr.Number
  pErrMsg = objErr.Description
  pErrPrc = ErrPrc
End Sub
'エラー情報クリア
Private Sub resetErr()
  pErrNum = 0
  pErrMsg = ""
  pErrPrc = ""
End Sub





同じテーマ「SQL入門」の記事

データの取得:条件指定(SELECT,WHERE)
データの取得:集約集計、並べ替え(DISTINKT,GROUP,HAVING,ORDER)
SQL関数と演算子
データベースにおけるNULLの扱い方
データベースの正規化とマスタの作成
テーブルを結合して取得(INNER JOIN,OUTER JOIN)
複数のSELECT結果を統合(UNION,UNION ALL)
データの更新(UPDATE)
データの削除(DELETE)
他のテーブルを基にデータを追加/更新/削除
VBAクラスの全コード:データの取得


新着記事NEW ・・・新着記事一覧を見る

他のテーブルを基にデータを追加/更新/削除|SQL入門(12月8日)
データの削除(DELETE)|SQL入門(12月7日)
データの更新(UPDATE)|SQL入門(12月6日)
複数のSELECT結果を統合(UNION,UNION ALL)|SQL入門(12月5日)
テーブルを結合して取得(INNER JOIN,OUTER JOIN)|SQL入門(12月4日)
データベースの正規化とマスタの作成|SQL入門(12月3日)
データベースにおけるNULLの扱い方|SQL入門(12月2日)
オブジェクト変数とは何か|VBA技術解説(12月2日)
SQL関数と演算子|SQL入門(12月1日)
データの取得:集約集計、並べ替え(DISTINKT,GROUP,HAVING,ORDER)|SQL入門(11月30日)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
3.RangeとCellsの使い方|VBA入門
4.Range以外の指定方法(Cells,Rows,Columns)|VBA入門
5.変数宣言のDimとデータ型|VBA入門
6.繰り返し処理(For Next)|VBA入門
7.マクロって何?VBAって何?|VBA入門
8.セルに文字を入れるとは(Range,Value)|VBA入門
9.空白セルを正しく判定する方法(IsEmpty,IsError,HasFormula)|VBA技術解説
10.ひらがな⇔カタカナの変換|エクセル基本操作



  • >
  • >
  • >
  • VBAクラスの全コード:データの挿入

  • このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


    記述には細心の注意をしたつもりですが、
    間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
    掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
    掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。



    このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
    本文下部へ