VBA技術解説
最終行・最終列の取得方法（End,CurrentRegion,SpecialCells,UsedRange）

手操作で、A列の最終行に移動する場合は、
A1セルが選択されている状態で、
Ctrl + ↓
これで、A11に移動できます。
これをマクロで書くと、
Cells(1, 1).End(xlDown)
になります。
しかし、途中に空欄のセルがある場合、

この場合は、Ctrl + ↓ではA6セルになってしまいます。
このような場合は、シートの最終行（シートの一番下）のセルに移動してから、
Ctrl + ↑
とやれば、A11に移動できます。
これをマクロVBAで書くと、
Cells(Rows.Count, 1).End(xlUp)
になります。
Rows.Count
は、シートの行数になります。
2007以降なら1048576です、2003なら65536です。
つまり、シートのA列の最終行から、上に向かって、Ctrl+↑で移動している訳です。
このEndは、Rangeオブジェクトのプロパティです。
End(Direction)
Directionは、
xlDown : 下へ
xlToLeft : 左へ
xlToRight : 右へ
xlUp : 上へ

ただし、
Cells(1, 1).End(xlDown)
や
Cells(Rows.Count, 1).End(xlUp)

これは、最期のセルを表しています、つまり最期のセルのRangeオブジェクトになります。
その行数（行位置）を取得するには、
Cells(1, 1).End(xlDown).Row
や
Cells(Rows.Count, 1).End(xlUp).Row
このように、.Rowを指定します。
これで、データの最後の行数を取得できます。
この、.Rowは、Rangeオブジェクトのプロパティで、その行位置を返します。
上記例なら、11が返されます。
返されるとは、つまりは、
Cells(1, 1).End(xlDown).Rowは11と同じだと言う事です。
とにかく、最終行を取得する場合は、
Cells(1, 1).End(xlDown).Row
または
Cells(Rows.Count, 1).End(xlUp).Row
これは、定型文として丸暗記して下さい。
通常は、
Cells(Rows.Count, 1).End(xlUp).Row
これを使用します。
※注意点

最終行取得と同様の考えで、最終列の取得も行います。
A1セルから、Ctrl + →
や
シートの最終列（シートの一番右）のセルから、Ctrl + ←
マクロVBAコードで書くと
Cells(1, 1).End(xlToRight).Column
または
Cells(1, Columns.Count).End(xlToLeft).Column
最終行取得と合わせて、良く使われていますので覚えておいてください。

上記のような手法が使えないような表の場合があります。
以下の表で説明します。

最終列は見出し行の２行目で判断すれば良いでしょう。
Cells(2, Columns.Count).End(xlToLeft).Column
しかし、最終行の取得方法が、今までの方法ではうまく行きません。
マクロVBAで処理するなら、
10行目までか、12行目までになるでしょう。
しかし、
Cells(Rows.Count, 2).End(xlUp).Row
これでは、9になってしまいます。
Cells(Rows.Count, 3).End(xlUp).Row
これなら、10になりますが、
そもそも何列目に最終行のデータが入っているかが不明です。
このような場合に、使用するのは、
・CurrentRegion
・SpecialCells(xlCellTypeLastCell)
・UsedRange
・Findメソッド
これらを使用します。

CurrentRegionプロパティを使用して最終行を取得する場合です。
Range("B2").CurrentRegion.Item(Range("B2").CurrentRegion.Count).Row
または、
Range("B2").CurrentRegion.Row + Range("B2").CurrentRegion.Rows.Count - 1
これでは見ずらいので、Withでまとめると
With Range("B2").CurrentRegion
　　最終行 = .Item(.Count).Row
End With
または、
With Range("B2").CurrentRegion
　　最終行 = .Row + .Rows.Count - 1
End With
CurrentRegionは、アクティブセル領域を返します。
最初のコードは、アクティブセル領域の最後のセルの行位置を取得しています。
次のコードは、アクティブセル領域の開始行位置とアクティブセル領域の行数を足しています。
ただし、CurrentRegionなので、途中に空白行（何も入っていない行）がある場合は、
そこまでの行になってしまいます。

SpecialCellsプロパティを使用して最終行を取得する場合です。
Cells.SpecialCells(xlCellTypeLastCell).Row
SpecialCells(xlCellTypeLastCell)は、シートの最終セルを返します。
つまり、シートの使っているセルの最終位置を取得しています。
上の表なら、12となります。
（表範囲以外には何のデータもはいっていないとしてです。）
※SpecialCellsプロパティの範囲について

UsedRangeプロパティを使用して最終行を取得する場合です。
ActiveSheet.UsedRange.Item(ActiveSheet.UsedRange.Count).Row
または
ActiveSheet.UsedRange.row + ActiveSheet.UsedRange.Rows.count - 1
これでは見ずらいので、Withでまとめると
With ActiveSheet.UsedRange
　　最終行 = .Item(.Count).Row
End With
または、
With ActiveSheet.UsedRange
　　最終行 = .Row + .Rows.Count - 1
End With
UsedRangeは、指定されたワークシートで使われたセル範囲を返します。
使われたセル範囲の開始行位置と使われたセル範囲の行数を足しています。
UsedRangeは、シートの指定が必須となります。
ただし、
以下の注意点を良く確認してください、使うには少々注意が必要です。
※UsedRangeプロパティの範囲について
※注意してください

RangeオブジェクトのFindメソッドを使います。

最終行 = ActiveSheet.Cells.Find("*", , xlFormulas, , xlByRows, xlPrevious).Row
名前付き引数を使って書くと、
最終行 = Cells.Find(What:="*", LookIn:=xlFormulas, SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
とにかく最後の文字・数値・数式等が入っているセルを見つけようという事です。
あらゆる文字("*")を下から上へ(xlPrevious)へ探しています。
行方向なので(xlByRows)、列なら(xlByColumns)になります。
CellsはUsedRangeでも良いです。
非表示行も対象となりますので汎用性はあります。
ただし、複数の表（別々の連続セル範囲）があるシートでは、表を指定することはできません。
このような場合はCurrentRegionを使ってください。
また、Findメソッドは指定オプションがシート操作とリンクしている点については注意してください。

第18回.最終行の取得（End,Rows.Count）

第6回.表の先頭から最終行まで繰り返す（ForとEnd(xlUp).Row）

Rangeの使い方：最終行まで選択を例に

最終行の判定、Rangeオブジェクトと配列、高速化の為に

同じテーマの記事
新着記事
アクセスランク