Excel将棋：将棋進行クラスの作成(№8)

公開日：2013年5月以前　最終更新日：2020-08-31

Excel将棋：将棋進行クラスの作成(№8)

Excelで将棋を作ってみましょう。
人vs人で動かしてゲームとして成立するところまでが当面の目標です。

今回は、シートとやり取りする将棋進行クラスを作成します。
ここまでは、作成したクラスのテスト実行用のVBAを別途作成し、
結果をイミディエイトウィンドウに表示して確認していました。
単体テストとして、このような過程は必要なものですが、いかんせんテストが大変です。
今回作成する将棋進行クラスが出来上がれば、今後はシート操作で実行結果を確認できるようになります。
作成するクラス全体の設計は、№2. Excel将棋：クラスの設計、こちらを参照してください。

・作成するクラスの役割と作成順・作成するクラスのメンバー一覧・駒の移動の定義・Excel将棋の目次

※クラス名、プロシージャー名、変数名に日本語を使用しています。

将棋進行クラス

将棋進行クラスの設計

種別	名称	説明
プロパティ	将棋盤	シートのRange
プロパティ	先手持駒	シートのRange
プロパティ	後手持駒	シートのRange
プロパティ	先手消費時間	シートのRange
プロパティ	後手消費時間	シートのRange
プロパティ	手数	シートのRange
プロパティ	棋譜	シートのRange
プロパティ	将棋盤色	シートのRange
プロパティ	駒選択色	シートのRange
メソッド	駒配置	駒を並べる「大橋流」でアニメーションさせたい
メソッド	駒選択	選択駒の移動可能セルの協調表示既に選択されている場合は解除
メソッド	着手	引数(元位置, 先位置, 駒名) 元位置：-1,-1は初期配置元位置：0,0は駒台から反則（禁じ手）等の判定を行い、禁じ手の場合はFalseを返す相手の駒を取る場合は駒台へ追加駒台から打った場合は駒台から削除シート全体の更新
メソッド	盤面表示	盤面の2次元配列をシートに表示する 2次元配列はcls将棋盤の現在盤面で取得する
メソッド	終局判定	これは結構難しい・・・持駒を含めた全ての駒を使って受けがないかの判定

このような計画でいましたが、標準モジュールから呼び出すプロシージャーとして、
「ゲーム開始」
これをPublicで作成し、他は全てPrivateで作成することにしました。
してがって、プロパティも特に必要なくなったので、上記プロパティはPrivate変数にします。

また、初回の Excel将棋：マクロVBAの学習用、こちらで作成したシート作成も、このクラスに入れてしまいます。

・Excel将棋の要件定義・Excel将棋のシート作成・Excel将棋の目次

これにより、標準モジュールでは、
・cls将棋進行のインスタンス作成
・ゲーム開始メソッドのCall
これだけになります。

将棋進行クラスのVBA

クラス名称：cls将棋進行


  
    
      Option Explicit


Private Declare PtrSafe Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)


'イベント用

Private WithEvents xlApp As Excel.Application

Private p前回選択 As Range

Private p今回選択 As Range


'Excel将棋の書くオブジェクト

Private obj将棋盤 As cls将棋盤

Private obj先手駒台 As cls駒台

Private obj後手駒台 As cls駒台


'シートおよび名前定義の設定

Private pWs As Worksheet

Private p開始位置 As Range

Private p将棋盤 As Range

Private p先手持駒 As Range

Private p後手持駒 As Range

Private p先手消費時間 As Range

Private p後手消費時間 As Range

Private p手数 As Range

Private p棋譜 As Range

Private p将棋盤色 As Range

Private p駒選択色 As Range


'先手後手の定数

Private Const c先手 As Boolean = True

Private Const c後手 As Boolean = False


'**********************************************************************

' 公開メソッド：起動するゲーム開始だけ、他はイベントで処理

'**********************************************************************


Public Sub ゲーム開始()

　　Dim flgNew As Boolean

　　On Error Resume Next

