エクセル入門
LAMBDA以降の新関数の問題と解説（配列操作関数編）

ここからはフリー問題だよ編
好きな関数を使ってくれ編
いろんな関数を使ってね編
魔球編
豚が木に登れば落ちることもある編
たまには100点とってみたいものだ編
これは何と言う処理なんだろ編
数字は嫌いなのだ編
外堀から埋めていくぞ編
なぜわざわざそうしたいのか編
かっこつけてんじゃないよ編
頭の体操だけど新関数の出番はあるか?編
定番だけど出してなかったよね編

【エクセル問題】※ここからはフリー問題だよ編
10行10列の範囲に、1から100までの重複しない数値をランダムに配置してください。
365の最新関数まで含めると480個くらいありますかね。
ここからは関数知識を総動員。
とはいえLAMBDA以降の関数なら割と簡単にできる問題にしたいなと…

【解答数式】
=WRAPROWS(SORTBY(SEQUENCE(100),RANDARRAY(100)),10)
SEQUENCE+RANDARRAY+SORTBY
これは一つのテクニックとしてそのまま覚えておくと良いと思います。
後は配置の問題ですが、現365の新関数を使うと簡単にできますね。

【エクセル問題】※好きな関数を使ってくれ編
テーブルが3つあります。
A:Eは「TBL売上」
G:Iは「TBL取引先M」
K:Lは「TBL商品M」
「TBL売上」に「取引先名」と「商品名」を付加してN2以降に出力してください。
N1:T1の見出しおよび列表示形式は設定済。
※データは画像ALT（テーブル化してね）
練習…

【解答数式】
=LET(
取引先名,XLOOKUP(TBL売上[取引先id],TBL取引先M[id],TBL取引先M[取引先名],""),
商品名,XLOOKUP(TBL売上[商品id],TBL商品M[id],TBL商品M[商品名],""),
HSTACK(TBL売上,取引先名,商品名))
LET関数は無くても良いのですが、コメント代わりの変数名です。

テーブルや列名は固定で良いと思います。
もちろん作成する仕組みにもよりますが。
特定するには位置または名称が必要になります。
テーブルの構造化参照を使えば列位置不問になります。
名称から自動取得等の方法もありますが、テーブルを使うのならここは構造化参照が良いと思います。

【エクセル問題】※いろんな関数を使ってね編
テーブルが2つあります。
A:Cは「TBL旧」
E:Gは「TBL新」
「TBL旧」と「TBL新」をidで結合し、違いのあるものだけをI2以下に出力。
「TBL旧」のみ：「削除」
「TBL新」のみ：「新規」
両方で内容違い：「変更」
※データは画像ALT（テーブル化してね）

【解答数式】
=LET(
u,UNIQUE(VSTACK(TBL旧,TBL新),,TRUE),
uid,INDEX(u,,1),
cnt,COUNTIFS(TBL旧[id],uid)*2+COUNTIFS(TBL新[id],uid),
HSTACK(u,CHOOSE(cnt,"新規","削除","変更")))
VSTACKとHSTACK以外は旧来からの関数だけにしました。

旧と新の存在確認はCOUNTIFSを使いました。
旧：新
0：1 →2進数で01 → 10進で1
1：0 →2進数で10 → 10進で2
1：1 →2進数で11 → 10進で3
これを作成して、CHOOSEで文字列に変換しています。
※テーブル内重複なしを前提にしました。
双方で重複がある場合は出力表が意味不明になるので。

【エクセル問題】※魔球編
2つのテーブル、
A:Cは「TBL旧」
E:Gは「TBL新」
「TBL旧」と「TBL新」をidで横に結合し、下記区分を付加してI2以下に出力。
TBL旧のみ:「削除」
TBL新のみ:「新規」
内容違い:「変更」
※テーブル内id重複なし
※結果は画像参照
※データはALT（テーブル化して）

【解答数式】
添付画像の1枚目と2枚目の2通りで作ってみました。
数式はそれぞれの画像のALTに入れました。
1枚目の数式で良いと思ったのですが、2枚目の数式も面白いかなと言う事で両方出しました。

