VBA技術解説
オブジェクトの探索方法(オートシェイプのTextを探して)

ExcelマクロVBAの問題点と解決策、VBAの技術的解説
公開日:2016-08-07 最終更新日:2020-03-31

オブジェクトの探索方法(オートシェイプのTextを探して)


VBAを書き進めて行くと、どうしてもオブジェクトの扱い時に分からないことがでてきます、
何が分からないかというと、オブジェクトの中の目的の要素をどのように指定したら良いのかということです、
オブジェクトの中を調べて、目的の要素にたどり着く方法を説明します。


ローカルウィンドウを主体に説明します。
イミディエイトウィンドウ、オブジェクトブラウザー、ヘルプも使います。

ローカルウィンドウの基本的な使い方は、
ローカルウィンドウの使い方
VBAのエディター、VBEにはいくつかのウィンドウがあります、その中で、ローカルウィンドウの使い方の説明です、これが使えないと、配列やオブジェクトを扱ったVBAのデバッグに困ることになります。サンプルコードは、以下の表を使っています。まずは、配列でのローカルウィンドウの使い方について。
VBEの使い方:ローカル ウィンドウ
・ローカル ウィンドウの表示 ・ローカル ウィンドウの基本的な使い方 ・ローカル ウィンドウの制限 ・ローカル ウィンドウの最後に

こちら見てください。


オブジェクト探索の説明で使う例題

以下の例を使って説明します。
オートシェイプで、四角の中にテキストを書きました。

マクロ VBA オブジェクト 調べ方

これを、左端に番号順に並べます。
以下のように並べるという事です。

マクロ VBA オブジェクト 調べ方

分かってしまえば簡単なコードです。

Sub sample()
  Dim i As Long
  Dim sp As Shape
  Dim posTop As Single
  For i = 1 To 3
    For Each sp In ActiveSheet.Shapes
      If sp.TextFrame.Characters.Text = "TEST" & i Then
        sp.Top = posTop
        sp.Left = 0
        posTop = posTop + sp.Height
      End If
    Next
  Next
End Sub

もちろん、VBAの書き方はいろいろありますが、
いずれにしろ、たったこれだけです。
このようなオートシェイプをVBAで扱ったことが無いと、なにやら分からないことだらけではないでしょうか。

そもそも、
・オートシェイプを動かすには
・オートシェイプの文字を取得するには
分からないことだらけで、最初から、どうしたらよいのか途方に暮れます。

自動記録を使ってオートシェイプの概要を知る

そこで、誰もがやるであろう自動記録を使って、オートシェイプを動かしてみると、

Sub Macro1()
'
' Macro1 Macro
'

'
  ActiveSheet.Shapes.Range(Array("Rectangle 2")).Select
  Selection.ShapeRange.IncrementLeft -165
  Selection.ShapeRange.IncrementTop -57
End Sub

まず目にとまるのは、
Shapes
オートシェイプのオブジェクトらしいという事です。
このくらいの想像力はVBAをやるなら必要ですね。
そして、複数系なのでコレクションであろうことも理解してください。
Shapes以外は無視しましょう。
ShapeRangeやIncrementは、ちょっと想像しづらいですからひとまず置いときましょう。。

ここまでが分からない場合は、
ExcelマクロVBA入門
・VBA学習の進め方について ・1. VBAの基礎・基本:VBA入門 ・2. VBA入門に必要なVBEの基本的使い方 ・3. VBAプログラミングの基礎・基本 ・4. Excel各種機能とオブジェクトの理解:VBA入門 ・5. VBA初級からVBA中級を目指して ・6. VBA入門の後日追加記事 ・7. VBA入門その後の学習について ・「VBA入門」の記事を学校の授業もしくは企業研修でお使いになる場合
こちらで勉強してください。
コレクションについては、
第58回.コレクションとは
・コレクションの中から単一オブジェクトを指定する場合 ・セルであるRangeオブジェクトのコレクションは? ・コレクションの要素数 ・Collectionオブジェクト

つまり、オートシェイプは、
Shapeオブジェクトであり、Shapesコレクションに含まれるという事ですね。
ここまで分かると、以下のコードが書けます。