　　Set p開始位置 = ActiveSheet.Range("開始駒位置")

　　If Err Then

　　　　Err.Clear

　　　　Set p開始位置 = Application.InputBox(prompt:="将棋盤を作成するシートの作成開始左上をクリックしてください。" & vbLf & _

　　　　　　　　　　　　　　　　　　　　 "※シートは全消去されます。", _

　　　　　　　　　　　　　　　　　　　　 Title:="作成シート選択", _

　　　　　　　　　　　　　　　　　　　　 Type:=8)

　　　　If Err Then

　　　　　　Exit Sub

　　　　End If

　　　　flgNew = True

　　Else

　　　　flgNew = False

　　End If

　　On Error GoTo 0


　　Application.Cursor = xlWait

　　Set xlApp = Nothing

　　Application.Goto p開始位置

　　Set pWs = p開始位置.Worksheet

　　

　　Application.ScreenUpdating = False

　　If flgNew Then

　　　　pWs.Cells.Clear

　　　　ActiveWindow.DisplayGridlines = False

　　　　pWs.Names.Add Name:="開始駒位置", RefersToLocal:=p開始位置

　　　　Call シート名前定義

　　　　Call シート書式設定

　　Else

　　　　Call シート名前定義

　　　　p将棋盤.ClearContents

　　　　p先手持駒.ClearContents

　　　　p後手持駒.ClearContents

　　　　p先手消費時間.ClearContents

　　　　p後手消費時間.ClearContents

　　　　p手数.ClearContents

　　　　p棋譜.ClearContents

　　　　p将棋盤.Interior.Color = p将棋盤色.Interior.Color

　　End If

　　Application.ScreenUpdating = True

　　

　　Call 駒配置

　　Set xlApp = p開始位置.Application

　　Application.Cursor = xlDefault

End Sub


'**********************************************************************

' イベント

'**********************************************************************


Private Sub Class_Initialize()

　　Set obj将棋盤 = New cls将棋盤

　　Set obj先手駒台 = New cls駒台

　　Set obj後手駒台 = New cls駒台

End Sub


Private Sub Class_Terminate()

　　Set xlApp = Nothing

　　Set obj将棋盤 = Nothing

　　Set obj先手駒台 = Nothing

　　Set obj後手駒台 = Nothing

End Sub


'WithEventsのxlAppのイベント

Private Sub xlApp_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)

　　On Error Resume Next 'VBA作成中に意図せず出るエラー対応

　　If p将棋盤 Is Nothing Then Exit Sub

　　If Not Sh Is p将棋盤.Worksheet Then Exit Sub

　　If Intersect(p将棋盤, Target.Item(1)) Is Nothing Then Exit Sub

　　If Err Then Exit Sub

　　

　　xlApp.EnableEvents = False

　　xlApp.Goto p手数

　　xlApp.EnableEvents = True

　　

　　Set p前回選択 = p今回選択

　　Set p今回選択 = Target.Item(1)

　　

　　If Not (p前回選択 Is Nothing Or p今回選択 Is Nothing) Then

　　　　If p前回選択.Address = p今回選択.Address Then

　　　　　　Call 駒選択(p今回選択, False)

　　　　　　Exit Sub

　　　　End If

　　End If

　　Call 駒選択(p今回選択, True)

　　

　　Call 着手(p前回選択, p今回選択)

End Sub


'**********************************************************************

' 非公開メソッド

'**********************************************************************


'大橋流でゆっくり駒を並べます。

Private Sub 駒配置()

　　Dim ary駒配置

