VBA技術解説
特殊フォルダの取得(WScript.Shell,SpecialFolders)

ExcelマクロVBAの問題点と解決策、VBAの技術的解説
最終更新日:2019-11-13

特殊フォルダの取得(WScript.Shell,SpecialFolders)

デスクトップのフォルダ、スタートメニューのフォルダ、個人用ドキュメントのフォルダなど、
Windows の特殊フォルダを取得するには、
ネイティブのWindowsシェルへのアクセスを提供するWScript.ShellのSpecialFoldersプロパティを使用します。


CreateObject関数で作成したWscript.ShellのSpecialFoldersプロパティで、
特殊フォルダを示す文字列を引数に指定して特殊フォルダを取得します。

WScript.Shell

WScript.Shellを使うには、
CreateObject関数(ActiveXオブジェクトへの参照を作成して返す)を使います。
CreateObject関数は、ActiveXオブジェクトへの参照を作成して返します。CreateObject関数を使う事で、参照設定することなくActiveXオブジェクトを使用できるようになります。CreateObject関数の構文 CreateObject(class,[servername]) class 必ず指定します。

Dim wsh As Object
Set wsh = CreateObject("Wscript.Shell")
または、
「Windows Script Host Object Model」を参照設定して、
Dim wsh As New WshShell

WScript.Shellのプロパティ一覧



プロパティ 説明
CurrentDirectory プロパティ 現在アクティブになっているディレクトリを取得または変更します。
Environment プロパティ WshEnvironment オブジェクト (環境変数のコレクション) を返します。
SpecialFolders プロパティ SpecialFolders オブジェクト (特殊フォルダのコレクション) を返します。

WScript.Shellのメソッド一覧

メソッド 説明
AppActivate メソッド アプリケーション ウィンドウをアクティブにします。
CreateShortcut メソッド ショートカットまたは URL ショートカットへのオブジェクト参照を作成します。
ExpandEnvironmentStrings メソッド 環境変数を展開した値を返します。
LogEvent メソッド イベント エントリをログ ファイルに追加します。
Popup メソッド ポップアップ メッセージ ボックスにテキストを表示します。
RegDelete メソッド レジストリから指定されたキーまたは値を削除します。
RegRead メソッド レジストリ内のキー名または値名の値を返します。
RegWrite メソッド 新しいキーの作成、新しい値名の既存キーへの追加 (および値の設定)、既存の値名の値変更などを行います。
Run メソッド 新しいプロセス内でプログラムを実行します。
SendKeys メソッド キーボードから入力したときのように、1 つ以上のキー ストロークをアクティブなウィンドウに送ります。

※各プロパティ・メソッドの詳細について
VBAで通常使われるのは、SpecialFoldersプロパティくらいでしょう。
以下では、SpecialFolders プロパティ の解説をしています。

他のプロパティ・メソッドの詳細については、MSDNの、
WshShell オブジェクトのプロパティとメソッド
こちらを参照してください。

SpecialFolders プロパティ

SpecialFoldersはWshSpecialFoldersオブジェクトのコレクションです。
このオブジェクトには、
デスクトップのフォルダ、[スタート] メニューのフォルダ、個人用ドキュメントのフォルダなど、
Windowsの特殊フォルダ セット全体が格納されます。

目的の特殊フォルダを取得するには、列挙値またはフォルダ文字列をコレクション内のインデックスとして使用します。
要求したフォルダを使用できない場合は、NULL が返されます。



列挙値 フォルダ文字列 説明 一般的Windows10の具体的なフォルダ
0 AllUsersDesktop すべてのユーザーに共通のデスクトップ C:\Users\Public\Desktop
1 AllUsersStartMenu すべてのユーザーに共通のプログラムメニュー C:\ProgramData\Microsoft\Windows\Start Menu
2 AllUsersPrograms すべてのユーザーに共通の全てのプログラム C:\ProgramData\Microsoft\Windows\Start Menu\Programs
3 AllUsersStartup すべてのユーザーに共通のスタートアップ C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp
4 Desktop デスクトップ C:\Users\[username]\Desktop
5 AppData ログインユーザーのアプリ用データ C:\Users\[username]\AppData\Roaming
6 PrintHood プリンタフォルダ C:\Users\[username]\AppData\Roaming\Microsoft\Windows\Printer Shortcuts
7 Templates 新規作成のテンプレート C:\Users\[username]\AppData\Roaming\Microsoft\Windows\Templates
8 Fonts インストールされているフォント C:\Windows\Fonts
9 NetHood ネットワークに表示される共有フォルダの情報 C:\Users\[username]\AppData\Roaming\Microsoft\Windows\Network Shortcuts
10 Desktop デスクトップ C:\Users\[username]\Desktop
11 StartMenu スタートメニュー C:\Users\[username]\AppData\Roaming\Microsoft\Windows\Start Menu
12 SendTo 送るメニュー C:\Users\[username]\AppData\Roaming\Microsoft\Windows\SendTo
13 Recent 最近使ったファイル C:\Users\[username]\AppData\Roaming\Microsoft\Windows\Recent
14 Startup ログインユーザーのスタートアップ C:\Users\[username]\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup
15 Favorites お気に入り C:\Users\[username]\Favorites
16 MyDocuments マイドキュメント C:\Users\[username]\Documents
17 Programs ログインユーザーのプログラムメニュー C:\Users\[username]\AppData\Roaming\Microsoft\Windows\Start Menu\Programs