Sub sample()
  Dim i As Long
  Dim sp As Shape
  Dim posTop As Single
  For i = 1 To 3
    For Each sp In ActiveSheet.Shapes
      
    Next
  Next
End Sub

ローカルウィンドウでオートシェイプのテキストを調べる

テキスト内の数字を1~3の順に並べる為に、数字順に処理しようという事ですが、
問題は、オートシェイプのテキストをどのように取得するかです。
Stopを入れて、停止させてみましょう。

マクロ VBA オブジェクト 調べ方

ここで、ローカルウィンドウを表示してみましょう。

マクロ VBA オブジェクト 調べ方

spを展開しましょう。

マクロ VBA オブジェクト 調べ方

かなり多くのメンバーがあり、どれがテキストなのか・・・
それでは、VBAを終了させて、あらためて自動記録でテキストを変更してみましょう。
"TEXT1"を"TEXT11"に変更してみます。

Sub Macro2()
'
' Macro2 Macro
'

'
  ActiveSheet.Shapes.Range(Array("Rectangle 2")).Select
  Selection.ShapeRange(1).TextFrame2.TextRange.Characters.Text = "TEST11"
  With Selection.ShapeRange(1).TextFrame2.TextRange.Characters(1, 6). _
    ParagraphFormat
    .FirstLineIndent = 0
    .Alignment = msoAlignLeft
  End With
  With Selection.ShapeRange(1).TextFrame2.TextRange.Characters(1, 6).Font
    .NameComplexScript = "+mn-cs"
    .NameFarEast = "+mn-ea"
    .Fill.Visible = msoTrue
    .Fill.ForeColor.ObjectThemeColor = msoThemeColorLight1
    .Fill.ForeColor.TintAndShade = 0
    .Fill.ForeColor.Brightness = 0
    .Fill.Transparency = 0
    .Fill.Solid
    .Size = 18
    .Name = "+mn-lt"
  End With
  Range("A1").Select
End Sub

"TEST11"と書かれている行をみてみると、
Selection.ShapeRange(1).TextFrame2.TextRange.Characters.Text = "TEST11"
何やら、

ShapeRange
TextFrame2
TextRange
Characters


このあたりを使うようです。
順に適当に和訳して、まずは適当に解釈して見当をつけます。

図形範囲
テキスト枠
テキスト範囲
文字列


この、適当に和訳して見当を付けるのが重要です。
いちいち全てを調べていたのでは、時間がいくらあっても足りません。
ShapeRangeはオートシェイプの集まり、つまりは、Shapesと同じようなものではないかと、
なので、無視して次へ(ここで気になる場合はググって調べましょう)
TextFrame2ここに核心のテキストがはいっていそうだと、このように目星をつけます。

では、TEST11をTEST1に戻しておいて、
最初のsampleを実行して、ローカルウィンドウでspの中を探してみましょう。

マクロ VBA オブジェクト 調べ方

TextFrame2の中に、先の自動記録で見つけた、
TextRangeがありました、これをさらに展開すると、

マクロ VBA オブジェクト 調べ方

TEXTの値に、"TEST2"が見つかりました。
つまり、

sp.TextFrame2.TextRange.Text

これでオートシェイプ内のテキストを取得できそうです。
イミディエイトウィンドウで確かめてみると、

マクロ VBA オブジェクト 調べ方

間違いなく取得できています。
このTextを文字列を判定すれば出来そうですね。

オートシェイプの位置移動について

次は、オートシェイプの位置の移動です。
最初の自動記録では、

Selection.ShapeRange.IncrementLeft -165
Selection.ShapeRange.IncrementTop -57

Increment(増加、増大と言った英単語)がどうもそのようなのですが・・・
ここは、慣れと事前知識が必要かもしれません。
Incrementなので、場所を特定しているのではなく、現在位置からの移動量を指定しているのだろうと推測できるのです。
IncrementLeftで左位置の移動、IncrementTopで上位置の移動
移動量だからIncrementが付く、だったらIncrementを付けずに、Left、Topでよくねー・・・
のようなノリで調べてみると良いでしょう。
ローカルウィンドウでspの中を探してみましょう。

マクロ VBA オブジェクト 調べ方