　　ary駒配置 = Array( _

　　　　　　　　Array(5, 9, "玉", c先手), Array(5, 1, "玉", c後手), _

　　　　　　　　Array(6, 9, "金", c先手), Array(4, 1, "金", c後手), _

　　　　　　　　Array(4, 9, "金", c先手), Array(6, 1, "金", c後手), _

　　　　　　　　Array(7, 9, "銀", c先手), Array(3, 1, "銀", c後手), _

　　　　　　　　Array(3, 9, "銀", c先手), Array(7, 1, "銀", c後手), _

　　　　　　　　Array(8, 9, "桂", c先手), Array(2, 1, "桂", c後手), _

　　　　　　　　Array(2, 9, "桂", c先手), Array(8, 1, "桂", c後手), _

　　　　　　　　Array(9, 9, "香", c先手), Array(1, 1, "香", c後手), _

　　　　　　　　Array(1, 9, "香", c先手), Array(9, 1, "香", c後手), _

　　　　　　　　Array(8, 8, "角", c先手), Array(2, 2, "角", c後手), _

　　　　　　　　Array(2, 8, "飛", c先手), Array(8, 2, "飛", c後手), _

　　　　　　　　Array(5, 7, "歩", c先手), Array(5, 3, "歩", c後手), _

　　　　　　　　Array(6, 7, "歩", c先手), Array(4, 3, "歩", c後手), _

　　　　　　　　Array(4, 7, "歩", c先手), Array(6, 3, "歩", c後手), _

　　　　　　　　Array(7, 7, "歩", c先手), Array(3, 3, "歩", c後手), _

　　　　　　　　Array(3, 7, "歩", c先手), Array(7, 3, "歩", c後手), _

　　　　　　　　Array(8, 7, "歩", c先手), Array(2, 3, "歩", c後手), _

　　　　　　　　Array(2, 7, "歩", c先手), Array(8, 3, "歩", c後手), _

　　　　　　　　Array(9, 7, "歩", c先手), Array(1, 3, "歩", c後手), _

　　　　　　　　Array(1, 7, "歩", c先手), Array(9, 3, "歩", c後手))

　　DoEvents

　　Sleep 500

　　

　　Dim i As Long, j As Long

　　With obj将棋盤

　　　　For i = LBound(ary駒配置) To UBound(ary駒配置)

　　　　　　.着手 ary駒配置(i)(2), Nothing, 棋譜位置(ary駒配置(i)(0), ary駒配置(i)(1)), ary駒配置(i)(3)

　　　　　　Call 盤面表示(obj将棋盤.現在盤面, obj先手駒台.駒台一覧, obj後手駒台.駒台一覧)

　　　　　　DoEvents

　　　　　　Sleep 100

　　　　Next

　　End With

End Sub


'棋譜の筋・段を配列の行・列に変換

Private Function 棋譜位置(ByVal arg列 As Integer, ByVal arg行 As Integer) As g位置

　　Set 棋譜位置 = g位置(arg行, 10 - arg列)

End Function


'盤内を選択した時に駒選択と移動可能位置の色設定を行う

Private Sub 駒選択(ByVal argRng As Range, _

　　　　　　　　　ByVal is選択 As Boolean)

　　If argRng Is Nothing Then Exit Sub

　　

　　p将棋盤.Interior.Color = p将棋盤色.Interior.Color

　　

　　If Not is選択 Then Exit Sub

　　If argRng.Value = "" Then Exit Sub

　　

　　argRng.Interior.Color = p駒選択色.Interior.Color

　　

　　'クリックセル → 盤面配列位置 → 移動可能位置取得 → シートに色設定

　　Call 駒移動可能位置色変更(obj将棋盤.駒移動可能位置(セル2配列位置(argRng)))

End Sub


'セル選択位置を配列の位置に変換

Private Function セル2配列位置(ByVal argRng As Range) As g位置

　　Dim r As Long, c As Long

　　r = argRng.Row - p将棋盤.Row + 1

　　c = argRng.Column - p将棋盤.Column + 1

　　Set セル2配列位置 = g位置(r, c)

End Function


'駒を選択した時に駒の移動可能位置の色設定を行う

Private Sub 駒移動可能位置色変更(ByVal argCol As Collection)

　　If argCol Is Nothing Then Exit Sub

　　Dim tmp位置 As g位置

　　For Each tmp位置 In argCol

