VBAサンプル集
全シートの画面キャプチャを取得する（keybd_event）

Option Explicit

Declare Sub keybd_event Lib "user32.dll" (ByVal bVk As Byte, _
　　　　　　　　　　　　　　　　　　　　 ByVal bScan As Byte, _
　　　　　　　　　　　　　　　　　　　　 ByVal dwFlags As Long, _
　　　　　　　　　　　　　　　　　　　　 ByVal dwExtraInfo As Long)

Const KEYEVENTF_EXTENDEDKEY = &H1 'キー押下

Const KEYEVENTF_KEYUP = &H2　　　　 'キー解放

Sub Sample()
　　Dim addSht As Worksheet
　　Dim mySht As Variant
　　Dim i As Long
　　Dim lngRow As Long
　　Dim lngHeight As Long
　　'VBEから起動した場合の為に
　　AppActivate Application.Caption
　　'新規シートを追加
　　Set addSht = ActiveWorkbook.Worksheets.Add
　　'2行目から貼り付け
　　lngRow = 2
　　addSht.Cells(lngRow, 1).Select
　　For Each mySht In ActiveWorkbook.Sheets
　　　　If Not mySht Is addSht Then
　　　　　　mySht.Select
　　　　　　DoEvents

　　　　　　'Alt+PrntScrn押下、解放
　　　　　　keybd_event vbKeyMenu, 0, KEYEVENTF_EXTENDEDKEY, 0
　　　　　　keybd_event vbKeySnapshot, 0, KEYEVENTF_EXTENDEDKEY, 0
　　　　　　keybd_event vbKeySnapshot, 0, KEYEVENTF_EXTENDEDKEY Or KEYEVENTF_KEYUP, 0
　　　　　　keybd_event vbKeyMenu, 0, KEYEVENTF_EXTENDEDKEY Or KEYEVENTF_KEYUP, 0

　　　　　　DoEvents
　　　　　　With addSht
　　　　　　　　.Select
　　　　　　　　.Paste
　　　　　　　　Selection.ShapeRange.ScaleHeight 0.3, msoFalse, msoScaleFromTopLeft
　　　　　　　　'画像の高さ分、行を下げる
　　　　　　　　lngHeight = 0
　　　　　　　　Do While lngHeight < Selection.Height
　　　　　　　　　　lngHeight = lngHeight + Rows(lngRow).RowHeight
　　　　　　　　　　lngRow = lngRow + 1
　　　　　　　　Loop
　　　　　　　　lngRow = lngRow + 1
　　　　　　　　.Cells(lngRow, 1).Select
　　　　　　End With
　　　　End If
　　Next
End Sub