マクロ VBA オブジェクト 調べ方

ありますね、LeftTop
しかも数値をみれば、絶対位置であることも想像できるでしょう。
ここまで調べたら、ヘルプ(MSのVBAリファレンス)も使いましょう。
「vba shape top」このような感じでぐぐってみると良いでしょう。

図形範囲の最前面にある図形の上端から、ワークシートの上端までの距離をポイント単位で表す単精度浮動小数点型 (single) の値を取得、または設定します。

まさにこれで間違いがないことが分かりますし、数値はポイントであることも分かります。

VBAを完成させる

以上をもとにVBAコードを完成させると、

Sub sample()
  Dim i As Long
  Dim sp As Shape
  Dim posTop As Single
  For i = 1 To 3
    For Each sp In ActiveSheet.Shapes
      If sp.TextFrame2.TextRange.Text = "TEST" & i Then
        sp.Top = posTop
        sp.Left = 0
        posTop = posTop + sp.Height
      End If
    Next
  Next
End Sub

あれれ、最初のVBAコードと何やら少し違う・・・

最初のコードは、
If sp.TextFrame.Characters.Text = "TEST" & i Then
最後のコードは、
If sp.TextFrame2.TextRange.Text = "TEST" & i Then

先に解説しますと、
TextFrame2は、Excel2007で追加されたプロパティで、
TextFrameは、それ以前からあるプロパティです。
どちらでも、結果は同じです。

オブジェクトブラウザーを使いさらにオブジェクトを調べる

では、
sp.TextFrame.Characters.Text
このコードにはどのようにたどり着いたら良いでしょうか。

マクロ VBA オブジェクト 調べ方

どうも、TextCharacterといったキーワードが見当たりません。
ローカルウィンドウの使い方
こちらに書きましたが、ローカルウィンドウのメンバーにはすべてが表示されているわけではありません。
そこで、
オブジェクトブラウザー(F2)を見てみましょう。

マクロ VBA オブジェクト 調べ方

ありました、
Characters
これっぽいですよね、
慣れてくれば、VBEのインテリセンス(候補表示)で見つけられるようになり、
さらに、その下の.Textも簡単に見つけられます。

マクロ VBA オブジェクト 調べ方

マクロ VBA オブジェクト 調べ方

しかし、もっと階層のあるオブジェクトの場合、インテリセンス(候補表示)だけではなかなか探せない時もあります。
そんな時は、判明したオブジェクトを一旦オブジェクト変数にいれて、ローカルウィンドウを見ます

マクロ VBA オブジェクト 調べ方

オブジェクトを調べたいので、オブジェクトの型は汎用のObjectにします。
大抵はプロパティ名と同じですが、調べるだけなのでObjectで十分でしょう。

マクロ VBA オブジェクト 調べ方

確かに、Textがありました。
Fontもありますね。
Captionにも同じ"TEST2"がありますが、今回の場合はTextでよいでしょう。

このようにオブジェクトを探索できるようになれば、どんなオブジェクトでも自分で調べて自在にVBAを書くことができるようになります。

ローカルウィンドウ、イミディエイトウィンドウ、オブジェクトブラウザー、ヘルプ
これがあれば何も要らない

ウォッチウィンドウについて

今回は、ローカルウィンドウを中心に説明しましたが、適宜ウォッチウィンドウも使って、効率的に調べるようにしてください。

VBEの使い方:ウォッチ ウィンドウ
・ウォッチ ウィンドウの表示 ・ウォッチ ウィンドウとは ・「ウォッチ式の追加」の操作手順 ・ウォッチ式の追加 ・ウォッチ ウィンドウの制限と注意 ・ウォッチ ウィンドウの最後に

マクロ VBA オブジェクト 調べ方



同じテーマ「マクロVBA技術解説」の記事

文字種(ひらがな、全半角カタカナ、半角英大文字等々)の判定

