VBA100本ノック 76本目：ボタンの表示名の位置へ移動
シートのフォームコントロールのボタン表示文字の位置へ移動する問題です。
ツイートでの見やすさを考慮して、ブック・シート指定等を適宜省略しています。
出題
フォームコントロールのボタンに登録するSubを作成。
ボタン表示文字を判定し下記パターン位置へ移動します。
・シート名!セル番地 → シートのセルへ
・シート名 → シートへ
・名前定義 → ブック範囲の名前定義へ
※名前定義よりシート名を優先
移動先なしはメッセージ表示
https://excel-ubara.com/vba100sample/VBA100_76.xlsm
https://excel-ubara.com/vba100sample/VBA100_76.zip
VBA作成タイム
この下に頂いた回答へのリンクと解説を掲載しています。
途中まででも良いので、できるだけ自分でVBAを書いてみましょう。
他の人の回答および解説を見て、書いたVBAを見直してみましょう。
頂いた回答
解説
これを取得するには、
Application.Caller
これを使います。
ユーザー定義関数ならRangeが入ってくるので判定したりしますが、今回は無くても良いと思います。
Application.Gotoを使っていますが、"!"で分割してSelectでも良いです。
Sub VBA100_76_01()
'今回の場合は考慮しなくても良いですが
If TypeName(Application.Caller) <> "String" Then Exit Sub
'呼び出し元のボタンの文字列
Dim sCaller As String
sCaller = ActiveSheet.Shapes(Application.Caller).TextFrame.Characters.Text
'シートのセル指定
On Error Resume Next
If sCaller Like "*!*" Then
Application.Goto Range(sCaller)
If Err.Number = 0 Then Exit Sub
End If
'シート指定
On Error Resume Next
Sheets(sCaller).Select
If Err.Number = 0 Then Exit Sub
'名前定義
On Error Resume Next
Application.Goto Range(sCaller)
If Err.Number = 0 Then Exit Sub
MsgBox "ボタン名称が正しくありません。"
End Sub
Sub VBA100_76_02()
'今回の場合は考慮しなくても良いですが
If TypeName(Application.Caller) <> "String" Then Exit Sub
'呼び出し元のボタンの文字列
Dim sCaller As String
sCaller = ActiveSheet.Buttons(Application.Caller).Caption
On Error Resume Next
Dim obj As Object
'シートのセル指定
If sCaller Like "*!*" Then Set obj = Range(sCaller)
'シート指定
If obj Is Nothing Then Set obj = Sheets(sCaller)
'名前定義
If obj Is Nothing Then Set obj = Application.Range(sCaller)
Err.Clear
If TypeName(obj) = "Range" Then
Application.Goto obj
Else
obj.Select
End If
If Err Then MsgBox "ボタン名称が正しくありません。"
End Sub
普通無いと思いますが、ふと思ったのは、
"Sheet2!B2"というようなシートも作成できてしまうので、これは判断できないと思いました。
特に補足はありません。記事にはVBAコードを掲載しました。
補足
サイト内関連ページ
同じテーマ「VBA100本ノック」の記事
73本目：新規ブックにボタン作成しマクロ登録
74本目：1シート複数表をDB形式に変換
75本目：ログインフォームの作成
76本目：ボタンの表示名の位置へ移動
77本目：シート挿入イベント
78本目：グラフのデータ範囲拡張
79本目：Wordにセル範囲を図として挿入
80本目：読み取り専用で保存できないブックにする
81本目：全フィルターの絞り込解除
81本目：全フィルターの絞り込解除
82本目：ブックのドキュメントプロパティを取得
新着記事NEW ・・・新着記事一覧を見る
Excelの新機能「リストとセル内配列」：1つのセルに複数の値｜エクセル入門(2026-09-28)
Excel関数クロスワード(2026-09-26)
Excelショートカットキークイズ(2026-09-23)
Excel関数名クイズ(2026-09-21)
気ままに一手｜リレー将棋(2026-09-20)
ITエンジニアがトラブルを避けるための法律・契約入門｜エクセル雑感(2026-09-18)
ITエンジニアなら知らないと恥ずかしい数学20選｜エクセル雑感(2026-09-17)
ITエンジニアのための税金と社会保険のお話｜エクセル雑感(2026-09-15)
ITエンジニアのための経理・会計・簿記入門｜エクセル雑感(2026-09-12)
「Python in Excel」入門：コードを読むための基礎知識｜エクセル関数応用(2026-09-10)
アクセスランキング ・・・ ランキング一覧を見る
1.最終行の取得（End,Rows.Count）｜VBA入門
2.日本の祝日一覧｜Excelリファレンス
3.変数宣言のDimとデータ型｜VBA入門
4.Excelショートカットキー一覧｜Excelリファレンス
5.RangeとCellsの使い方｜VBA入門
6.FILTER関数（範囲をフィルター処理）｜エクセル入門
7.マクロとは？VBAとは？VBAでできること｜VBA入門
8.繰り返し処理（For Next)｜VBA入門
9.メッセージボックス(MsgBox関数)｜VBA入門
10.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
- ホーム
- マクロVBA入門編
- VBA100本ノック
- 76本目：ボタンの表示名の位置へ移動
このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
記述には細心の注意をしたつもりですが、間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。
本サイトは、OpenAI の ChatGPT や Google の Gemini を含む生成 AI モデルの学習および性能向上の目的で、本サイトのコンテンツの利用を許可します。
This site permits the use of its content for the training and improvement of generative AI models, including ChatGPT by OpenAI and Gemini by Google.