エクセル入門
GROUPBY関数（縦軸でグループ化して集計）

以下では品名の範囲として、
B1:B19
このようにセル参照しています。
データ範囲をテーブル化して使う場合は、
テーブル1[[#すべて],[品名]]
このように読み替えてください。

もちろん、テーブルで使う方が良い場合が多いと思います。
ここでは、テーブル構造化参照の数式では数式文字列が長くなってしまうのでセル参照にしています。

=GROUPBY(B1:B19,C1:D19,SUM,,0)

商品ごとの売上・利益の集計です。
商品の一覧を作成して、SUMIFS関数を使う場面です。
この関数を使わずにこれと同じような処理を行おうとすると、
F列に、UNIQUE関数で商品の一覧を作成し、
G列H列に、SUMIFS関数いれて集計。
このような処理が必要になります。
さらに、これを1セルの数式で実現しようとすると、かなり大変です。

=LET(キー,B2:B19,値1,C2:C19,値2,D2:D19,
商品,UNIQUE(キー),
売上,SUMIFS(値1,キー,商品),
利益,SUMIFS(値2,キー,商品),
SORT(HSTACK(商品,売上,利益)))

=GROUPBY(B:B,C:D,SUM,,0)
ピボットテーブルと同様に、空欄は0集計として出力されてしまいます。
入力範囲がテーブルの場合は構造化参照するので問題になりませんが、
セル範囲の場合はメンテナンス性を考慮しての列指定は使いづらくなります。
FILTER関数と組み合わせたり等の対応も考えられますが、数式が複雑化してしまう懸念があります。
このような場合は範囲をテーブルにしたほうが良いと思います。

=GROUPBY(A1:B19,C1:D19,SUM,3)

行フィールドをA:B列で指定しています。
つまり、日付・商品の2段階のグループになります。

=GROUPBY(A1:B19,C1:D19,SUM,3,-2)

これなどは、クリックしていくだけで作成するピボットテーブルとほぼ同じです。

=GROUPBY(A1:B19,C1:D19,SUM,3,0,-1)

並べ替え順序に -1 を指定しているので、
行フィールドの先頭列の降順/逆順で並べ替えられます。

=GROUPBY(A1:B19,C1:D19,SUM,3,0,{-1,-2})

並べ替えを行フィールドのみで行う場合は、複数の列を指定することが出来ます。
※行フィールドと値の両方を指定して並べ替えることはできません。
この場合は、並べ替え順序の数値をベクトル（配列）で指定します。
並べ替え順序の数値は、行フィールドと値で通し番号です。
A列 → 1
B列 → 2
C列 → 3
D列 → 4
降順/逆順の場合は数値をマイナスで指定します。
※シートの列位置とは関係なく、あくまで「行フィールド」の中での順番です。

=GROUPBY(A1:B19,C1:D19,SUM,3,0,3)

並べ替え順序に 3 を指定しているので、値のC列で並べ替えられます。
気を付けて見てもらいたいのは、
グループの小計 > グループ内集計値
この順で並べ替えられます。
今回では、
・日付・品名の売上計
・日付・品名内の売上
この順で並べ替えられています。

=GROUPBY(A1:B19,C1:D19,SUM,3,,,A1:A19<>DATE(2023,11,2))

フィルター配列はFILTER関数の指定と同じ要領になります。
行フィールド・値と同じ行数のブール値（TRUE/FALSE）の配列を指定します。
A1:A19<>DATE(2023,11,2)
これは、19個のTRUE/FALSEの縦配列です。
この配列が FALSE の行は対象外として除外されます。

=GROUPBY(A1:B19,C1:C19,HSTACK(SUM,AVERAGE),3)

HSTACKで横方向にしているので、出力も横に展開されています。
この場合「値」を複数列指定することはできません、複数列指定しても無視されます。
ではVSTACKを使うと、

=GROUPBY(A1:B19,C1:C19,VSTACK(SUM,AVERAGE),3)

VSTACKで縦方向にしているので、出力も縦に展開されています。
この場合「値」を複数列指定することはできません、複数列指定しても無視されます。

=GROUPBY(HSTACK(C1:C19,A1:A19),HSTACK(B1:B19,D1:D19),SUM,3)

行フィールドも値列もHSTACK関数で横に結合して引数に指定しています。
IF関数に配列定数を指定して列の配列を作成する方法もあります。
=GROUPBY(IF({0,1},A1:A19,C1:C19),IF({0,1},D1:D19,B1:B19),SUM,3)

=GROUPBY(TEXT(A1:A19,"yyyy/mm!_")&B1:B19,C1:D19,SUM,3)
年月と品名で集計しています。
元のデータを編集してGROUPBY関数に入れる事が出来ます。
この時に使用できる関数に特に制限ありません。
当然ですが、VLOOKUPやMATCH+INDEX等の関数も使えます。
ただし、上記の例ではCONCAT関数を使う事は出来ません。
（CONCAT関数は19行分全てを1つの文字列にしてしまいます。）

=GROUPBY(IFERROR(VLOOKUP(B1:B19,J1:K3,2,FALSE),"品名VLOOKUP"),C1:D19,SUM,3)
ヘッダーを表示する場合は、上記のようにデータの先頭をヘッダーとして使えるように作成する必要があります。

=GROUPBY(A1:B19,IFERROR(ROUND(C1:D19/1000,0),""),SUM)
値の列も自由に数式を指定することが出来ます。
ただしヘッダーを表示する場合はヘッダー文字列の作成が面倒な場合が多くなると思います。

イータ縮小ラムダ関数は単純にLAMBDA関数に書き換えることが出来ます。
SUM、AVERAGE、MEDIAN、COUNT、COUNTA、、、
これらは、LAMBDA関数の記述を縮小簡略化した書き方です。
従って、もともとのLAMBDA関数で書き直すことが出来ます。
=GROUPBY(...,イータ縮小関数)
↓
=GROUPBY(...,LAMBDA(x,イータ縮小関数(x)))

=GROUPBY(A1:B19,C1:D19,LAMBDA(x,SUM(x)),3)
=GROUPBY(A1:B19,C1:D19,SUM,3)
どちらでも同じになります。
さらに、LET関数を使ってLAMBDA関数を事前に定義しておき、その関数を使う事も出来ます。

=LET(合計,LAMBDA(x,y,SUM(x)*2),
GROUPBY(A1:B19,C1:D19,合計,3))
上記では、「合計」という関数を作成してそれを使っています。
独自に作製する関数名をイータ縮小ラムダ関数と同じにすると、その名前で上書きされます。
誤解の元になるので、このような使い方は避けた方が良いでしょう。

GROUPBY関数の第3引数「関数」に渡す引数は2つ存在します。
以下では、この「関数」に渡す第2引数についての解説になります。
ただし、イータ縮小ラムダには第2引数は渡さません。

=GROUPBY(A1:B19,C1:D19,LAMBDA(x,y,SUM(x)),3)
LAMBDA関数に第2引数を指定することが出来ます。
上記は第1引数しか使っていないので、第1引数だけを指定した場合と同じです。

=GROUPBY(A1:B19,C1:D19,LAMBDA(x,y,SUM(y)),3)
SUM(y)として第2引数を合計しています。
各行の結果が「合計」と同じになっています。
LAMBDA(第1引数,第2引数,計算)
第1引数は各グループごとの計算になります。
第2引数は全体にたいする計算になります。
つまり、
第1引数は各グループごとの配列。
第2引数はデータ全体の配列。

=GROUPBY(A1:B19,C1:C19,LAMBDA(x,y,COUNTA(x)&"-"&COUNTA(y)))
上記のように件数を確認してみると良く分かると思います。
第1引数と第2引数は配列の大きさ（件数）が違うので、
第1引数と第2引数を直接演算するような式はエラーとなります。

第1引数と第2引数をそれぞれ別々に集計した後（つまり1件ずつに集計後）に演算することは問題ありません。

=GROUPBY(A1:B19,C1:D19,LAMBDA(x,y,SUM(x)/SUM(y)),3,2)
これは全体に対する構成比の計算になります。
※この記事を執筆時点では何故かPERCENTOF関数がまだ降りてきていません…
以下はPERCENTOF関数が降りて来たので以下に追記。

=PERCENTOF(data_subset,data_all)
SUM(第1引数) / SUM(第2引数)
従って全合計の値が0の場合は「#DIV/0!」のエラーになります。

=GROUPBY(A1:B19,C1:D19,PERCENTOF,3,2)
先に掲載したLAMBDAと同じ結果となっています。

最後のオプション引数である[field_relationship]は、特定のシナリオで非常に重要な役割を果たします。
この引数の使い方、0と1の具体的な違い、そしてなぜこの引数が必要なのかを解説します。
field_relationship 引数は、GROUPBY関数で複数の「行フィールド」（データをグループ化する列）を指定した場合に、それらのフィールド間の「関係性」をExcelに伝えるためのものです。
この関係性は、集計結果の表示方法（特に小計の有無）や、内部的なデータ処理に影響を与えます。
0 (階層) と 1 (テーブル) の違い

なぜ field_relationship が必要なのか？ (必要性)