数式が長くなる場合はまずはLETを使ったほうが良いと思います。
LETの途中で結果を見たい時には、別セル（当該数式の最終出力に入れても良い）で対象の変数を出力にして確認できます。
順に変数を一つずつ作成していって、最後にHSTACKで横に並べて完成になります。

【エクセル問題】※豚が木に登れば落ちることもある編
A:C列の短文の全組み合わせをE1以下に出力してください。
添付画像は結果の上部のみになります。
A:C列は増減対応として、添付2枚目のように列全体を指定してください。
※完成文章の意味は通じなくても良い🤣
※一応データはALT

【解答数式】
=LAMBDA(a,b,c,
LET(aa,FILTER(a,a<>""),bb,FILTER(b,b<>""),cc,FILTER(c,c<>""),
rc,LAMBDA(x,y,TOCOL(TOCOL(x)&TOROW(y))),
rc(rc(aa,bb),cc)
))(A:A,B:B,C:C)
列全体を指定すると、空行をどうやって排除するかが問題となりますね。

FILTER関数を使いましたが、1行目から空行を挟まずにデータが埋まっていることを前提にするなら、
TAKE(a,COUNTA(a))
INDEX(a,1):INDEX(a,COUNTA(a))
こういう方法でも良さそうです。
そして、TOCOL,TOROWにも空白無視の引数があります。
=TOCOL(array, [ignore], [scan_by_column])
これを使った数式なら、
=TOCOL(TOCOL(TOCOL(A:A,1)&TOROW(B:B,1))&TOROW(C:C,1))
ネストが見ずらいのは、LETなりで書き換えてください。

【エクセル問題】※たまには100点とってみたいものだ編
A2:F12に個人別の5教科（英語、国語、数学、理科、社会）の点数一覧があります。
全科目共通で点数ベスト10（順位付けて）を出力してください。
同点は「英語>国語>数学>理科>社会 」の順。
完全同順位は順番は問いません。
※データは画像ALT

【解答数式】
=LET(
氏名,A2:A12,科目,B1:F1,点数,TOCOL(B2:F12),
rc,LAMBDA(x,y,TOCOL(IF(ISNA(y),,x))),
h,HSTACK(rc(氏名,科目),rc(科目,氏名),点数),
s,SORTBY(h,点数,-1,MATCH(INDEX(h,0,2),科目,0),1),
HSTACK(SEQUENCE(10),TAKE(s,10)))
この問題は本来はTAKEの問題のつもりだったのですが…

単なるTAKEではつまらないと思って問題作ったら、むしろアンピボットの問題になってしまったようです😅
アンピボットの部分は書き方はいろいろあると思います。
一応別数式も書いたので、
=LET(
氏名,A2:A12,科目,B1:F1,点数,TOCOL(B2:F12),
氏名2,TOCOL(氏名&EXPAND("",,COLUMNS(科目),"")),
科目2,TOCOL(科目&EXPAND("",ROWS(氏名),,"")),
h,HSTACK(氏名2,科目2,点数),
s,SORTBY(h,点数,-1,MATCH(INDEX(h,0,2),科目,0),1),
HSTACK(SEQUENCE(10),TAKE(s,10)))
さらに科目ソートを省けるようなので、こんな数式も、
=LET(
氏名,TOROW(A2:A12),科目,TOCOL(B1:F1),点数,TOCOL(B2:F12,,TRUE),
rc,LAMBDA(x,y,TOCOL(IF(ISNA(y),,x))),
h,HSTACK(rc(氏名,科目),rc(科目,氏名),点数),
s,SORTBY(h,点数,-1),
HSTACK(SEQUENCE(10),TAKE(s,10)))
色々試してみてください。

【エクセル問題】※これは何と言う処理なんだろ編
A1:A5に入っている文字列は、
「文字列-数値」
となっています。
最後の「-」の後ろは必ず2桁以内の数値となっています。
添付画像のように、最後の数値回数で文字列を縦に繰り返し、「-」に続けて順番を01から2桁数値で振ってください。

【解答数式】
今回は作成した順番に出していきます。
最初の数式は長い…のでALTで。
本当はTEXT処理だけでやりたかったのですが、途中で挫けてREDUCE使っちゃいました。
もちろん納得いかないですね。
でもまあ出題は出来るなと言うくらいです。