マクロVBAで、文字の種類を判定する具体的なコードになります、書き方はいろいろありますし、なにより、文字を何の種類に入れるかは決まりがありません。カタカナって、どこからどこまで、カナ記号は含むの このような細部については、使用する時々に合わせて微調整が必要になります。
オブジェクトとプロパティの真実
オブジェクトとプロパティについて、解説をします。対象は、VBA中級以上になると思いますが、初級の方でも、VBAって奥が深いんだなーと感動位は出来ると思います。(笑) ただし、あまり役には立たないかもしれませんので、あしからず。
オブジェクト式について
・オブジェクト式の書き方 ・オブジェクトは直接指定できない ・オブジェクト式の書き始めは何か ・メソッドとプロパティの違いについて ・オブジェクト式の最後に
オブジェクトの探索方法(オートシェイプのTextを探して)
条件付きコンパイル(32ビット64ビットの互換性)
条件付きコンパイルは、VBAの特定のコードブロックを選択してコンパイルします、VBAの他の部分は無視されます、条件付きコンパイルステートメントは、実行時ではなくコンパイル時に実行されます。条件に基づいてコンパイルするコードのブロックを指定するには #If...Then...#Elseディレクティブを使用します。
ドキュメントプロパティ(BuiltinDocumentProperties,CustomDocumentProperties)
・組み込みドキュメントプロパティ(BuiltinDocumentProperties) ・組み込みドキュメントプロパティを一覧出力 ・組み込みドキュメントプロパティの値を変更する ・組み込みドキュメントプロパティを消去する ・ ・ユーザー設定のドキュメントプロパティを一覧出力 ・ユーザー設定のドキュメントプロパティを追加する ・ユーザー設定のドキュメントプロパティを削除する
VBAでファイルを既定のアプリで開く方法
・実行テストメイン ・Shell関数 ・batファイル(コマンド プロンプト) ・WScript.Shell ・Shell.Application ・FollowHyperlink ・最後に
Excelアドインの作成と登録について
・Excelアドインについて ・アドインファイルのフォルダ ・アドインの作り方 ・アドインの登録と有効化 ・ ・アドインで保存するVBA ・アドインを登録するVBA ・アドインを有効化するVBA ・登録されているアドインを確認するVBA ・アドインマネージャーを表示するVBA ・アドイン配布時に自動登録するVBA ・個人用マクロブックについて
VBAでのタイマー処理(SetTimer,OnTime)
・Application.OnTime メソッド ・WindowsAPI:SetTimer関数 ・最後に
マクロでShift_JIS文字コードか判定する
・文字コードについて ・UnicodeにあってShift_JISにない文字の具体例 ・シート構成 ・配列数式での判定 ・Shift_JIS文字コードか判定するマクロVBA全コード ・最後に
Byte配列と文字コード関数について
・文字列をByte配列に入れる ・文字コードについて ・文字列をByte配列に入れて、文字列に戻す ・文字列をByte配列に入れて、自力で文字列に戻す ・文字列をSJISに変換してからByte配列にいれて、自力で文字列に戻す ・最後に


新着記事NEW ・・・新着記事一覧を見る

テンキーのスクリーンキーボード作成|ユーザーフォーム入門(2024-02-26)
無効な前方参照か、コンパイルされていない種類への参照です。|エクセル雑感(2024-02-17)
初級脱出10問パック|VBA練習問題(2024-01-24)
累計を求める数式あれこれ|エクセル関数応用(2024-01-22)
複数の文字列を検索して置換するSUBSTITUTE|エクセル入門(2024-01-03)
いくつかの数式の計算中にリソース不足になりました。|エクセル雑感(2023-12-28)
VBAでクリップボードへ文字列を送信・取得する3つの方法|VBA技術解説(2023-12-07)
難しい数式とは何か?|エクセル雑感(2023-12-07)
スピらない スピル数式 スピらせる|エクセル雑感(2023-12-06)
イータ縮小ラムダ(eta reduced lambda)|エクセル入門(2023-11-20)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.RangeとCellsの使い方|VBA入門
3.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
4.繰り返し処理(For Next)|VBA入門
5.変数宣言のDimとデータ型|VBA入門
6.ブックを閉じる・保存(Close,Save,SaveAs)|VBA入門
7.並べ替え(Sort)|VBA入門
8.条件分岐(IF)|VBA入門
9.セルのクリア(Clear,ClearContents)|VBA入門
10.マクロとは?VBAとは?VBAでできること|VBA入門




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。



このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
本文下部へ