　　　　p将棋盤.Resize(1, 1).Offset(tmp位置.行 - 1, tmp位置.列 - 1).Interior.Color = p駒選択色.Interior.Color

　　Next

End Sub


'盤面配列をシートに表示する

Private Sub 盤面表示(ByRef arg盤面() As String, _

　　　　　　　　　　 ByRef arg先手駒台() As Variant, _

　　　　　　　　　　 ByRef arg後手駒台() As Variant)

　　Dim i As Long, j As Long

　　

　　'将棋盤

　　For i = 1 To 9

　　　　For j = 1 To 9

　　　　　　If p将棋盤(i, j) <> Left(arg盤面(i, j), 1) Then

　　　　　　　　If p将棋盤(i, j).Value <> Trim(Left(arg盤面(i, j), 1)) Then

　　　　　　　　　　p将棋盤(i, j).Value = Trim(Left(arg盤面(i, j), 1))

　　　　　　　　End If

　　　　　　End If

　　　　　　If IIf(p将棋盤(i, j).Orientation = xlUpward, "↓", "↑") <> Right(arg盤面(i, j), 1) Then

　　　　　　　　If p将棋盤(i, j).Orientation <> IIf(Right(arg盤面(i, j), 1) = "↓", xlUpward, xlHorizontal) Then

　　　　　　　　　　p将棋盤(i, j).Orientation = IIf(Right(arg盤面(i, j), 1) = "↓", xlUpward, xlHorizontal)

　　　　　　　　End If

　　　　　　End If

　　　　Next

　　Next

　　

      　　'先手持駒 ※駒を取る機能と合わせて実装※

　　

      　　'後手持駒 ※駒を取る機能と合わせて実装※

　　

End Sub


'駒選択後に移動可能位置を選択したら着手します

Private Sub 着手(元位置, 先位置)

      　　'※次回作成※

End Sub


'玉の詰み判定し、詰んでいれば終局

Private Function 終局判定() As Boolean

　　'※※※これは難しいので後回し※※※

　　'cls将棋盤の終局判定を使用する

End Function


'**********************************************************************

' シート設定：名前定義と書式設定

'**********************************************************************


Private Sub シート名前定義()

　　With pWs

　　　　.Names.Add Name:="将棋盤", RefersToLocal:=p開始位置.Offset(4, 5).Resize(9, 9)

　　　　.Names.Add Name:="先手持駒", RefersToLocal:=p開始位置.Offset(6, 16).Resize(7, 2)

　　　　.Names.Add Name:="先手消費時間", RefersToLocal:=p開始位置.Offset(15, 12).Resize(1, 2)

　　　　.Names.Add Name:="後手持駒", RefersToLocal:=p開始位置.Offset(4, 1).Resize(7, 2)

　　　　.Names.Add Name:="後手消費時間", RefersToLocal:=p開始位置.Offset(1, 6).Resize(1, 2)

　　　　.Names.Add Name:="手数", RefersToLocal:=p開始位置.Offset(15, 5)

　　　　.Names.Add Name:="棋譜", RefersToLocal:=p開始位置.Offset(15, 6).Resize(1, 3)

　　　　.Names.Add Name:="将棋盤色", RefersToLocal:=p開始位置.Offset(0, 18)

　　　　.Names.Add Name:="駒選択色", RefersToLocal:=p開始位置.Offset(1, 18)

　　　　Set p将棋盤 = .Range("将棋盤")

　　　　Set p先手持駒 = .Range("先手持駒")

　　　　Set p先手消費時間 = .Range("先手消費時間")

　　　　Set p後手持駒 = .Range("後手持駒")

　　　　Set p後手消費時間 = .Range("後手消費時間")

　　　　Set p手数 = .Range("手数")

　　　　Set p棋譜 = .Range("棋譜")

　　　　Set p将棋盤色 = .Range("将棋盤色")

　　　　Set p駒選択色 = .Range("駒選択色")

　　End With

End Sub


Private Sub シート書式設定()

　　'列幅行高設定()