前の数式、良く見るとREDUCE使うんなら、そもそもREDUCEだけで良いのではないかと。
そして、とにかく書いてみたのがこれです。
=DROP(REDUCE(0,A1:A5,LAMBDA(x,y,VSTACK(x,TEXTBEFORE(y,"-",-1)&"-"&TEXT(SEQUENCE(TEXTAFTER(y,"-",-1)),"00")))),1)
数式も短いし悪くはない。
※画像は改行入れました。

しかし最初の予定通りTEXT処理で進めた数式も…そして作りました。
=LET(
入力,A1:A5,
文字,TEXTBEFORE(入力,"-",-1),
数値,TEXTAFTER(入力,"-",-1)*1,
数値横,SEQUENCE(1,MAX(数値)),
TOCOL(IF(数値横>数値,NA(),文字&"-"&TEXT(数値横,"00")),3))
TOCOL使うのは仕方ない…とりあえず良し😇

【エクセル問題】※数字は嫌いなのだ編
A1:A3は文字数値混在の文字列です。
半角数字のみ「-」に置換してください。
そして空白TRIMと同じ要領で「-」の連続は1つに、最初と最後の「-」は消す。
※画像参照。
問題1：スピル不要
問題2：余裕があればスピルさせて。

【解答数式】
問題1：スピル不要
=TEXTJOIN("-",,TEXTSPLIT(A1,SEQUENCE(10,,0)))
これはTEXTSPLITを使うだけですね。
構文は、
=TEXTSPLIT(text,col_delimiter,row_delimiter,ignore_empty,match_mode,pad_with)
delimiterに配列を使う事で複数種類の文字で分割できます。

問題2：スピル
=MAP(A1:A3,LAMBDA(x,TEXTJOIN("-",,TEXTSPLIT(x,SEQUENCE(10,,0)))))
ついでにSCANとREDUCEも、
=SCAN(0,A1:A3,LAMBDA(x,y,TEXTJOIN("-",,TEXTSPLIT(y,SEQUENCE(10,,0)))))
=DROP(REDUCE(0,A1:A3,LAMBDA(x,y,VSTACK(x,TEXTJOIN("-",,TEXTSPLIT(y,SEQUENCE(10,,0)))))),1)

これは問題からして特にスピルさせる必要があるとも思えませんが、、、
新関数の練習ですので、やはりスピルさせるならどうするかと考えてもらいました。
でも、今まで問題をこなして来ていれば、それほど苦労せずにスピルさせられたはずです。

