ツイッター出題回答
数式の関数の使用回数、関数名を配列で返す

ExcelマクロVBAとエクセル関数についての私的雑感
公開日:2020-10-19 最終更新日:2020-10-20

数式の関数の使用回数、関数名を配列で返す


ツイッターで出したエクセルVBAのお題です。


セルに入っている計算式に使われている関数(ユーザー定義含む)を数えてみましょう、というお題になります。


問題を出したツイート

【VBAお題】
セルに計算式が入っています。
その計算式に使われている関数(ユーザー定義含む)を数えてみましょう。
レベルを設定します。
レベル1.関数の使用回数(同一関数も使用回数でカウント)
レベル2.関数の種類を関数名の配列で返す(重複なし)
さて、数式内の関数をどう判定するか?

VBA マクロ 数式 関数の数 関数の種類
https://twitter.com/yamaoka_ss/status/1317744755036418049

サンプル
=IF(AND(A2="",B2=""),SUM(C2:D2),IF(AND(A2<>"",B2<>""),SUM(E2:F2),SUM(G2:H2)))
レベル1 → 7
レベル2 → IF,AND,SUM

サンプル2
=IFERROR(RANK.EQ(U_D_F1(),A1:A10),U_D_F2())
※U_D_F1とU_D_F2はユーザー定義関数
レベル1 → 4
レベル2 → IFERROR,RANK.EQ,U_D_F1,U_D_F2

サンプル3
="SUM()"
今回は、こういうのは考えないことにしましょう。

="SUM()"
このような文字列内の関数っぽいのは無視して(考慮しなくて)構いません。
ユーザー定義関数の日本語(全角)使用も無視して良いです。


用意した解答

正規表現を使った方法

'関数の使用回数
Function CountOfFunctions(ByVal argFormula As String) As Long
  Dim re As Object
  Dim mc As Object
  Set re = CreateObject("VBScript.RegExp")
  re.Global = True
  
  re.Pattern = "(([.\w]|[^\x01-\x7E])+(?=\())"
  Set mc = re.Execute(argFormula)
  
  CountOfFunctions = mc.Count
End Function

'関数の種類を関数名の配列で返す
Function TypeOfFunctions(ByVal argFormula As String) As Variant
  Dim re As Object
  Dim mc As Object
  Dim m As Object
  Set re = CreateObject("VBScript.RegExp")
  re.Global = True
  
  re.Pattern = "(([.\w]|[^\x01-\x7E])+(?=\())"
  Set mc = re.Execute(argFormula)
  
  Dim dic As Object
  Set dic = CreateObject("Scripting.Dictionary")
  For Each m In mc
    dic(m.Value) = ""
  Next
  
  Dim ary
  ary = dic.keys()
  TypeOfFunctions = ary
End Function

正規表現については以下を参照してください。
VBAで正規表現を利用する(RegExp)
正規表現は複雑なパターンマッチングとテキストの検索置換するためのツールです、マクロVBAで正規表現を使う場合はRegExpオブジェクトを使用します、RegExpは、VBScriptに正規表現として用意されているオブジェクトです。目次 メタ文字 正規表現 正規表現RegExpの使い方 RegExpオブジェクト Reg…

お題の補足として、
サンプル3
="SUM()"
今回は、こういうのは考えないことにしましょう。

="SUM()"
このような文字列内の関数っぽいのは無視して(考慮しなくて)構いません。
ユーザー定義関数の日本語(全角)使用も無視して良いです。

このように書きましたが、上記では全角は対応しています。
文字列として入っている関数っぽいものは未対応です。

文字列の関数っぽいものを排除するなら、
1度にやろうとするとパターンが複雑になってしまうので、別途""の中を消してしまったほうが簡単ではないでしょうか。

re.Pattern = "(""[^""]*"")"
argFormula = re.Replace(argFormula, "")

これをExecuteの前に実行しておけば良いと思います。
またユーザー定義関数では全角文字も扱えるので、
とりあえず対応しましたが、VBAで許可されている範囲の方が小さいはずなのでこれで大丈夫だと思います。

正規表現以外の方法

'関数の使用回数
Function CountOfFunctions(ByVal argFormula As String) As Long
  Dim cnt As Long
  Dim iStart As Long
  Dim s As String
  
  cnt = 0
  iStart = 1
  Do
    iStart = InStr(iStart + 1, argFormula, "(")
    If iStart = 0 Then Exit Do
    s = UCase(Mid(argFormula, iStart - 1, 1))
    If s Like "[A-Z]" Or _
      s Like "[0-9]" Or _
      s = "_" Or _
      LenB(StrConv(s, vbFromUnicode)) = 2 Then
      cnt = cnt + 1
    End If
  Loop
  CountOfFunctions = cnt
End Function