　　With p開始位置.EntireColumn

　　　　.Offset(, 0).ColumnWidth = 2.4

　　　　.Offset(, 1).ColumnWidth = 2.4

　　　　.Offset(, 2).ColumnWidth = 4

　　　　.Offset(, 3).ColumnWidth = 0.47

　　　　.Offset(, 4).ColumnWidth = 1.6

　　　　.Offset(, 5).Resize(, 9).ColumnWidth = 4

　　　　.Offset(, 14).ColumnWidth = 1.6

　　　　.Offset(, 15).ColumnWidth = 0.47

　　　　.Offset(, 16).ColumnWidth = 4

　　　　.Offset(, 17).ColumnWidth = 2.4

　　　　.Offset(, 18).ColumnWidth = 2.4

　　End With

　　With p開始位置.EntireRow

　　　　.Offset(0).Resize(17).RowHeight = 18

　　　　.Offset(2).RowHeight = 4.8

　　　　.Offset(3).RowHeight = 13.8

　　　　.Offset(4).Resize(9).RowHeight = 28.2

　　　　.Offset(13).RowHeight = 13.8

　　　　.Offset(14).RowHeight = 4.8

　　End With


　　'セル結合設定()

　　With pWs

　　　　.Range("後手消費時間").Merge

　　　　.Range("先手消費時間").Merge

　　　　.Range("棋譜").Merge

　　End With


　　'セル書式設定()

　　With p将棋盤色

　　　　.Interior.Color = RGB(255, 222, 117)

　　　　.BorderAround LineStyle:=xlContinuous

　　End With

　　With p駒選択色

　　　　.Interior.Color = RGB(252, 228, 217)

　　　　.BorderAround LineStyle:=xlContinuous

　　End With

　　With p開始位置

　　　　.Resize(17, 19).BorderAround LineStyle:=xlContinuous

　　End With

　　With p将棋盤

　　　　.Offset(-1, -1).Resize(11, 11).BorderAround LineStyle:=xlContinuous, Weight:=xlThick

　　　　.Offset(-1, -1).Resize(11, 11).Interior.Color = p将棋盤色.Interior.Color

　　　　.Borders.LineStyle = xlContinuous

　　　　.Font.Name = "AR教科書体M"

　　　　.Font.Size = 20

　　　　.Font.Bold = True

　　　　.HorizontalAlignment = xlCenter

　　　　.Resize(3).Font.Name = "@AR教科書体M" '後手陣のみ

　　　　.Resize(3).Orientation = xlUpward '後手陣のみ

　　　　.Offset(-1).Resize(1).Font.Name = "ＭＳ Ｐゴシック"

　　　　.Offset(-1).Resize(1).Font.Size = 8

　　　　.Offset(-1).Resize(1).HorizontalAlignment = xlCenter

　　　　.Offset(-1).Resize(1).VerticalAlignment = xlCenter

　　　　.Offset(, 9).Resize(, 1).Font.Name = "ＭＳ Ｐゴシック"

　　　　.Offset(, 9).Resize(, 1).Font.Size = 8

　　　　.Offset(, 9).Resize(, 1).HorizontalAlignment = xlCenter

　　　　.Offset(, 9).Resize(, 1).VerticalAlignment = xlCenter

　　End With

　　With p先手持駒

　　　　.BorderAround LineStyle:=xlContinuous

　　　　.Interior.Color = p将棋盤色.Interior.Color

　　　　.Offset(, 0).Resize(, 1).Font.Name = "AR教科書体M"

　　　　.Offset(, 0).Resize(, 1).Font.Size = 20

　　　　.Offset(, 0).Resize(, 1).Font.Bold = True

　　　　.Offset(, 0).Resize(, 1).HorizontalAlignment = xlCenter

　　　　.Offset(, 1).Resize(, 1).Font.Name = "ＭＳ Ｐゴシック"

　　　　.Offset(, 1).Resize(, 1).Font.Size = 11

