エクセル入門
PIVOTBY関数（縦軸と横軸でグループ化して集計）

以下では品名の範囲として、
C1:C21
このようにセル参照しています。
データ範囲をテーブル化して使う場合は、
テーブル1[[#すべて],[品名]]
このように読み替えてください。

もちろん、テーブルで使う方が良い場合が多いと思います。
ここでは、テーブル構造化参照の数式では数式文字列が長くなってしまうのでセル参照にしています。

=PIVOTBY(C1:C21,A1:A21,D1:D21,SUM)

商品・日別の売上集計です。
商品の一覧と日付でSUMIFS関数を使うか、ピボッテーブルを使う場面ですが、
PIVOT関数でかなり簡単に作製することができるようになりました。

=PIVOTBY(C:C,A:A,D:D,SUM)
ピボットテーブルと同様に、空欄は0集計として出力されてしまいます。
入力範囲がテーブルの場合は構造化参照するので問題になりませんが、
セル範囲の場合はメンテナンス性を考慮しての列指定は使いづらくなります。
FILTER関数と組み合わせたり等の対応も考えられますが、数式が複雑化してしまう懸念があります。
このような場合は範囲をテーブルにしたほうが良いと思います。

=PIVOTBY(B1:C21,A1:A21,D1:D21,SUM,,2)

行フィールドをB:C列で指定しています。
つまり、分類・商品の2段階のグループになります。
（サンプルデータは、商品が分類通してユニークなので商品集計と同じ結果になります。）

=PIVOTBY(C1:C21,A1:A21,D1:E21,SUM,3)

売上と利益の2つの値で集計してています。
しかし、列の合計が出力されていません・・・
「列合計深さ」を指定しても出力させることはできませんでした。
これが仕様なのかバグなのか、現時点では不明です。

=PIVOTBY(B1:C21,A1:A21,D1:D21,SUM,3,-2)

ヘッダーの表示＋上部に合計行
個人的な感想になってしまいますが、この組み合わせはあまり見やすいとは思えません。
使う場合は、レイアウトを工夫したほうが良いかもしれません。

=PIVOTBY(B1:C21,A1:A21,D1:D21,SUM,,,-2)

行並べ替え順序に -2 を指定しています。
数値（1から始まる）は「行フィールド」の列に対応しています。
※シートの列位置とは関係なく、あくまで「行フィールド」の中での順番になります。
数値が負の場合、行は降順/逆順に並べ替えられます。
上記では、
B列 → 1
C列 → 2
B列は省略で昇順、C列を降順に指定していることになります。

=PIVOTBY(B1:C21,A1:A21,D1:D21,SUM,,,{-1,-2})

行並べ替え順序に {-1,-2} を指定しています。
並べ替えを行フィールドのみで行う場合は、複数の列を指定することが出来ます。
この場合は、並べ替え順序の数値をベクトル（配列）で指定します。
並べ替え順序の数値は、行フィールドと値で通し番号です。
B列 → 1
C列 → 2
D列 → 3
降順/逆順の場合は数値をマイナスで指定します。
※シートの列位置とは関係なく、あくまで「行フィールド」の中での順番です。
※行フィールドと値の両方を指定して並べ替えることはできません。

=PIVOTBY(B1:C21,A1:A21,D1:D21,SUM,,,,,-1)

列並べ替え順序に -1 を指定しています。
並べ替え順序の数値は、行フィールドと値で通し番号です。
A列 → 1
D列 → 2
降順/逆順の場合は数値をマイナスで指定します。
※列（横）で並べ替えることはあまりないと思います。

=PIVOTBY(B1:C21,A1:A21,D1:D21,SUM,,,3,,2)

列並べ替え順序に 3 を指定しています。
並べ替え順序の数値は、行フィールドと値で通し番号です。
B列 → 1
C列 → 2
D列 → 3
行並べ替え順序に 2 を指定しています。
並べ替え順序の数値は、列フィールドと値で通し番号です。
A列 → 1
D列 → 2
結果の表を見ても分かりづらいのですが・・・
総計→小計→明細
この順で並べ替えられています。

=PIVOTBY(C1:C21,A1:A21,D1:D21,SUM,,,,,,B1:B21="分類A")

フィルター配列はFILTER関数の指定と同じ要領になります。
行フィールド・値と同じ行数のブール値（TRUE/FALSE）の配列を指定します。
B1:B21="分類A"
これは、21個のTRUE/FALSEの縦配列です。
この配列が FALSE の行は対象外として除外されます。

=PIVOTBY(C1:C21,A1:A21,D1:D21,HSTACK(SUM,AVERAGE))

HSTACKで横方向にしているので、出力も横に展開されています。
ではVSTACKを使うと、

VSTACKで縦方向にしているので、出力も縦に展開されています。

=PIVOTBY(HSTACK(E1:E21,A1:A21),B1:B21,C1:C21,SUM)

行フィールドも値列もHSTACK関数で横に結合して引数に指定しています。
IF関数に配列定数を指定して列の配列を作成する方法もあります。
=PIVOTBY(IF({1,0},E1:E21,A1:A21),B1:B21,C1:C21,SUM)

=PIVOTBY(B1:B21&C1:C21,A1:A21,D1:D21,SUM,3)

B1:B21&C1:C21
分類と品名を文字列結合しています。
元のデータを編集してPIVOTBY関数に入れる事が出来ます。
この時に使用できる関数に特に制限ありません。
当然ですが、VLOOKUPやMATCH+INDEX等の関数も使えます。
ただし、上記の例ではCONCAT関数を使う事は出来ません。
（CONCAT関数は21行分全てを1つの文字列にしてしまいます。）
ヘッダーを表示する場合は、先頭をヘッダーとして使えるように作成する必要があります。

=PIVOTBY(C1:C21,A1:A21,ROUND(D1:D21/1000,0),SUM,3)

値の列も自由に数式を指定することが出来ます。
ただし、ヘッダーを表示する場合は、先頭をヘッダーとして使えるように作成する必要があります。

イータ縮小ラムダ関数は単純にLAMBDA関数に書き換えることが出来ます。
SUM、AVERAGE、MEDIAN、COUNT、COUNTA、、、
これらは、LAMBDA関数の記述を縮小簡略化した書き方です。
従って、もともとのLAMBDA関数で書き直すことが出来ます。
=GROUPBY(...,イータ縮小関数)
↓
=GROUPBY(...,LAMBDA(x,イータ縮小関数(x)))

=PIVOTBY(C1:C21,A1:A21,D1:D21,LAMBDA(x,SUM(x)))
=PIVOTBY(C1:C21,A1:A21,D1:D21,SUM)
どちらでも同じになります。
さらに、LET関数を使ってLAMBDA関数を事前に定義しておき、その関数を使う事も出来ます。

=LET(合計,LAMBDA(x,y,SUM(x)*2),
PIVOTBY(C1:C21,A1:A21,D1:D21,合計))
上記では、「合計」という関数を作成してそれを使っています。
独自に作製する関数名をイータ縮小ラムダ関数と同じにすると、その名前で上書きされます。
誤解の元になるので、このような使い方は避けた方が良いでしょう。

PIVOTBY関数の第3引数「関数」に渡す引数は2つ存在します。
以下では、この「関数」に渡す第2引数についての解説になります。
ただし、イータ縮小ラムダには第2引数は渡さません。

=PIVOTBY(C1:C21,A1:A21,D1:D21,LAMBDA(x,y,SUM(x)))
LAMBDA関数に第2引数を指定することが出来ます。
上記は第1引数だけを指定した場合と同じです。

=PIVOTBY(C1:C21,A1:A21,D1:D21,LAMBDA(x,y,SUM(y)))
SUM(y)としています。
各行の結果が「合計」と同じになっています。
LAMBDA(第1引数,第2引数,計算)
第1引数は各グループごとの計算になります。
第2引数は全体にたいする計算になります。
つまり、
第1引数は各グループごとの配列。
第2引数はデータ全体の配列。

=PIVOTBY(C1:C21,A1:A21,D1:D21,LAMBDA(x,y,COUNTA(x)&"-"&COUNTA(y)))
上記のように件数を確認してみると良く分かると思います。
第1引数と第2引数は配列の大きさ（件数）が違うので、
第1引数と第2引数を直接演算するような式はエラーとなります。

第1引数と第2引数をそれぞれ別々に集計した後に演算することは問題ありません。

=PIVOTBY(C1:C21,A1:A21,D1:D21,LAMBDA(x,y,SUM(x)/SUM(y)))
これは全体に対する構成比の計算になります。
※この記事執筆時点では何故かPERCENTOF関数がまだ降りてきていません…
以下はPERCENTOF関数が降りて来たので追記。

=PERCENTOF(data_subset,data_all)
SUM(第1引数) / SUM(第2引数)
従って全合計の値が0の場合は「#DIV/0!」のエラーになります。

=PIVOTBY(C1:C21,A1:A21,D1:D21,PERCENTOF)
先に掲載したLAMBDAと同じ結果となっています。