セル値でパス・ブック・シート名を指定

公開日：2023-02-07　最終更新日：2023-02-08

セル値でパス・ブック・シート名を指定

「パワク2本目」
Power Query（M言語）の問題と解答・解説

本シリーズは、ツイッターと連動企画になります。
ツイッターで問題を出して、それに解答と解説をしていく形でPower QueryとM言語の理解を深めていきます。

ページ内目次

パワク2本目
解答コード
Excel.CurrentWorkbook
Power Query M言語仕様

パワク2本目

#パワク2本目
別ブックの特定シートをパワクで取り込んでください。
テーブル"tbl設定"に、パス・ブック名・シート名が入っています。
この"tbl設定"の情報を元に取り込んでください。
※"tbl設定"の名前は随意で。
※設定値は正しく入力されているものとします。
#パワク #PowerQuery

解答コード

let
    設定 = Excel.CurrentWorkbook(){[Name="tbl設定"]}[Content][設定],
    パス名 = 設定{0}, ブック名 = 設定{1}, シート名 =  設定{2},
    ソース = Excel.Workbook(File.Contents(パス名 & "\" & ブック名), true, true),
    シート = ソース{[Item=シート名,Kind="Sheet"]}[Data]
in
    シート

パス名、ブック名、シート名
これらを一旦変数に入れてから使っていますが、もちろん直接使っても構いません。

let
    設定 = Excel.CurrentWorkbook(){[Name="tbl設定"]}[Content][設定],
    ソース = Excel.Workbook(File.Contents(設定{0} & "\" & 設定{1}), true, true),
    シート = ソース{[Item=設定{2},Kind="Sheet"]}[Data]
in
    シート

面倒なら変数を減らしてしまって、
inでまとめて処理しても構いません。

let
    設定 = Excel.CurrentWorkbook(){[Name="tbl設定"]}[Content][設定]
in
    Excel.Workbook(File.Contents(設定{0} & "\" & 設定{1}), true, true){[Item=設定{2},Kind="Sheet"]}[Data]

この辺りは見やすさ書きやすさの問題なので、自身で分かり易いと思う書き方で良いと思います。
普通は、分かりやすい名前の変数に入れて使うようにした方が良いと思います。

Excel.CurrentWorkbook

いきなり、Excel.CurrentWorkbookがでてくるので、ちょっと戸惑うかもしれません。

構文

Excel.CurrentWorkbook() as table

※Learn

現在の Excel ブックの内容を返します。
テーブル、名前付き範囲、動的配列を返します。
Excel.Workbook とは異なり、シートは返しません。

簡単に言えば、
テーブルを含む名前定義の一覧が、tableとして返されるという事です。

空のクエリを作成して確認してみましょう。

数式バーに、
= Excel.CurrentWorkbook()
これだけ入れると、

Excel.CurrentWorkbook(){[Name="tbl設定"]}[Content][設定]
Excel.CurrentWorkbook()で取得したtableの中から、
Nameが"tbl設定"を抽出し、[Content]列、[設定]列を取得してます。
画面で、
「Content」列の1行目の「Table」の部分をクリックすると、下部に中身が表示されます。

{[Name="tbl設定"]}
これは、1行目のデータなので、
Excel.CurrentWorkbook(){[Name="tbl設定"]}
Excel.CurrentWorkbook(){0}
どちらでも同じになります。

リストは配列のようなものと考えて良いでしょう。
特定の要素を取得するには、インデックス（0から始まる）を波括弧{}の中に指定します。

レコードとリストの違いに注意してください。
= Excel.CurrentWorkbook(){[Name="tbl設定"]}
これはレコードです。
行番号がありませんので、これに続けてインデックス{}の指定はできません。
Excel エクセル Power Query M言語

[Content]を指定することでリストになります。
= Excel.CurrentWorkbook(){[Name="tbl設定"]}[Content]

これは「Content」のリストになるので、インデックスを指定できます。
= Excel.CurrentWorkbook(){[Name="tbl設定"]}[Content]{0}

[Content]のインデックスを指定する前に[設定]列を指定しても良いです。

つまり、パス名を取得するには、
= Excel.CurrentWorkbook(){[Name="tbl設定"]}[Content]{0}[設定]
= Excel.CurrentWorkbook(){[Name="tbl設定"]}[Content][設定]{0}
どちらでもパス名にたどりつくことができます。

解答のクエリでは、後で使いやすいように、
設定 = Excel.CurrentWorkbook(){[Name="tbl設定"]}[Content][設定]
パス名 = 設定{0}
ブック名 = 設定{1}
シート名 = 設定{2}
このように使用しています。

Power Query M言語仕様

Microsoft Learn

Power Query のドキュメント
Power Query M言語仕様

詳細は上記を参照してください。
ここまでに使われた記号の意味と、コメントについて簡単に説明しておきます。

位置指定インデックス演算子

{} 波括弧
数値インデックスを使用してリスト内の項目にアクセスします。
0から始まるリストの先頭からのインデックスです。

参照演算子

[] 角括弧
レコードのフィールドに名前でアクセスできます。

単一行コメントは、// 文字で始まり、ソース行の末尾までです。
区切られたコメントは、/* 文字で始まり、*/ 文字で終わります。

同じテーマ「PowerQuery（M言語）入門」の記事

別ブックのシートを列可変で取り込む
セル値でパス・ブック・シート名を指定
別ブックの最終シートの取り込み
 列数不定のCSVの取り込み
 CSVのA列が日付の行だけを取り込む
 A列のヘッダー名を変更する
 「売上」が数値の行のみ取り込む
 2つのテーブルのマージ
 グルーブ内の最小・最大
 グルーブ内の最小・最大
 有効な最新単価の取得

アクセスランキング・・・ランキング一覧を見る

1.最終行の取得（End,Rows.Count）｜VBA入門
2.RangeとCellsの使い方｜VBA入門
3.繰り返し処理（For Next)｜VBA入門
4.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
5.変数宣言のDimとデータ型｜VBA入門
6.条件分岐（IF）｜VBA入門
7.ブックを閉じる・保存（Close,Save,SaveAs）｜VBA入門
8.並べ替え（Sort）｜VBA入門
9.マクロとは？VBAとは？VBAでできること｜VBA入門
10.Range以外の指定方法（Cells,Rows,Columns）｜VBA入門

ホーム
その他
PowerQuery（M言語）入門
セル値でパス・ブック・シート名を指定

このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。

記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。

Power Query（M言語）入門
セル値でパス・ブック・シート名を指定