ツイッター出題回答
greeenはgreenに、greeeeeNをGReeeeNに変換

ExcelマクロVBAとエクセル関数についての私的雑感
公開日:2020-09-13 最終更新日:2020-10-20

greeenはgreenに、greeeeeNをGReeeeNに変換


ツイッターで出したエクセルの入力規則のお題です。


「greeenはgreenに、greeeeeNやGReeeeeenはGReeeeNに直す」
文字列操作のVBA問題です。

問題を出したツイート

【VBA問題】
greenは緑です。GReeeeNは音楽グループです。
「greeenはgreenに、greeeeeNやGReeeeeenはGReeeeNに直す」
引数の文字列を直して返す関数を作りましょう。
3連続eは2つに、5連続以上のeは4つに。
上記文字列なら以下を返す。
「greenはgreenに、GReeeeNやGReeeeNはGReeeeNに直す」


補足します。
Debug.Print 関数("greeenはgreenに、greeeeeNやGReeeeeenはGReeeeNに直す")

'"greenはgreenに、GReeeeNやGReeeeNはGReeeeNに直す"
このような関数を作成するという事です。


VBA マクロ 文字列操作
https://twitter.com/yamaoka_ss/status/1304650741550690309


VBA マクロ 文字列操作
https://twitter.com/yamaoka_ss/status/1304681634545807361


お寄せいただいた回答ツイート

以下のモーメントにまとめました。

VBA マクロ 文字列操作
https://twitter.com/i/events/1304779848389332992

用意した解答

頂いた回答を大別すると以下の3通りに分かれます。
・正規表現を使う
・ループして文字列を見つけて置換する
・文字列長-3の"e"を最大として置換しまくる

最初の2通りについては、問題を出した直後に私の方で作成しておいたものです。
最後の方法は事前には私は考えなかったものでしたので、後で追加しました。

正規表現を使う

Sub sample()
  Debug.Print fncGreen("greeenはgreenに、greeeeeNやGReeeeeenはGReeeeNに直す")
  Debug.Print fncGreen("grEEn、GreeeN、grEEEEn、greeeeeN、GReeeeeen、GREEEEEEEN")
End Sub

Function fncGreen(ByVal argStr As String) As String
  fncGreen = argStr
  
  Dim reg As Object
  Set reg = CreateObject("VBScript.RegExp")
  reg.Global = True '文字列全体
  reg.IgnoreCase = True '大文字小文字を区別しない
  
  'gre(4以上)nをGReeeeN
  reg.Pattern = "(gre{4,}n)"
  fncGreen = reg.Replace(argStr, "GReeeeN")
  
  'gre(2,3)nをgreen
  reg.Pattern = "(gre{2,3}n)"
  fncGreen = reg.Replace(fncGreen, "green")
End Function

正規表現については以下を参照してください。
VBAで正規表現を利用する(RegExp)
正規表現は複雑なパターンマッチングとテキストの検索置換するためのツールです、マクロVBAで正規表現を使う場合はRegExpオブジェクトを使用します、RegExpは、VBScriptに正規表現として用意されているオブジェクトです。目次 メタ文字 正規表現 正規表現RegExpの使い方 RegExpオブジェクト Reg…

ループして文字列を見つけて置換する

Sub sample()
  Debug.Print fncGreen("Greeenはgreenに、greeeeeNやGReeeeeenはGReeeeNに直す")
  Debug.Print fncGreen("grEEn、GreeeN、grEEEEn、greeeeeN、GReeeeeen、GREEEEEEEN")
End Sub

Function fncGreen(ByVal argStr As String) As String
  fncGreen = argStr
  Dim pos As Long
  Do
    pos = InStr(1, fncGreen, String(5, "e"), vbTextCompare)
    If pos >= 3 Then
      If LCase(Mid(fncGreen, pos - 2, 2)) = "gr" Then
        fncGreen = Replace(fncGreen, "gr" & getGreen(fncGreen, pos), "GReeeeN", 1, -1, vbTextCompare)
      End If
    End If
  Loop While pos <> 0
  
  fncGreen = Replace(fncGreen, "greeeen", "GReeeeN", 1, -1, vbTextCompare)
  fncGreen = Replace(fncGreen, "greeen", "green", 1, -1, vbTextCompare)
  fncGreen = Replace(fncGreen, "green", "green", 1, -1, vbTextCompare)
End Function

Function getGreen(ByVal argStr As String, argPos As Long) As String
  Dim i As Long
  For i = argPos To Len(argStr)
    Select Case LCase(Mid(argStr, i, 1))
      Case "e"
      Case "n"
        getGreen = Mid(argStr, argPos, i - argPos + 1)
        Exit Function
      Case Else
        getGreen = ""
        Exit Function
    End Select
  Next
  getGreen = "" 'これは"e"で終わった場合
End Function


文字列長-3の"e"を最大として置換しまくる

Sub sample()
  Debug.Print fncGreen("greeenはgreenに、greeeeeNやGReeeeeenはGReeeeNに直す")
  Debug.Print fncGreen("grEEn、GreeeN、grEEEEn、greeeeeN、GReeeeeen、GREEEEEEEN")
End Sub

