ExcelマクロVBA技術解説
値渡し、参照渡しについて(ByVal,ByRef)

ExcelマクロVBAの問題点と解決策、エクセルVBAの技術的解説
最終更新日:2013-05-30

値渡し、参照渡しについて(ByVal,ByRef)


ByValが値渡し、ByRefが参照渡しです。


ここまでは、どこにでも書いてありますし、なんとなく理解していても、

実際の活用がなかなか出来ない事が多いようです。

使用例を通じて、理解して下さい。



Sub sample1()
  Dim i, j
  i = 1
  j = 1
  Call sub1(i, j)
  MsgBox i
  MsgBox j
End Sub
Sub sub1(arg1, arg2)
  arg1 = arg1 + 1
  arg2 = arg2 + 2
End Sub


上記のsample1を実行すると、2,3の順にメッセージ表示されます。


ByValもByRef指定していないので、ByRefとなっています。

この場合、参照渡しとなり、Call元のプロシージャーの引数も変更されます。

Sub sample2()
  Dim i, j
  i = 1
  j = 1
  Call sub2(i, j)
  MsgBox i
  MsgBox j
End Sub
Sub sub2(ByVal arg1, ByVal arg2)
  arg1 = arg1 + 1
  arg2 = arg2 + 2
End Sub


上記のsample2を実行すると、1,1の順にメッセージ表示されます。


ByValを指定しているので、値渡しとなっています。

この場合、Call元のプロシージャーの引数は変更されません。

ここまでは良いでしょうか、


引数にオブジェクトを指定した場合に、勘違いしている場合が多いです。



Sub sample()
  Dim MyRange As Range
  Set MyRange = Range("A1")
  Call sample2(MyRange)
End Sub
Sub sample2(ByVal MyRange As Range)
  MyRange.Value = 1
End Sub

上記の結果は、A1セルに1が入ります。


当然ですよね。

つまり、ByValで渡されたオブジェクトに変更を加えれば、

呼出元でもオブジェクトは変更されています。

Range以外の他のオブジェクトでも同じことです。

では、オブジェクトの場合、ByValとByRefの違いは何かですが、

Sub sample()
  Dim MyRange As Range
  Set MyRange = Range("A1")
  Call sample2(MyRange)
  MyRange.Value = 2
End Sub
Sub sample2(ByVal MyRange As Range)
  MyRange.Value = 1
  Set MyRange = Range("A2")
End Sub

まずは、ByValの場合です。


上記の結果は、A1セルに2が入るだけです。

sample2での
Set MyRange = Range("A2")
これは、呼出元に影響を与えないので、ここでは無意味です。

Sub sample()
  Dim MyRange As Range
  Set MyRange = Range("A1")
  Call sample2(MyRange)
  MyRange.Value = 2
End Sub
Sub sample2(ByRef MyRange As Range)
  MyRange.Value = 1
  Set MyRange = Range("A2")
End Sub


今度は、ByRefの場合です。


この結果は、A1セルに1、A2セルに2が入ります。

sample2での
Set MyRange = Range("A2")
この変更が、呼出元に返されています。


ここでは、とても単純な例にしましたが、


オブジェクトを引数に使う場合の参考にして下さい。



同じテーマ「マクロVBA技術解説」の記事

WorksheetFunctionについて
RangeとCellsの深遠
Offset、Resizeを使いこなそう
値渡し、参照渡しについて(ByVal,ByRef)
最終行・最終列の取得方法(End,CurrentRegion,SpecialCells,UsedRange)
ユーザー定義関数の作り方
セルの値について(Value,Value2,Text)
Excelのバージョンを判断して「名前を付けて保存」
空白セルを正しく判定する方法(IsEmpty,IsError,HasFormula)
空白セルを正しく判定する方法2
Rangeオブジェクト.Valueの省略について


新着記事NEW ・・・新着記事一覧を見る

VBAにおける変数のメモリアドレスについて|VBA技術解説(11月8日)
空文字列の扱い方と処理速度について(""とvbNullString)|VBA技術解説(1月7日)
Errオブジェクトとユーザー定義エラー|VBA入門(11月5日)
シングルクォートの削除とコピー(PrefixCharacter)|VBA技術解説(11月4日)
ユーザー定義型の制限とクラスとの使い分け|VBA技術解説(11月3日)
クリップボードに2次元配列を作成してシートに貼り付ける|VBA技術解説(11月1日)
VBAクラスを使ったイベント作成(Event,RaiseEvent,WithEvents)|VBA技術解説(10月31日)
VBAクラスのAttributeについて(既定メンバーとFor Each)|VBA技術解説(10月19日)
VBAの用語について:ステートメントとは|VBA技術解説(10月16日)
VBAのマルチステートメント(複数のステートメントを同じ行に)|VBA技術解説(10月14日)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
3.RangeとCellsの使い方|ExcelマクロVBA入門
4.Range以外の指定方法(Cells,Rows,Columns)|VBA入門
5.変数宣言のDimとデータ型|ExcelマクロVBA入門
6.繰り返し処理(For Next)|ExcelマクロVBA入門
7.マクロって何?VBAって何?|ExcelマクロVBA入門
8.ひらがな⇔カタカナの変換|エクセル基本操作
9.空白セルを正しく判定する方法(IsEmpty,IsError,HasFormula)|VBA技術解説
10.セルに文字を入れるとは(Range,Value)|VBA入門



  • >
  • >
  • >
  • 値渡し、参照渡しについて(ByVal,ByRef)

  • このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


    記述には細心の注意をしたつもりですが、
    間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
    なお、掲載のVBAコードは自己責任で使ってください。万一データ破損等の損害が発生しても責任は負いません。




    このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
    本文下部へ