VBAサンプル集
Excelファイルを開かずにシート名をチェック

Private Function SheetExist(ByVal sFile As String, ByVal sName As String) As Boolean
　　Dim objCn As New ADODB.Connection
　　Dim objRS As ADODB.Recordset
　　Dim sSheet As String
　　
　　SheetExist = False
　　
　　On Error Resume Next
　　With objCn
　　　　.Provider = "Microsoft.ACE.OLEDB.12.0"
　　　　.Properties("Extended Properties") = "Excel 12.0"
　　　　.Open sFile
　　　　Set objRS = .OpenSchema(ADODB.adSchemaTables)
　　End With
　　If Err.Number = 0 Then
　　　　sName = Replace(sName, "!", "_")
　　　　sName = Replace(sName, ".", "#")
　　　　Do Until objRS.EOF
　　　　　　sSheet = objRS.Fields("TABLE_NAME").Value
　　　　　　If Right(sSheet, 1) = "$" Or Right(sSheet, 2) = "$'" Then
　　　　　　　　If Right(sSheet, 1) = "$" Then
　　　　　　　　　　sSheet = Left(sSheet, Len(sSheet) - 1)
　　　　　　　　End If
　　　　　　　　If Right(sSheet, 2) = "$'" Then
　　　　　　　　　　sSheet = Left(sSheet, Len(sSheet) - 2)
　　　　　　　　End If
　　　　　　　　If Left(sSheet, 1) = "'" Then
　　　　　　　　　　sSheet = Mid(sSheet, 2)
　　　　　　　　End If
　　　　　　　　sSheet = Replace(sSheet, "''", "'")
　　　　　　　　If sName = sSheet Then
　　　　　　　　　　SheetExist = True
　　　　　　　　　　Exit Do
　　　　　　　　End If
　　　　　　End If
　　　　　　objRS.MoveNext
　　　　Loop
　　End If
　
　　objRS.Close
　　objCn.Close
　　Set objRS = Nothing
　　Set objCn = Nothing
　　On Error GoTo 0
End Function