'関数の種類を関数名の配列で返す
Function TypeOfFunctions(ByVal argFormula As String) As Variant
  Dim dic As Object
  Set dic = CreateObject("Scripting.Dictionary")
  Dim iStart As Long
  Dim ix As Long
  Dim s As String
  
  iStart = 1
  Do
    iStart = InStr(iStart + 1, argFormula, "(")
    If iStart = 0 Then Exit Do
    s = getFunctionString(argFormula, iStart)
    If s <> "" Then
      dic(s) = ""
    End If
  Loop
  
  Dim ary
  ary = dic.keys()
  TypeOfFunctions = ary
End Function

'関数名を取得する
Function getFunctionString(ByVal argFormula As String, ByVal iStart As Long) As String
  Dim ix As Long
  Dim s As String
  ix = iStart
  Do
    ix = ix - 1
    If ix = 0 Then Exit Do
    s = UCase(Mid(argFormula, ix, 1))
    If s Like "[A-Z]" Or _
      s Like "[0-9]" Or _
      s = "_" Or _
      s = "." Or _
      LenB(StrConv(s, vbFromUnicode)) = 2 Then
    Else
      Exit Do
    End If
  Loop
  getFunctionString = Mid(argFormula, ix + 1, iStart - ix - 1)
End Function

お題の補足として、
サンプル3
="SUM()"
今回は、こういうのは考えないことにしましょう。

="SUM()"
このような文字列内の関数っぽいのは無視して(考慮しなくて)構いません。
ユーザー定義関数の日本語(全角)使用も無視して良いです。

このように書きましたが、上記では全角は対応(2バイト文字として判定)しています。
文字列として入っている関数っぽいものは未対応です。

文字列の関数っぽいものを排除するなら、
1度にやろうとせずに、事前に""の中を消してしまったほうが簡単だと思います。

Function delDoubleQuote(ByVal argFormula As String) As String
  Dim i As Long
  Dim iStart As Long
  Dim iEnd As Long
  Dim s As String
  
  iStart = 0
  Do
    iStart = InStr(iStart + 1, argFormula, """")
    If iStart = 0 Then Exit Do
    iEnd = InStr(iStart + 1, argFormula, """")
    If iEnd = 0 Then Exit Do
    Mid(argFormula, iStart, iEnd - iStart + 1) = Space(iEnd - iStart + 1)
    iStart = iEnd
  Loop
  delDoubleQuote = argFormula
End Function

これをDo...Loopの前に実行して数式文字列から""の文字列を排除してしまうと簡単だと思います。

使用方法

A列に数式の文字列を入れておきます。

Sub test()
  Dim i As Long
  Dim ary
  Range("A1").CurrentRegion.Offset(, 1).ClearContents
  For i = 1 To Cells(Rows.Count, 1).End(xlUp).Row
    Cells(i, 2) = CountOfFunctions(Cells(i, 1).Value)
    ary = TypeOfFunctions(Cells(i, 1).Value)
    If UBound(ary) >= 0 Then
      Cells(i, 3).Resize(, UBound(ary) - LBound(ary) + 1) = ary
    End If
  Next
End Sub

セルに入っている数式なら、Formulaを取得するようにしてください。

VBA マクロ 数式 関数の数 関数の種類




同じテーマ「ツイッター出題回答 」の記事

greeenはgreenに、greeeeeNをGReeeeNに変換
数値変数の値を別の変数を使わずに入れ替える
Rangeオブジェクトを受け取り"行数,列数"で埋める
数式の関数の使用回数、関数名を配列で返す
日付型と通貨型のValueとValue2について
小文字"abc"を大文字"ABC"に変換する方法
オブジェクトのByRef、ByVal、Variant
「マクロの登録」で登録できないプロシージャーは?
ジャグ配列から順列を作成する
シート内の全テーブルを1つに統合
VBA穴埋め問題「On Error GoToの挙動」


新着記事NEW ・・・新着記事一覧を見る

ExcelマクロVBA入門目次|エクセルの神髄(2024-03-20)
VBA10大躓きポイント(初心者が躓きやすいポイント)|VBA技術解説(2024-03-05)
テンキーのスクリーンキーボード作成|ユーザーフォーム入門(2024-02-26)
無効な前方参照か、コンパイルされていない種類への参照です。|エクセル雑感(2024-02-17)
初級脱出10問パック|VBA練習問題(2024-01-24)
累計を求める数式あれこれ|エクセル関数応用(2024-01-22)
複数の文字列を検索して置換するSUBSTITUTE|エクセル入門(2024-01-03)
いくつかの数式の計算中にリソース不足になりました。|エクセル雑感(2023-12-28)
VBAでクリップボードへ文字列を送信・取得する3つの方法|VBA技術解説(2023-12-07)
難しい数式とは何か?|エクセル雑感(2023-12-07)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.RangeとCellsの使い方|VBA入門
3.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
4.繰り返し処理(For Next)|VBA入門
5.変数宣言のDimとデータ型|VBA入門
6.ブックを閉じる・保存(Close,Save,SaveAs)|VBA入門
7.並べ替え(Sort)|VBA入門
8.条件分岐(IF)|VBA入門
9.セルのクリア(Clear,ClearContents)|VBA入門
10.マクロとは?VBAとは?VBAでできること|VBA入門




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。



このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
本文下部へ