Function fncGreen(ByVal argStr As String) As String
  fncGreen = argStr
  Dim i As Long, repStr As String
  For i = Len(argStr) - 3 To 2 Step -1
    If i <= 3 Then
      repStr = "green"
    Else
      repStr = "GReeeeN"
    End If
    fncGreen = Replace(fncGreen, "gr" & String(i, "e") & "n", repStr, 1, -1, vbTextCompare)
  Next
End Function




同じテーマ「ツイッター出題回答 」の記事

言語依存の関数を使用できるFormulaLocal

ツイッターでVBAのお題として出したものです。複数セルに一括で数式を入れるバ宇井の記述と、言語環境に依存する関数をセルに設定する場合のFormulaプロパティの使い方についての問題です。問題を出したツイート A1:A10セルに半角の英数文字が入っているので、これを全角で表示するためにB1:B10セルに数式をVBAで…
配列のUBoundがLBoundがより小さいことはあり得るか
ツイッターでVBAのお題として出したものです。配列の下限が上限より大きくなるような配列は存在するかの問題です。LBound(ary)>UBound(ary) この条件を満たすような配列は存在するか? 問題を出したツイート 配列の下限と上限を調べるにはLBound関数とUBound関数を使います。
コレクションの要素を削除する場合
ツイッターで出したVBAのお題(投票)です。Collectionから要素を順に削除するVBAの正誤問題です。問題を出したツイート 【VBA問題】 DimcAsNewCollection Dimi Fori=1To100 c.Addi,CStr(i) Next Fori=1To100 c.Remove□ Next 四…
greeenはgreenに、greeeeeNをGReeeeNに変換
数値変数の値を別の変数を使わずに入れ替える
ツイッターで出したエクセルVBAのお題です。数値が入っている3つの変数を、他の変数を使わずに値を入れ替えるという問題です。問題を出したツイート 【VBA問題】 変数a,b,cに整数値が入っています。これをa>b>cとなるように値を入れ替えてください。
Rangeオブジェクトを受け取り"行数,列数"で埋める
ツイッターで出したエクセルVBAのお題です。Rangeオブジェクトを受け取り、"行数,列数"の値(数式ではなく値)で埋めるVBAを書く問題です。問題を出したツイート 【VBAお題】 Rangeオブジェクトを受け取り、添付のように"行数,列数"の値(数式ではなく値)で埋めてくだ…
数式の関数の使用回数、関数名を配列で返す
ツイッターで出したエクセルVBAのお題です。セルに入っている計算式に使われている関数(ユーザー定義含む)を数えてみましょう、というお題になります。問題を出したツイート 【VBAお題】セルに計算式が入っています。
日付型と通貨型のValueとValue2について
ツイッターでVBAに関する問題を出しました。問題としてはValueとValue2について問うもので、日付型と通貨型が問題の焦点になります。https://twitter.com/yamaoka_ss/status/1408259798357794817 VBA問題の出題ツイート 【VBA問題】 Rangeに対して、
小文字"abc"を大文字"ABC"に変換する方法
ツイッターで出した「VBA問題」です。小文字"abc"を大文字"ABC"に変換する方法を可能な限り列挙してください。という問題です。。出題ツイート https://twitter.com/yamaoka_ss/status/1425799283303882758 「VBA問題…
オブジェクトのByRef、ByVal、Variant
ツイッターで出題した問題です。オブジェクトを引数にした場合の、ByRef、ByValの違いと、仮引数にVariantを指定した場合の動作違いを問う問題です。出題ツイート 【VBA問題】 Submain() Range("A1")=1 DimaAsRange:Seta=Range("A1…
「マクロの登録」で登録できないプロシージャーは?
ツイッターで出題した問題です。マクロはボタン等に「マクロの登録」で登録して使う場合が多いです。どのようなプロシージャーかによって「マクロの登録」での登録方法を違ってきます。このやり方を知っているかどうかを問うVBA問題です。


新着記事NEW ・・・新着記事一覧を見る

エクセルが起動しない、Excelが立ち上がらない|エクセル雑感(2024-04-11)
ブール型(Boolean)のis変数・フラグについて|VBA技術解説(2024-04-05)
テキストの内容によって図形を削除する|VBA技術解説(2024-04-02)
ExcelマクロVBA入門目次|エクセルの神髄(2024-03-20)
VBA10大躓きポイント(初心者が躓きやすいポイント)|VBA技術解説(2024-03-05)
テンキーのスクリーンキーボード作成|ユーザーフォーム入門(2024-02-26)
無効な前方参照か、コンパイルされていない種類への参照です。|エクセル雑感(2024-02-17)
初級脱出10問パック|VBA練習問題(2024-01-24)
累計を求める数式あれこれ|エクセル関数応用(2024-01-22)
複数の文字列を検索して置換するSUBSTITUTE|エクセル入門(2024-01-03)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
3.変数宣言のDimとデータ型|VBA入門
4.繰り返し処理(For Next)|VBA入門
5.RangeとCellsの使い方|VBA入門
6.ブックを閉じる・保存(Close,Save,SaveAs)|VBA入門
7.並べ替え(Sort)|VBA入門
8.メッセージボックス(MsgBox関数)|VBA入門
9.セルのクリア(Clear,ClearContents)|VBA入門
10.ひらがな⇔カタカナの変換|エクセル基本操作




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。


このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
本文下部へ