WshShellのSpecialFoldersのマクロVBA使用例

まずデスクトップのフォルダを取得する場合です。

Sub デスクトップの取得()
  Dim wsh As Variant
  Set wsh = CreateObject("Wscript.Shell")
  MsgBox wsh.SpecialFolders("Desktop")
  'MsgBox wsh.SpecialFolders(4)
  Set wsh = Nothing
End Sub

"Desktop"と4のどちらで指定しても同じ結果を取得できます。
4の指定において"4"と指定してしまうと取得できません。

以下では、少し汎用的なFunctionプロシージャーを作成して、
・すべてのユーザーに共通のデスクトップ
・送るメニュー
・マイドキュメント
これらを取得して、イミィディエイト ウインドウに表示しています。

Sub sample()
  Debug.Print getSpecialFolder("Desktop")
  Debug.Print getSpecialFolder("MyDocuments")
  Debug.Print getSpecialFolder(4)
  Debug.Print getSpecialFolder("16")
End Sub

Function getSpecialFolder(ByVal vFolder As Variant)
  Dim wsh As Object
  Set wsh = CreateObject("Wscript.Shell")
  If IsNumeric(vFolder) Then
    getSpecialFolder = wsh.SpecialFolders(CLng(vFolder))
  Else
    getSpecialFolder = wsh.SpecialFolders(CStr(vFolder))
  End If
  Set wsh = Nothing
End Function

数値列挙でも文字列でも、どちらでも取得できるようにしています。
CStr(vFolder)の部分は、& ""や()で代用することもできます。

上記VBAは記事掲載後に列挙でも指定できるように変更したものです。

変更前の記述
Sub sample()
  Dim sFolder As String
  Debug.Print getSpecialFolder("Desktop")
  Debug.Print getSpecialFolder("MyDocuments")
  Debug.Print getSpecialFolder("SendTo")
End Sub

Function getSpecialFolder(ByVal strFolder As String)
  Dim wsh As Variant
  Set wsh = CreateObject("Wscript.Shell")
  getSpecialFolder = wsh.SpecialFolders(strFolder & "")
  '以下の書き方でも
'  getSpecialFolder = wsh.SpecialFolders((strFolder))
'  getSpecialFolder = wsh.SpecialFolders(CStr(strFolder))
  Set wsh = Nothing
End Function

wsh.SpecialFolders(strFolder & "")
この部分については、引数を直接引き渡して、
wsh.SpecialFolders(strFolder)
このように記述すれば良さそうですが、
これではなぜか正しく取得できません。
理由についての詳細ははっきりしませんが、
MSDNを見ると、
object.SpecialFolders(objWshSpecialFolders)
このように書かれているので、
引数が単なる文字列としては扱われていないのではないかと推測されます。
そこで、
& ""
()
Cstr()
これらを使うことで、文字列として値の評価を行ってから引き渡すことで解決しています。


本来は、VBAでこれらの特殊フォルダは使わないほうが良いのですが、時には使うことで便利な場合もあります。
例えば、マクロの結果出力先として、「デスクトップ」を使うことは時々あります。
出力先をデスクトップにすることで、わかりやすく探さなくて済むという利点は確かにあるようです。




同じテーマ「マクロVBA技術解説」の記事

VBAでのInternetExplorer自動操作
VBAでのSQLの基礎(SQL:Structured Query Language)
VBAで正規表現を利用する(RegExp)
VBAでメール送信する(CDO:Microsoft Collaboration Data Objects)
VBAでのOutlook自動操作
ADO(ActiveX Data Objects)の使い方の要点
特殊フォルダの取得(WScript.Shell,SpecialFolders)
参照設定、CreateObject、オブジェクト式の一覧
VBAのスクレイピングを簡単楽にしてくれるSelenium
VBA+SeleniumBasicで検索順位チェッカー作成
VBA+SeleniumBasicで検索順位チェッカー(改)


新着記事NEW ・・・新着記事一覧を見る

COUNTIF関数の結果は?(ツイッターお題)|エクセル雑感(5月30日)
エクセル&VBA オンライン講座|エクセル セミナー(5月29日)
アルファベットの26進(ツイッターお題)|エクセル雑感(5月19日)
VBAが消えてしまった!マクロが壊れて動かない!|エクセル雑感(5月8日)
時間に関する関数の扱い方(ツイッター投稿)|エクセル雑感(5月6日)
文字列のセルだけ結合(ツイッターのお題)|エクセル雑感(5月5日)
表示形式.言語設定|エクセル入門(5月1日)
GoogleスプレッドシートをExcelにインポートする|VBAサンプル集(4月28日)
ツイッターのお題「CSV編集」|エクセル雑感(4月25日)
プログレスバーを自作する|ユーザーフォーム入門(4月18日)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.RangeとCellsの使い方|VBA入門
3.変数宣言のDimとデータ型|VBA入門
4.マクロって何?VBAって何?|VBA入門
5.Range以外の指定方法(Cells,Rows,Columns)|VBA入門
6.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
7.繰り返し処理(For Next)|VBA入門
8.セルに文字を入れるとは(Range,Value)|VBA入門
9.とにかく書いてみよう(Sub,End Sub)|VBA入門
10.マクロはどこに書くの(VBEの起動)|VBA入門




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。



このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
本文下部へ