Excel将棋:駒台クラスの作成&単体テスト(№5)

Excelで将棋を作ってみましょう。
人vs人で動かしてゲームとして成立するところまでが当面の目標です。
作成するクラス全体の設計は、№2. Excel将棋:クラスの設計、こちらを参照してください。
※クラス名、プロシージャー名、変数名に日本語を使用しています。
日本語を適宜使う事は、
VBAを読むときの手助けとしては、コメントをダラダラと書くより、はるかに助けになると思います。
仕事で使うVBAでは、あまり日本語は使用しないのですが、
今回はVBAの勉強材料としてのゲーム作成という事で日本語を使っていきます。
駒クラス
駒クラスの設計
種別 | 名称 | 説明 |
プロパティ | 駒台一覧 | 金,1;歩,3 |
メソッド | 駒追加 | オブジェクトで追加 |
メソッド | 駒削除 | 名称で削除 |
駒クラスのVBA
Option Explicit
Private Type t駒台
正式名称 As String
表示名称 As String
個数 As Integer
End Type
Private pAry駒台(1 To 7) As t駒台
Private pCol駒台 As Collection
Private Sub Class_Initialize()
Set pCol駒台 = New Collection
End Sub
Public Sub 駒追加(ByVal arg駒 As cls駒)
With arg駒
pAry駒台(.表示順).正式名称 = .正式名称
pAry駒台(.表示順).表示名称 = .表示名称
pAry駒台(.表示順).個数 = pAry駒台(.表示順).個数 + 1
End With
'履歴保存
pCol駒台.Add Me.駒台一覧
End Sub
Public Sub 駒削除(ByVal arg駒 As Variant)
Dim str駒名 As String
'オブジェクトの指定と文字列指定の両方をサポート
If IsObject(arg駒) Then 'Objectはcls駒のみ
str駒名 = arg駒.表示名称
Else
str駒名 = arg駒
End If
'名称一致で駒台を探す
Dim i As Long
For i = LBound(pAry駒台) To UBound(pAry駒台)
If pAry駒台(i).正式名称 = str駒名 Or _
pAry駒台(i).表示名称 = str駒名 Then
pAry駒台(i).個数 = pAry駒台(i).個数 - 1
Exit For
End If
Next
'履歴保存
pCol駒台.Add Me.駒台一覧
End Sub
Public Function 駒台一覧() As Variant()
駒台一覧 = ArrayCompress(pAry駒台)
End Function
'駒台の配列(1 To 7)の使っていない要素を圧縮します
Private Function ArrayCompress(ByRef argAry() As t駒台) As Variant()
Dim ary() As Variant
ReDim ary(LBound(argAry) To UBound(argAry), 1 To 2)
Dim i1 As Long, i2 As Long
For i1 = LBound(argAry) To UBound(argAry)
If argAry(i1).個数 > 0 Then
i2 = i2 + 1
ary(i2, 1) = argAry(i1).表示名称
ary(i2, 2) = argAry(i1).個数
End If
Next
ArrayCompress = ary
End Function
駒台クラスVBAの解説
ユーザー定義型とCollectionの使い方くらいでしょうか。
ユーザー定義型(構造体)
これは、このクラス内でしか使わないので、特にユーザー定義型の制限を苦にしなくても大丈夫です。
Collection
駒台クラスのテストVBAコード
Sub test2()
Const 先手 As Boolean = True
Const 後手 As Boolean = False
Dim obj駒台 As New cls駒台
Dim obj駒 As cls駒
Set obj駒 = New cls駒
Call obj駒台.駒追加(obj駒.駒作成("金将", 先手))
Set obj駒 = New cls駒
Call obj駒台.駒追加(obj駒.駒作成("歩兵", 先手))
Set obj駒 = New cls駒
Call obj駒台.駒追加(obj駒.駒作成("金将", 先手))
Set obj駒 = New cls駒
Call obj駒台.駒追加(obj駒.駒作成("歩兵", 先手))
Set obj駒 = New cls駒
Call obj駒台.駒追加(obj駒.駒作成("銀将", 先手))
Call obj駒台.駒削除("金")
Call PrintArray(obj駒台.駒台一覧, ":")
End Sub
Sub PrintArray(ByRef ary, Optional separator As String = "")
Dim i As Long, j As Long, str As String
For i = LBound(ary, 1) To UBound(ary, 1)
str = ""
For j = LBound(ary, 2) To UBound(ary, 2)
If j > LBound(ary, 2) Then str = str & separator
str = str & ary(i, j)
Next
Debug.Print str
Next
End Sub
駒台に、以下の順番で出し入れしています。
金 ← 追加
歩 ← 追加
金 ← 追加
歩 ← 追加
銀 ← 追加
金 ← 削除
駒クラスのテストVBAの結果
金:1
銀:1
歩:2
:
:
:
:
Excel将棋の目次
新着記事NEW ・・・新着記事一覧を見る
AI時代におけるRPAとVBAの位置づけ - 補完技術としての役割と未来 -|生成AI活用研究(2025-05-12)
スマートExcel|AI×Excel:AIと進化するExcelの新常識|生成AI活用研究(2025-05-11)
VBA開発の現場で生成AIはどう使う? そのメリットと潜むリスク|生成AI活用研究(2025-05-11)
CursorでVBAを直接?編集・実行できる環境構築について|生成AI活用研究(2025-05-10)
Geminiと100本ノック 17本目:重複削除(ユニーク化)|生成AI活用研究(5月10日)
Geminiと100本ノック 16本目:無駄な改行を削除|生成AI活用研究(5月6日)
AIがあればVBAはできる:セルに絵文字を入れる|生成AI活用研究(2025-05-07)
Geminiと100本ノック 15本目:シートの並べ替え|生成AI活用研究(5月6日)
Geminiと100本ノック 14本目:社外秘シート削除|生成AI活用研究(5月4日)
Geminiと100本ノック 13本目:文字列の部分フォント|生成AI活用研究(5月4日)
アクセスランキング ・・・ ランキング一覧を見る
1.最終行の取得(End,Rows.Count)|VBA入門
2.繰り返し処理(For Next)|VBA入門
3.変数宣言のDimとデータ型|VBA入門
4.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
5.ひらがな⇔カタカナの変換|エクセル基本操作
6.RangeとCellsの使い方|VBA入門
7.メッセージボックス(MsgBox関数)|VBA入門
8.セルのクリア(Clear,ClearContents)|VBA入門
9.FILTER関数(範囲をフィルター処理)|エクセル入門
10.条件分岐(Select Case)|VBA入門
- ホーム
- マクロVBA応用編
- マクロVBAサンプル集
- Excel将棋:駒台クラスの作成&単体テスト(№5)
このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。