レジストリの操作（SaveSetting,GetSetting,GetAllSettings,DeleteSetting）

最終更新日：2018-03-12

第129回.レジストリの操作（SaveSetting,GetSetting,GetAllSettings,DeleteSetting）

VBAでレジストリを操作することの是非はありますが、

VBAには、レジストリ操作のテートメントと関数が用意されています。

MOSのVBAスタンダートの出題範囲を見るとレジストリ操作が入っており、

ここまでの「マクロVBA入門」で漏れている項目として今回取り上げます。

レジストリを保存するには、SaveSettingステートメントを使います。
レジストリからキー設定値を取得するには、GetSetting関数を使います。
レジストリから全ての設定値を取得するには、GetAllSettings関数を使います。
レジストリからキー設定を削除するには、DeleteSettingステートメントを使います。

SaveSettingステートメント

レジストリにアプリケーションの項目を保存または作成します。

SaveSetting appname, section, key, setting

SaveSetting ステートメントの構文は、次の名前付き引数から構成されます。

指定項目	内容
appname	必ず指定します。設定を適用するアプリケーション名またはプロジェクト名を含む文字列式を指定します。 Macintosh の場合には、システムフォルダ内の初期設定フォルダに含まれているファイル名を指定します。
section	必ず指定します。キー設定を保存するセクション名を含む文字列式を指定します。
key	必ず指定します。保存するキー名を含む文字列式を指定します。
setting	必ず指定します。名前付き引数 key に設定する値を含む式を指定します。

キー設定が保存できない場合、エラーが発生します。

レジストリに保存される位置は、

HKEY_CURRENT_USER
→Software
　→VB and VBA Program Settings

この下に、以下のように保存されます

VBA マクロ参考画像

DeleteSettingステートメント

レジストリにあるセクションまたはキー設定を削除します。

DeleteSetting appname, section[, key]

DeleteSetting ステートメントの構文は、次の名前付き引数から構成されます。

指定項目	内容
appname	必ず指定します。セクションか、キー設定を適用するアプリケーション名またはプロジェクトの名前を含む文字列式を指定します。 Macintosh の場合には、システムフォルダ内の初期設定フォルダに含まれているファイル名を指定します。
section	必ず指定します。キー設定を削除するセクション名を含む文字列式を指定します。名前付き引数 appname および名前付き引数 section だけを指定した場合、指定されたセクションは関連付けられたすべてのキー設定と共に削除されます。
key	省略可能です。削除するキー名を含む文字列式を指定します。

引数をすべて指定した場合、指定したキー設定が削除されます。

ただし、

指定したセクションまたはキー設定が存在しない場合に DeleteSetting ステートメントを使用すると、実行時エラーが発生します。

GetSetting関数

レジストリにあるキー設定値を取得し返します。

GetSetting(appname, section, key[, default])

GetSetting 関数の構文は、次の名前付き引数から構成されます。

指定項目	内容
appname	必ず指定します。設定を適用するアプリケーション名またはプロジェクト名を含む文字列式を指定します。 Macintosh の場合には、システムフォルダ内の初期設定フォルダに含まれているファイル名を指定します。
section	必ず指定します。キー設定を保存するセクション名を含む文字列式を指定します。
key	必ず指定します。保存するキー名を含む文字列式を指定します。
default	省略可能です。キー設定に値が設定されていない場合に返す値を含む式を指定します。省略すると、長さ 0 の文字列 ("") とみなされます。

GetSetting 関数の名前付き引数のいずれかを指定していない場合、
GetSetting 関数では、名前付き引数 default の値が返されます。

GetAllSettings関数

レジストリにあるSaveSettingステートメントを使って作成された項目内のすべてのキー設定および各キー設定に対応する値のリストを返します。

GetAllSettings(appname, section)

GetAllSettings 関数の構文は、次の名前付き引数から構成されます。

指定項目	内容
appname	必ず指定します。キー設定を取得するアプリケーション名またはプロジェクト名を含む文字列式を指定します。Macintosh の場合には、システムフォルダ内の初期設定フォルダに含まれているファイル名を指定します。
section	必ず指定します。キー設定を取得するセクション名を含む文字列式を指定します。GetAllSettings 関数では、指定したセクションのすべてのキー設定およびそのキー設定に対応する値を含む文字列の二次元配列を格納したバリアント型 (Variant) の値が返されます。

名前付き引数 appname または名前付き引数 section のいずれかを指定していない場合、
GetAllSettings 関数は初期化されていないバリアント型 (Variant) の値を返します。

使用例

'レジストリに保存
SaveSetting appname:="MyApp", _
　　　　　　section:="Test", _
　　　　　　Key:="Test1", _
　　　　　　setting:="Excelの神髄1"
SaveSetting "MyApp", _
　　　　　　"Test", _
　　　　　　"Test2", _
　　　　　　"Excelの神髄2"

'レジストリから取得
MsgBox GetSetting(appname:="MyApp", _
　　　　　　　　　section:="Test", _
　　　　　　　　　Key:="Test1", _
　　　　　　　　　Default:="未登録")
MsgBox GetSetting("MyApp", _
　　　　　　　　　"Test", _
　　　　　　　　　"Test2", _
　　　　　　　　　"未登録")

'レジストリから全てを取得します。
Dim MySettings As Variant
Dim intSettings As Integer
MySettings = GetAllSettings(appname:="MyApp", _
　　　　　　　　　　　　　　section:="Test")
For intSettings = LBound(MySettings, 1) To UBound(MySettings, 1)
　　MsgBox MySettings(intSettings, 0) & ":" & _
　　　　　　　MySettings(intSettings, 1)
Next

'レジストリから削除
DeleteSetting appname:="MyApp", _
　　　　　　　section:="Test"

以下の順にメッセージボックスに表示されます。

Excelの神髄1
Excelの神髄2
Test1:Excelの神髄1
Test2:Excelの神髄2

各種アプリケーションを開発してきたものとしては、
アプリケーションでレジストリを使う場合は、アプリケーションのアンインストールを用意すべきだと思っています。

ExcelのVBAでレジストリを扱うのであれば、アンインストールも用意すべきだと考えます。
しかしVBAで、これを用意しているいないのであれば、レジストリは使うべきではないと思います。