　　　　.Offset(, 1).Resize(, 1).Font.Bold = True

　　　　.Offset(, 1).Resize(, 1).HorizontalAlignment = xlLeft

　　End With

　　With p後手持駒

　　　　.BorderAround LineStyle:=xlContinuous

　　　　.Interior.Color = p将棋盤色.Interior.Color

　　　　.Offset(, 1).Resize(, 1).Font.Name = "@AR教科書体M"

　　　　.Offset(, 1).Resize(, 1).Orientation = xlUpward

　　　　.Offset(, 1).Resize(, 1).Font.Size = 20

　　　　.Offset(, 1).Resize(, 1).Font.Bold = True

　　　　.Offset(, 1).Resize(, 1).HorizontalAlignment = xlCenter

　　　　.Offset(, 0).Resize(, 1).Font.Name = "ＭＳ Ｐゴシック"

　　　　.Offset(, 0).Resize(, 1).Font.Size = 11

　　　　.Offset(, 0).Resize(, 1).Font.Bold = True

　　　　.Offset(, 0).Resize(, 1).HorizontalAlignment = xlRight

　　End With

　　With p先手消費時間

　　　　.Offset(, -1).Resize(, 3).BorderAround LineStyle:=xlContinuous

　　　　.Offset(, -1).Resize(, 3).Interior.Color = vbBlack

　　　　.Offset(, -1).Resize(, 3).Font.Name = "ＭＳ Ｐゴシック"

　　　　.Offset(, -1).Resize(, 3).Font.Size = 11

　　　　.Offset(, -1).Resize(, 3).Font.Bold = True

　　　　.Offset(, -1).Resize(, 3).Font.Color = vbWhite

　　　　.HorizontalAlignment = xlCenter

　　　　.NumberFormatLocal = "h:mm:ss"

　　End With

　　With p後手消費時間

　　　　.Offset(, -1).Resize(, 3).BorderAround LineStyle:=xlContinuous

　　　　.Offset(, -1).Resize(, 3).Interior.Color = vbWhite

　　　　.Offset(, -1).Resize(, 3).Font.Name = "ＭＳ Ｐゴシック"

　　　　.Offset(, -1).Resize(, 3).Font.Size = 11

　　　　.Offset(, -1).Resize(, 3).Font.Bold = True

　　　　.HorizontalAlignment = xlCenter

　　　　.NumberFormatLocal = "h:mm:ss"

　　End With

　　With p手数

　　　　.Resize(, 4).Borders.LineStyle = xlContinuous

　　　　.Resize(, 4).Interior.Color = p駒選択色.Interior.Color

　　　　.Resize(, 4).Font.Name = "ＭＳ Ｐゴシック"

　　　　.Resize(, 4).Font.Size = 11

　　End With


　　'文字設定()

　　p将棋盤.Offset(-1).Resize(1).Value = Array(9, 8, 7, 6, 5, 4, 3, 2, 1)

　　p将棋盤.Offset(, 9).Resize(, 1).Value = WorksheetFunction.Transpose(Array("一", "二", "三", "四", "五", "六", "七", "八", "九"))

　　p先手消費時間.Offset(, -1).Resize(, 1).Value = "先手"

　　p後手消費時間.Offset(, -1).Resize(, 1).Value = "後手"

　　p将棋盤色.Offset(, -2).Value = "将棋盤色"

　　p駒選択色.Offset(, -2).Value = "駒選択色"

End Sub

将棋進行クラスVBAの解説

まだまた足らないのですが、結構なコード量になってしまいました。
ただし後半は、シート設定のVBAコードなのでだらだらと長くなっているだけです。

シート設定のVBAコードは、初回の Excel将棋：マクロVBAの学習用 から変更しています。

・Excel将棋の要件定義・Excel将棋のシート作成・Excel将棋の目次

プロシージャーをまとめたり、空行を削除したり、記述をクラスで使うように変更しています。

全体の構造としては、