【エクセル問題】※外堀から埋めていくぞ編
A1:I9に数列が入っています。
引数として、(範囲,レベル）を与えます。
範囲：A1:I9
消すレベル：1なら一番外側だけ、2なら外枠2周分
※添付画像参照
※レベル不正指定は気にしなくて良い。

【解答数式】
=LAMBDA(a,n,LET(
中,DROP(DROP(a,n,n),-n,-n),
左,HSTACK(EXPAND("",ROWS(中),n,""),中),
上,VSTACK(EXPAND("",n,COLUMNS(左),""),左),
EXPAND(上,ROWS(上)+n,COLUMNS(上)+n,"")
))(A1:I9,2)
4分割で作成しました。

中,DROP(DROP(a,n,n),-n,-n),
これで中央の残す数値部分だけになります。
左,HSTACK(EXPAND("",ROWS(中),n,""),中),
左の余白を作成してHSTACK
上,VSTACK(EXPAND("",n,COLUMNS(左),""),左),
上の余白を作成してVSTACK
最後にEXPANDで元の大きさにしています。

【エクセル問題】※なぜわざわざそうしたいのか編
A:B列にテーブル（名前は任意）があります。
A列に1か月分（何日でも）の日付、B列に数値が入っています。
添付画像のように、日付と数値で2段にして1週間（月～日）で折り返してください。
※8/1開始も確認
※表示形式は不問
※データは画像ALT

【解答数式】
長い…コメントも付けたので余計に。
数式は画像ALT。
関数「fx」がほぼ本体です。
入力配列を、月初の曜日に応じて先頭に空白配列を入れてずらし、先頭列に1からの順番を付ける関数です。
この関数を日付列と数値列で呼び出してVSTACKしてSORT、先頭の順番を削除して完成です。

【エクセル問題】※かっこつけてんじゃないよ編
A1セルの文字列から、複数の括弧（）内の文字列を取り出して横に展開してください。
※括弧は全角半角問わない。
※括弧が正しく対になっていることを基本として、括弧が正しく対になっていない場合の結果については特に限定しません。

【解答数式】※かっこつけてんじゃないよ編
=TOROW(TEXTBEFORE( TEXTSPLIT(A1,{"(","（"}),{")","）"}),3)
テキスト関係の新関数
TEXTSPLIT
TEXTBEFORE
TEXTAFTER
これらを組み合わせれば括弧内の文字は取り出せます。
後は取り出した部分のエラー対応だけです。
これにはTOROW,TOCOLが便利です。

※括弧は全角半角問わない。
この意味がはっきりしませんでした。
どちらかに限定しても良いし両対応にしても良いし、回答者の都合でも良いでしょうという主旨でした。
先の数式の中の、
{"(","（"}
{")","）"}
この部分を配列にするかどうかの違いだけになります。

【エクセル問題】※頭の体操だけど新関数の出番はあるか?編
シートの任意の範囲を指定します。
その範囲内での奇数行は奇数列のみ、偶数行は偶数列のみ合計します。
行列数の判定はシート上のセル番地ではなく、指定範囲内の相対位置で判定してください。
※添付画像の黄色セルの合計
※データはALT

【解答数式】
=LAMBDA(範囲,
SUM(範囲*MAKEARRAY(ROWS(範囲),COLUMNS(範囲),LAMBDA(行,列,ISEVEN(行+列))))
)(D3:L11)
奇数+奇数=偶数、偶数+偶数=偶数、これで判定
MAKEARRAY関数を使いました。
タイトルからしてこれが目的になってますね😅
MAKEARRAYを使う場面はあまり多くないと思います。

MAKEARRAYを無理して使わなくても数式はできます。
=LAMBDA(範囲,LET(
縦数列,SEQUENCE(ROWS(範囲)),
横数列,SEQUENCE(,COLUMNS(範囲)),
SUM(範囲*ISEVEN(縦数列+横数列)))
)(D3:L11)
LAMBDAは関数化しているだけなので不要ですし、なんならLETも無くてもかまわないですね。
ついでなのでBITXORの使用例も出しておきます。
=LAMBDA(範囲,LET(
縦数列,SEQUENCE(ROWS(範囲)),
横数列,SEQUENCE(,COLUMNS(範囲)),
SUM(範囲*BITXOR(ISODD(縦数列),ISEVEN(横数列))))
)(D3:L11)

【エクセル問題】※定番だけど出してなかったよね編
A1セルの文字列をC:D列の文字列で置換してください。
置換において置換対象が複数ある場合の数式です。
C:D列の置換一覧は随時増える事が前提
縦スピルは任意と言う事にしておきます。
※サンプル文字列は一応ALTに

【解答数式】
=LET(
範囲,A1,
置換,FILTER(C:D,C:C<>""),
置換行,SEQUENCE(ROWS(置換)-1,,2),
REDUCE(範囲,置換行,LAMBDA(x,y,SUBSTITUTE(x,INDEX(置換,y,1),INDEX(置換,y,2)))))
REDUCEを使いました。
この数式は範囲をA1:A3のようにすれば縦にスピルします。

SUBSTITUTEに配列を指定しても、その配列に従ってスピルしてしまうだけで複数の置換が出来ません。
したがって、これをLAMBDAとヘルパー関数なしでやろうとするとかなり大変です。
ただしREDUCEを使っても、置換前と置換後の文字列取得が簡単には出来ないためINDEXを使う事になっています。
INDEXではなくOFFSETを使って取り出すこともできます。
=LET(
範囲,A1,置換,C:C,
置換前,DROP(TAKE(置換,COUNTA(置換)),1),
REDUCE(範囲,置換前,LAMBDA(x,y,SUBSTITUTE(x,y,OFFSET(y,0,1)))))
どちらもほぼ似たようなものですが、書き方はいろいろあると思います。