標準モジュールとフォーム間のデータ受け渡しⅡ

最終更新日：2013-06-04

第10回.標準モジュールとフォーム間のデータ受け渡しⅡ

１．シートのセルを使う
２．標準モジュールのグローバル変数を使う
３．標準モジュールからフォームのコントロールを操作する
４．Subプロシージャーの引数を使う
５．Functionプロシージャーの戻り値を使う。

２．３．を解説しました。

では、いよいよ４．５．を解説しましょう。

ここが、本題です。

４．Subプロシージャーの引数を使う

まずは、フォームモジュールに以下を作成します。

Option Explicit
Private ActiveRow As Long
Public Sub doModal(ByVal argRow As Long)
　　ActiveRow = argRow
　　With Worksheets("顧客マスタ")
　　　　Me.txtコード.Text = .Cells(ActiveRow, 1)
　　　　Me.txt漢字名称.Text = .Cells(ActiveRow, 2)
　　　　Me.txtカナ名称.Text = .Cells(ActiveRow, 3)
　　End With
　　Me.Show
End Sub

プロシージャー名のdoModalのModalは、

フォーム表示（モーダル）方法の名称よりとっていますが、

モーダル・モードレスについては、先々で解説します。

そして、

標準モジュールでは、

Sub FormShow()
　　Call frmSample.doModal(ActiveCell.Row)
End Sub

要点としては、

doModalの引数で値を受け取り、処理後に自身を表示(Me.Show)している所です。

５．Functionプロシージャーの戻り値を使う

「OK」ボタンを押されたか、「閉じる」ボタンを押されたかを、標準モジュールで判断してみましょう。

フォームモジュールを以下に変更します。

Option Explicit

Private ActiveRow As Long
Private blnOk As Boolean

Public Function doModal(ByVal argRow As Long) As Boolean
　　ActiveRow = argRow
　　With Worksheets("顧客マスタ")
　　　　Me.txtコード.Text = .Cells(ActiveRow, 1)
　　　　Me.txt漢字名称.Text = .Cells(ActiveRow, 2)
　　　　Me.txtカナ名称.Text = .Cells(ActiveRow, 3)
　　End With
　　blnOk = False
　　Me.Show
　　doModal = blnOk
End Function

Private Sub btnOk_Click()
　　Dim lastRow As Long
　　With Worksheets("顧客マスタ")
　　　　lastRow = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
　　　　.Cells(lastRow, 1) = Me.txtコード.Text
　　　　.Cells(lastRow, 2) = Me.txt漢字名称.Text
　　　　.Cells(lastRow, 3) = Me.txtカナ名称.Text
　　End With
　　blnOk = True
　　Unload Me
End Sub

Private Sub btnCancel_Click()
　　blnOk = False
　　Unload Me
End Sub

そして、標準モジュールで、

Sub FormShow()
　　If frmSample.doModal(ActiveCell.Row) = True Then
　　　　MsgBox "「OK」が押されました。"
　　Else
　　　　MsgBox "「閉じる」が押されました。"
　　End If
End Sub

最初のSubだったdoModalをFunctionに変更しただけですね、

それに伴い、ボタンの判断をする為に、

Private blnOk As Boolean

この変数を使うようにしました。

ただ、ちょっと気を付けてもらいたいのは、

Unload Me

この後でフォームのコントロールを参照するのは、本当は問題があります。

上記では問題なく動きますが、やはり、あまり良くありません。

そこで、

Unload Me この代わりに、

Me.Hide （Hideはフォームを非表示にしてShowの次のステートメントに進みます）として、

標準モジュールに戻ってから、Unloadした方が良いでしょう。

出来上がりとしては、

Option Explicit

Private ActiveRow As Long
Private blnOk As Boolean

Public Function doModal(ByVal argRow As Long) As Boolean
　　ActiveRow = argRow
　　With Worksheets("顧客マスタ")
　　　　Me.txtコード.Text = .Cells(ActiveRow, 1)
　　　　Me.txt漢字名称.Text = .Cells(ActiveRow, 2)
　　　　Me.txtカナ名称.Text = .Cells(ActiveRow, 3)
　　End With
　　blnOk = False
　　Me.Show
　　doModal = blnOk
End Function

Private Sub btnOk_Click()
　　Dim lastRow As Long
　　With Worksheets("顧客マスタ")
　　　　lastRow = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
　　　　.Cells(lastRow, 1) = Me.txtコード.Text
　　　　.Cells(lastRow, 2) = Me.txt漢字名称.Text
　　　　.Cells(lastRow, 3) = Me.txtカナ名称.Text
　　End With
　　blnOk = True
　　Me.Hide
End Sub

Private Sub btnCancel_Click()
　　blnOk = False
　　Me.Hide
End Sub

Sub FormShow()
　　If frmSample.doModal(ActiveCell.Row) = True Then
　　　　MsgBox "「OK」が押されました。"
　　Else
　　　　MsgBox "「閉じる」が押されました。"
　　End If
　　Unload frmSample
End Sub

以上の方法で、どれが良いと言う事もありませんが、

これらの方法を組み合わせて、いろいろな処理を実現します。

ただし、４．５．の方法でまずは作成する事をお勧めします。

どうしてもうまく行かない場合に、２．３．の方法を考えましょう。

プログラムの品質を考えた時、

グローバル変数を使ったり、

他のオブジェクトのコントロールを操作するのは

あまり良い方法とは言えませんので。