・ゲーム開始が呼ばれる
・ブック・シートを選択してもらう（他ブックも可、ブック・シートは問いません）
・アクティブシートに名前定義"開始駒位置"が無い場合は、シートに名前定義および書式設定する。
・WithEvents xlApp As Excel.ApplicationにApplicationを設定
・駒を並べる（大橋流）

ここでマクロVBAは一旦終了します。

・セル選択で、SheetSelectionChangeが起動される
・駒選択を呼ぶ
・選択セルの該当位置から配列インデックスを求めcls駒のオブジェクトを特定
・cls駒のオブジェクトの駒移動可能位置を取得
・シートの該当セルの色を設定する

しっかり見て欲しいのは、WithEventsを使ったイベント処理です。
これを使う事で、シートモジュールにイベントを記述せずに済むようになっています。
SheetSelectionChangeは選択セルが動く必要があるので、イベントの中で盤外にアクティブセルを移動しています。

WithEvents、SheetSelectionChange

VBAクラスを使ったイベント作成（Event,RaiseEvent,WithEvents）

・Eventステートメント・RaiseEventステートメント・WithEventsキーワード・標準モジュールと動作概要・ユーザーフォーム(UserForm1) ・クラス(clsEvent) ・クラスを使ったイベントの解説・VBAクラスを使ったイベントの最後に

関連するものとしては、
イベントプロシージャーの共通化｜ユーザーフォーム入門

・サンプルのユーザーフォーム・イベントプロシージャーの共通化のVBA ・イベントプロシージャーの共通化の問題点・イベントプロシージャーの共通化の雛形VBA ・イベントプロシージャーの共通化の最後に

イベントプロシージャーの共通化（Enter,Exit）

・イベントプロシージャーの共通化の問題点・問題解決した経緯・API:ConnectToConnectionPointについて・ConnectToConnectionPointの使用例・イベントと対応するVB_UserMemIdの一覧とインポート用雛形・イベントプロシージャーの共通化の最後に

駒台クラス

オブジェクト変数の定義だけで、まだ何も実装しています。

※次回作成※

着手

最初のクリックで選択し、駒の移動可能位置のクリックで駒を移動します。
駒の選択状態の判定と次のクリックが移動可能な場所かを判定し、配列のオブジェクトを移動して、シートの表示も変更します。

※駒を取る機能と合わせて実装※

盤面表示の先手持駒と後手持駒

cls駒台の駒台一覧から持駒の種類と枚数の一覧を配列で受け取りシートに表示します。

将棋進行クラスの起動方法

標準モジュールに以下を作成します。


  
    
      Option Explicit


      Private obj将棋 As cls将棋進行


      Sub ゲーム開始()

　　Set obj将棋 = New cls将棋進行

　　obj将棋.ゲーム開始

End Sub

シートにボタンを作ってマクロを登録するか、開発タブのマクロから起動してください。
ブック・シートはどれでも構いませんが、選択したシートは全て消去されるので注意下ください。

将棋盤クラスのテストVBAの結果

Excel将棋の目次

№1. Excel将棋：マクロVBAの学習用

・Excel将棋の要件定義・Excel将棋のシート作成・Excel将棋の目次

№2. Excel将棋：クラスの設計

・作成するクラスの役割と作成順・作成するクラスのメンバー一覧・駒の移動の定義・Excel将棋の目次

№3. Excel将棋：駒クラスの作成

・位置クラス・移動クラス・駒クラス・駒クラスVBAの解説・使用しているVBAの参考ページ・Excel将棋の目次

№4. Excel将棋：駒クラスの単体テスト

・駒クラスのテスト内容・駒クラスのテストVBAコード・駒クラスのテストVBAの結果・Excel将棋の目次

№5. Excel将棋：駒台クラスの作成&単体テスト

・駒クラス・駒台クラスVBAの解説・駒台クラスのテストVBAコード・駒クラスのテストVBAの結果・Excel将棋の目次

№6. Excel将棋：位置クラスをデフォルトインスタンスに変更

