ユーザーフォーム入門
数値専用のテキストボックス

Excelマクロのユーザーフォームの基礎、エクセルVBAの入門解説
最終更新日:2019-12-17

第19回.数値専用のテキストボックス


ユーザーフォーム入門として基礎から解説します。
数値専用のテキストボックスの作成です。
数字以外は入力出来ないテキストボックスを作成します。


数値専用のテキストボックスの追加

以下のように金額のテキストボックスを追加します。

VBA マクロ ユーザーフォーム 数値テキスト

オブジェクト名は、txt金額とします。

KeyDownイベントで数値のみに限定



Private Sub txt金額_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
  Select Case KeyCode
    Case vbKeyReturn, vbKeyBack, vbKeyDelete, vbKeyTab
    Case vbKey0, vbKey1, vbKey2, vbKey3, vbKey4, vbKey5, vbKey6, vbKey7, vbKey8, vbKey9
    Case vbKeyNumpad0, vbKeyNumpad1, vbKeyNumpad2, vbKeyNumpad3, vbKeyNumpad4, vbKeyNumpad5, vbKeyNumpad6, vbKeyNumpad7, vbKeyNumpad8, vbKeyNumpad9
    Case vbKeyLeft, vbKeyUp, vbKeyRight, vbKeyDown
    Case 188 '「,」カンマ
    Case Else
      KeyCode = 0
  End Select
End Sub

数字のみ入力可能なテキストボックスになります。
数字以外では、EnterキーやBackSpaceキー、そしてカンマ等々を入力できるようにしておきます。

数字キーは、
vbKey0~vbKey9と、vbKeyNumpad0~vbKeyNumpad9
この両方を入れるのを忘れないようにして下さい。
vbKeyNumpadは、テンキーからの入力になります。

数値専用テキストボックスをカンマ編集

数値を読みやすいようらカンマ編集します。

まずは、テキストボックスに入った時点では、カンマを削除した状態にして、
テキストボックスを抜けた時にカンマ編集してみましょう。

Private Sub txt金額_Enter()
  Call setColor(Me.txt金額)
  If IsNumeric(Me.txt金額.Text) Then
    Me.txt金額.Text = Format(Me.txt金額.Text, "0")
  End If
End Sub

Private Sub txt金額_Exit(ByVal Cancel As MSForms.ReturnBoolean)
  If Me.txt金額.Text = "" Then
    Exit Sub
  End If
  If IsNumeric(Me.txt金額.Text) Then
    Me.txt金額.Text = Format(Me.txt金額.Text, "#,##0")
  Else
    MsgBox "数値を入力して下さい。"
    Cancel = True
  End If
End Sub

Exitイベントでは、数値以外の場合は、抜けないようにしています。
Cancel = True
これで、テキストボックスを抜けないようにしています。

If Me.txt金額.Text = "" Then
  Exit Sub
End If
これが無いと、何も入力していない状態でもテキストボックスを出られなくなってしまいます。
入力必須項目であっても、ここは一旦は、未入力を許可しておい方が使い勝手が良いでしょう。
必須入力のチェックは、OKボタンが押された時点でチェックするようにしたほうが良いです。

Changeイベントで電卓風に

別の方法で、数字を入力している途中で、カンマを自動挿入してみましょう。
電卓の数値入力のような感じになります。



Private Sub txt金額_Change()
  If IsNumeric(Me.txt金額.Text) Then
    Me.txt金額.Text = Format(Me.txt金額.Text, "#,##0")
  End If
End Sub

これで、数値を入力していくと、3桁ごとに自動でカンマが付くようになります。
ここは、好みで使い分ければ良いと思います。
イベントの使い方によって、いろいろな表現方法ができますので、工夫していろいろ試してみてください。



同じテーマ「ユーザーフォーム入門」の記事

第16回.アクティブコントロールに色を付ける
第17回.Enterキーで次のコントロールに移動する
第18回.2段階のコンボボックス
第19回.数値専用のテキストボックス
第20回.テキストボックスの各種イベント
第21回.ユーザーフォームの各種イベント
第22回.コントロールの動的作成
第23回.イベントプロシージャーの共通化
第24回.イベントプロシージャーの共通化(Enter,Exit)
第25回.簡易音楽プレーヤーの作成
第26回.プログレスバーを自作する


新着記事NEW ・・・新着記事一覧を見る

数字(1~50)を丸付き数字に変換するVBA|VBA技術解説(2022-11-15)
TEXTAFTER関数(テキストの指定文字列より後ろの部分を返す)|エクセル入門(2022-11-14)
TEXTBEFORE関数(テキストの指定文字列より前の部分を返す)|エクセル入門(2022-11-14)
TEXTSPLIT関数(列と行の区切り記号で文字列を分割)|エクセル入門(2022-11-12)
LAMBDA以降の新関数はVBAで使えるか|VBA技術解説(2022-11-11)
WRAPCOLS関数(1次元配列を指定数の列で折り返す)|エクセル入門(2022-11-08)
WRAPROWS関数(1次元配列を指定数の行で折り返す)|エクセル入門(2022-11-08)
EXPAND関数(配列を指定された行と列に拡張する)|エクセル入門(2022-11-07)
TAKE関数(配列の先頭/末尾から指定行/列数を取得)|エクセル入門(2022-11-06)
DROP関数(配列の先頭/末尾から指定行/列数を除外)|エクセル入門(2022-11-06)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.RangeとCellsの使い方|VBA入門
3.変数宣言のDimとデータ型|VBA入門
4.繰り返し処理(For Next)|VBA入門
5.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
6.Excelショートカットキー一覧|Excelリファレンス
7.並べ替え(Sort)|VBA入門
8.エクセルVBAでのシート指定方法|VBA技術解説
9.マクロって何?VBAって何?|VBA入門
10.ExcelマクロVBAの基礎を学習する方法|エクセルの神髄




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。



このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
本文下部へ