写真の取込方法について（Pictures.Insert,Shapes.AddPicture）
写真を取り込んで、アルバムのようにしたり、
各種の資料を作ったりと、写真をエクセルに取り込む機会は多いようです。
手動で取り込んだままではスクロールもままならない状態となってしまいます。
さらにセル内に収まるように縮小するマクロVBAになります。
Pictures.Insertメソッド
まずは、マクロの記録でも使われているPictures.Insertメソッドを使ったVBAサンプルです。
これで、とりあえず、ちゃんと貼りつきます。
シートには、写真そのものではなく、写真ファイルへのリンクが挿入されます。
このことにより、元ファイルが取り込んだ時のフォルダーに存在しないと表示できません。
これは不都合な場合が多いでしょう。
エクセルファイルだけでは配布できないですし、Excelファイルまたはファイル写真ファイルを移動してしまうとリンク切れとなってしまいます。
以下では、写真をリンクではなくエクセルに貼り付けています。
Sub sample1()
Dim ws As Worksheet
Dim FileName As Variant
Dim sp As Shape
Dim i As Long
Dim j As Long
Dim dblScal As Double
FileName = Application.GetOpenFilename( _
FileFilter:="画像ファイル,*.bmp;*.jpg;*.gif", _
MultiSelect:=True)
If Not IsArray(FileName) Then
Exit Sub
End If
Set ws = ActiveSheet
For Each sp In ws.Shapes
If sp.TopLeftCell.Column = 1 Then
sp.Delete
End If
Next
j = 1
For i = LBound(FileName) To UBound(FileName)
ws.Cells(j, 1).Select
With ws.Pictures.Insert(FileName(i))
'サイズ調整、セル内に収める
If ws.Cells(j, 1).Width / .Width < ws.Cells(j, 1).Height / .Height Then
dblScal = WorksheetFunction.RoundDown(ws.Cells(j, 1).Width / .Width, 2)
Else
dblScal = WorksheetFunction.RoundDown(ws.Cells(j, 1).Height / .Height, 2)
End If
.Width = .Width * dblScal '縦横比を維持して縮小される
End With
j = j + 1
Next i
End Sub
これで、とりあえず、ちゃんと貼りつきます。
シートには、写真そのものではなく、写真ファイルへのリンクが挿入されます。
このことにより、元ファイルが取り込んだ時のフォルダーに存在しないと表示できません。
エクセルファイルだけでは配布できないですし、Excelファイルまたはファイル写真ファイルを移動してしまうとリンク切れとなってしまいます。
以下では、写真をリンクではなくエクセルに貼り付けています。
Shapes.AddPictureメソッド
Shapes.AddPictureメソッドを使ってリンクではなく写真を取り込みます。
Shapes.AddPictureメソッドの構文
Shapes.Addpicture(FileName、 linktofile、 savewithdocument、 Left、 Top、 Width、
Height)
全ての引数が必須です。
| 名前 | データ型 | 説明 |
| FileName | String | 図を作成するファイルを指定します。 |
| LinkToFile | MsoTriState | 図をグラフィック ファイルとリンクするかどうかを指定します。 MsoFalseを使用して、画像をファイルの独立したコピーとして作成します。 MsoTrueを使用して、図を作成元のファイルにリンクします。 |
| SaveWithDocument | MsoTriState | 文書を保存するときに図も一緒に保存するかどうかを指定します。 ドキュメントにリンク情報のみを格納するには、msoFalseを使用します。 MsoTrueを使用して、リンクされた図を挿入先の文書と共に保存します。 もしLinkToFileがmsoFalseの場合は、この引数をmsoTrueに設定する必要があります。 |
| Left | Single | 文書の左上隅を基準にして図の左上隅の位置をポイント単位で指定します。 |
| Top | Single | 文書の上端を基準にして図の左上隅の位置をポイント単位で指定します。 |
| Width | Single | ポイント単位での図の幅 (既存ファイルの幅を保持する場合は、-1 を入力してください)。 |
| Height | Single | ポイント単位での図の高さ (既存ファイルの高さを保持する場合は、-1 を入力してください)。 |
全ての引数が必須です。
Sub sample2()
Dim i As Long
Dim j As Long
Dim FileName As Variant
Dim dblScal As Double
Dim sp As Shape
FileName = Application.GetOpenFilename( _
FileFilter:="画像ファイル,*.bmp;*.jpg;*.gif", _
MultiSelect:=True)
If Not IsArray(FileName) Then
Exit Sub
End If
For Each sp In ActiveSheet.Shapes
If sp.TopLeftCell.Column = 1 Then
sp.Delete
End If
Next
j = 1
For i = LBound(FileName) To UBound(FileName)
Cells(j, 1).Select
With ActiveSheet.Shapes.AddPicture( _
FileName:=FileName(i), _
LinkToFile:=False, _
SaveWithDocument:=True, _
Left:=Selection.Left, _
Top:=Selection.Top, _
Width:=0, _
Height:=0)
'一旦、元のサイズに戻す
.ScaleHeight 1, msoTrue
.ScaleWidth 1, msoTrue
'サイズ調整、セル内に収める
If Cells(j, 1).Width / .Width < Cells(j, 1).Height / .Height Then
dblScal = WorksheetFunction.RoundDown(Cells(j, 1).Width / .Width, 2)
Else
dblScal = WorksheetFunction.RoundDown(Cells(j, 1).Height / .Height, 2)
End If
.Width = .Width * dblScal
.Height = .Height * dblScal
End With
j = j + 1
Next i
End Sub
Shapes.AddPictureでの取込時点では、サイズが不明なので、
Width:=0
Height:=0)
で、サイズ0で取り込んでいます。
その後、一旦、元のサイズに戻した後に、セル内に収めています。
.LockAspectRatio = msoTrue
この指定をしてからサイズ変更すれば、WidthとHeightのどちらかの設定で済みます。
その場合は、単純にセルのWidthまたはHeightを超えていたら設定するだけでも良いです。
.Placement = xlMoveAndSize
この指定を入れてください。
'縦横比を固定
.LockAspectRatio = msoTrue
'セルにあわせて移動やサイズ変更
.Placement = xlMoveAndSize
'一旦、元のサイズに戻す
.ScaleHeight 1, msoTrue
.ScaleWidth 1, msoTrue
'幅をセル内に収める
If .Width > Cells(j, 1).Width Then
.Width = Cells(j, 1).Width
End If
'高さをセル内に収める
If .Height > Cells(j, 1).Height Then
.Height = Cells(j, 1).Height
End If
画像サイズを小さくして、サムネイルとして取り込む方法は以下を参照してください。
Shapesに関連する記事
図形オートシェイプ（Shape）｜VBA入門
・図形オートシェイプ（Shape）関連のオブジェクト群 ・図形オートシェイプ（Shape）の追加 ・図形オートシェイプ（Shape）の削除 ・図形オートシェイプ（Shape）の編集 ・図形オートシェイプ（Shape）の全選択 ・図形オートシェイプ（Shape）の扱い方を工夫する ・オートシェイプ（Shape）を扱う実践例 ・図形オートシェイプ（Shape）に関連する記事
オートシェイプを他ブックの同じ位置に貼り付ける（Shapes,DrawingObjects）コメントでリクエストを頂きました。「１つのシートにバラバラにあるオートシェープを一度に選択して、コピーし、ほかのブックのあるシートの同じ位置にペーストしたい」というもの。これには色々な問題が含まれています。
図形オートシェイプ（Shape）の複数選択・ワークシートの全てのShapeを選択する場合 ・ShapeオブジェクトのSelectメソッド ・ShapeRangeオブジェクト ・シート内の指定名称の図形を選択
ShapesとDrawingObjectsの相違点と使い方・Shapes コレクション ・DrawingObjects コレクション ・ShapesとDrawingObjectsの相違点 ・DrawingObjectsの便利な使い道 ・最後に ・図形オートシェイプ（Shape）に関連する記事
同じテーマ「マクロVBAサンプル集」の記事
図を確認しながら消していく（Shape）
オートシェイプを他ブックの同じ位置に貼り付ける（Shapes,DrawingObjects）
全シートの画面キャプチャを取得する（keybd_event）
写真の取込方法について（Pictures.Insert,Shapes.AddPicture）
写真をサムネイルに変換して取り込む（Shapes.AddPicture）
円グラフの色設定（Chart,SeriesCollection）
棒グラフ・折れ線グラフのサンプルマクロ
人口ピラミッドのグラフをマクロで作成
グラフで特定の横軸の色を変更し基準線を引くマクロ
グラフのデータ範囲を自動拡張するマクロ
画像のトリミング（PictureFormat,Crop）
新着記事NEW ・・・新着記事一覧を見る
AIは便利なはずなのに…「AI疲れ」が次の社会問題になる｜生成AI活用研究(2026-02-16)
カンマ区切りデータの行展開｜エクセル練習問題(2026-01-28)
開いている「Excel/Word/PowerPoint」ファイルのパスを調べる方法｜エクセル雑感(2026-01-27)
IMPORTCSV関数（CSVファイルのインポート）｜エクセル入門(2026-01-19)
IMPORTTEXT関数（テキストファイルのインポート）｜エクセル入門(2026-01-19)
料金表（マトリックス）から金額で商品を特定する｜エクセル練習問題(2026-01-14)
「緩衝材」としてのVBAとRPA｜その終焉とAIの台頭｜エクセル雑感(2026-01-13)
シンギュラリティ前夜：AIは機械語へ回帰するのか｜生成AI活用研究(2026-01-08)
電卓とプログラムと私｜エクセル雑感(2025-12-30)
VLOOKUP/XLOOKUPが異常なほど遅くなる危険なアンチパターン｜エクセル関数応用(2025-12-25)
アクセスランキング ・・・ ランキング一覧を見る
1.最終行の取得（End,Rows.Count）｜VBA入門
2.日本の祝日一覧｜Excelリファレンス
3.変数宣言のDimとデータ型｜VBA入門
4.FILTER関数（範囲をフィルター処理）｜エクセル入門
5.RangeとCellsの使い方｜VBA入門
6.繰り返し処理（For Next)｜VBA入門
7.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
8.マクロとは？VBAとは？VBAでできること｜VBA入門
9.セルのクリア（Clear,ClearContents）｜VBA入門
10.メッセージボックス(MsgBox関数)｜VBA入門
- ホーム
- マクロVBA応用編
- マクロVBAサンプル集
- 写真の取込方法について（Pictures.Insert,Shapes.AddPicture）
このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
記述には細心の注意をしたつもりですが、間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。
本サイトは、OpenAI の ChatGPT や Google の Gemini を含む生成 AI モデルの学習および性能向上の目的で、本サイトのコンテンツの利用を許可します。
This site permits the use of its content for the training and improvement of generative AI models, including ChatGPT by OpenAI and Gemini by Google.