・デフォルトインスタンスに変更する理由と方法・位置クラスのインポート用ソース・cls位置とg位置の使い方の違い・位置クラス変更に伴う駒クラスの変更・Excel将棋の目次

№7. Excel将棋：将棋盤クラスの作成&単体テスト

・将棋盤クラス・将棋盤クラスVBAの解説・将棋盤クラスのテストVBAコード・将棋盤クラスのテストVBAの結果・Excel将棋の目次

№8. Excel将棋：将棋進行クラスの作成

・将棋進行クラス・将棋進行クラスVBAの解説・将棋進行クラスの起動方法・将棋盤クラスのテストVBAの結果・Excel将棋の目次

№9. Excel将棋：駒を動かす

・駒クラスにプロパティ追加・将棋進行クラスの変更点・将棋進行クラスのVBA ・Excel将棋の実行動作・Excel将棋の目次

№10. Excel将棋：相手の駒を取る、持ち駒を打つ

・主な変更追加箇所・全体の構成・Excel将棋の動作・Excel将棋の全VBAコード・Excel将棋の目次

№11. Excel将棋：駒を成る

・主な変更追加箇所・Excel将棋の動作・変更したクラスのVBA ・Excel将棋の目次

№12. Excel将棋：棋譜をユーザーフォームに表示する

・棋譜について・主な変更内容・ユーザーフォームの作成・Excel将棋の動作・変更したクラスのVBA ・Excel将棋の目次

№13. Excel将棋：棋譜選択でその時点の盤面に戻す

・Excel将棋の動作・全体構成図・全プロシージャー・プロパティの一覧・クリックで着手した時の主なプロシージャーの流れ・Excel将棋のダウンロード・Excel将棋の目次

№14. Excel将棋：棋譜ファイルの出力と読込自動再生

・Excel将棋の動作・VBAの修正箇所について・Excel将棋のダウンロード・棋譜KIFファイルのサンプル・Excel将棋の目次

№15. Excel将棋：反則（禁じ手）判定

・反則（禁じ手）・Excel将棋の動作・各クラスの共通で持つプロパティを整理・VBAの修正箇所について・Excel将棋のダウンロード・Excel将棋の目次

№16. Excel将棋：終局（詰み）判定と打ち歩詰め

・反則（禁じ手）・Excel将棋の動作・VBAの追加・修正箇所について・Excel将棋のダウンロード・Excel将棋の目次

№17. Excel将棋：千日手と連続王手の千日手

・反則（禁じ手）・Excel将棋の動作・VBAの修正箇所について・Excel将棋のダウンロード・Excel将棋の目次

№18 Excel将棋：ひとまず完成、これまでとこれから

・Excel将棋のこれから・Excel将棋の目次・Excel将棋のダウンロード・当初のクラス設計・作成するクラスのメンバー一覧・全体構成図・全プロシージャー・プロパティの一覧・全VBAコード

№19 Excel将棋：棋譜ファイルから対局一覧作成

・対局一覧のシート・Excel将棋の動作・全体構成図・Excel将棋のダウンロード・新規追加したVBAコード・Excel将棋の目次

アクセスランキング・・・ランキング一覧を見る

1.最終行の取得（End,Rows.Count）｜VBA入門
2.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
3.RangeとCellsの使い方｜VBA入門
4.ひらがな⇔カタカナの変換｜エクセル基本操作
5.繰り返し処理（For Next)｜VBA入門
6.変数宣言のDimとデータ型｜VBA入門
7.ブックを閉じる・保存（Close,Save,SaveAs）｜VBA入門
8.並べ替え（Sort）｜VBA入門
9.セルのクリア（Clear,ClearContents）｜VBA入門
10.Findメソッド（Find,FindNext,FindPrevious）｜VBA入門

ホーム
マクロVBA応用編
マクロVBAサンプル集
Excel将棋：将棋進行クラスの作成(№8)

このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。

記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。

VBAサンプル集
Excel将棋：将棋進行クラスの作成(№8)