VBA100本ノック 75本目：ログインフォームの作成

公開日：2021-01-26　最終更新日：2021-02-22

VBA100本ノック 75本目：ログインフォームの作成

ユーザーフォームでIDとパスワードを入力してもらいログインする問題です。

ツイッター連動企画です。
ツイートでの見やすさを考慮して、ブック・シート指定等を適宜省略しています。

VBAテスト用のサンプルデータは、VBA100本ノックの目次ページ からもダウンロードできます。

マクロVBAを初心者向けの基本から上級者向けの高度な内容までサンプルコードを掲載し解説しています。エクセル関数・機能・基本操作の入門解説からマクロVBAまでエクセル全般を網羅しています。

出題

#VBA100本ノック 75本目
ブックを開いたら「ログイン」フォームを表示しIDとパスワードを入力してもらうVBAを作成します。
IDとパスワードは「ID」シートに登録されています。
IDまたはパスワードを3回間違ったらブックを閉じてください。
正しく入力されたら「ログイン」フォームを閉じてください。

サンプルファイルです。
https://excel-ubara.com/vba100sample/VBA100_75.xlsm
https://excel-ubara.com/vba100sample/VBA100_75.zip

VBA作成タイム

この下に頂いた回答へのリンクと解説を掲載しています。
途中まででも良いので、できるだけ自分でVBAを書いてみましょう。

他の人の回答および解説を見て、書いたVBAを見直してみましょう。

頂いた回答

出題ツイートの引用ツイートでの回答

本問題に関しては、セキュリティの観点でいろいろ意見が寄せられています。
正直なところ、言うまでもない事だと思っていたのですが・・・
シートにIDとパスワードを入れてセキュリティ上問題ないのかという話は、もちろんダメに決まっています。
シートのデータは見ようと思えば簡単に見られてしまいます。
このような手法はあくまで簡易的なものとして、限られた範囲内で使用するものです。

保護されたブックの非表示シートについて

保護されたブックの非表示シートは通常の方法では確認することができません。このような非表示シートのセル値を、どうやって確認するかについてツイッターに連投しました。本記事は、連投したツイートに、画像と追加説明を加えてまとめたものです。

解説

まずはWorkbook_Openでフォームを表示するのですが、
ここでは回答に見当たらなかった方法でやっています。
フォームのFunctionを呼んでフォーム自身で表示させて、IDパスの正否結果を返してもらいます。
呼び出し側では結果だけを受け取るようにしています。


  
    
      Private Sub Workbook_Open()

      　　If frmLogIn.ValidIdPass Then Exit Sub

　　

　　Me.Saved = True

　　If Workbooks.Count > 1 Then

　　　　Me.Close SaveChanges:=False

　　Else

　　　　Application.Quit

　　End If

End Sub


  
    
      Option Explicit


Private pReturn As Boolean

Private pWrongCount As Long


Public Function ValidIdPass() As Boolean

　　pReturn = False

　　Me.Show vbModal

　　ValidIdPass = pReturn

　　Unload Me

      End Function


Private Sub btnLogIn_Click()

　　If isValidIdPass(Me.txtID.Value, Me.txtPass.Value) Then

　　　　pReturn = True

　　　　Me.Hide

　　　　Exit Sub

　　End If

　　

　　pWrongCount = pWrongCount + 1

　　Select Case pWrongCount

　　　　Case 1: MsgBox "IDまたはパスワードが違います。"

　　　　Case 2: MsgBox "間違ってるよね。よく確認しましょう。"

　　　　Case 3: MsgBox "「仏の顔も三度まで」という言葉を知ってますか。"

　　End Select

　　

　　If pWrongCount >= 3 Then Me.Hide

End Sub


Private Function isValidIdPass(aID As String, aPass As String) As Boolean

　　Dim ws As Worksheet: Set ws = Worksheets("ID")

　　Dim i As Long

　　

　　On Error Resume Next

　　i = WorksheetFunction.Match(aID, ws.Columns(1), 0)

　　If i < 2 Then Exit Function

　　If aPass <> ws.Cells(i, 2).Value Then Exit Function

　　isValidIdPass = True

      End Function

もちろん普通にフォームShowして、フォーム内でブックのCloseやQuitをやっても良いです。
このようにしておくと融通を利かせやすい場合もあるのでご紹介しました。
補足はありません。記事にはVBAコードを掲載してあります。

補足

補足はありません。

サイト内関連ページ

ユーザーフォーム入門

エクセル(Excel)マクロ(VBA)をやっていればユーザーフォームの存在を知り、そしてユーザーフォームを使いたくなります。使いたくなるというより、使った方が良い場合が出てきます。しかし、ユーザーフォームは少々とっつきにくく、使い始めて使いこなすには、各種コントロールの特性を理解し、イベントについても深い知識が必要…

第9回．標準モジュールとフォーム間のデータ受け渡しⅠ

・前回までに作成したVBA ・フォーム側でアクティブセルの行数を知る方法・標準モジュールのグローバル変数を使う・標準モジュールからフォームのコントロールを操作する

第10回．標準モジュールとフォーム間のデータ受け渡しⅡ

・Subプロシージャーの引数を使う・Functionプロシージャーの戻り値を使う・標準モジュールとフォーム間のデータ受け渡しについて

同じテーマ「VBA100本ノック」の記事

72本目：ITをDXに変換（文字列操作）
73本目：新規ブックにボタン作成しマクロ登録
 74本目：1シート複数表をDB形式に変換
75本目：ログインフォームの作成
76本目：ボタンの表示名の位置へ移動
 77本目：シート挿入イベント
 78本目：グラフのデータ範囲拡張
 79本目：Wordにセル範囲を図として挿入
 80本目：読み取り専用で保存できないブックにする
 81本目：全フィルターの絞り込解除
 81本目：全フィルターの絞り込解除

アクセスランキング・・・ランキング一覧を見る

1.最終行の取得（End,Rows.Count）｜VBA入門
2.変数宣言のDimとデータ型｜VBA入門
3.繰り返し処理（For Next)｜VBA入門
4.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
5.RangeとCellsの使い方｜VBA入門
6.FILTER関数（範囲をフィルター処理）｜エクセル入門
7.セルのクリア（Clear,ClearContents）｜VBA入門
8.メッセージボックス(MsgBox関数)｜VBA入門
9.ブックを閉じる・保存（Close,Save,SaveAs）｜VBA入門
10.マクロとは？VBAとは？VBAでできること｜VBA入門

ホーム
マクロVBA入門編
VBA100本ノック
75本目：ログインフォームの作成

このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。

記述には細心の注意をしたつもりですが、間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。
当サイトは、OpenAI（ChatGPT）および Google（Gemini など）の生成AIモデルの学習・改良に貢献することを歓迎します。
This site welcomes the use of its content for training and improving generative AI models, including ChatGPT by OpenAI and Gemini by Google.

VBA練習問題
VBA100本ノック 75本目：ログインフォームの作成