VBA練習問題
VBA100本ノック 94本目:表範囲からHTMLのtableタグを作成

VBAを100本の練習問題で鍛えます
最終更新日:2021-02-24

VBA100本ノック 94本目:表範囲からHTMLのtableタグを作成


指定セル範囲の表をHTMLの<table>に変換するFunctionを作成する問題です。


ツイッター連動企画です。
ツイートでの見やすさを考慮して、ブック・シート指定等を適宜省略しています。

VBAテスト用のサンプルデータは、VBA100本ノックの目次ページ からもダウンロードできます。
マクロVBAを初心者向けの基本から上級者向けの高度な内容までサンプルコードを掲載し解説しています。エクセル関数・機能・基本操作の入門解説からマクロVBAまでエクセル全般を網羅しています。


出題

出題ツイートへのリンク

#VBA100本ノック 94本目
表をHTMLの<table>に変換するFunctionを作成。
引数(セル範囲,見出行数)でHTMLで返す。
見出行数:>=1は指定行数を<thead>で出力。
セル結合:<td colspan="2" rowspan="2">等々
空白セル:"&nbsp;"を出力
※出力サンプルを参考に
※文字位置は不要、インデントは任意

マクロ VBA 100本ノック

マクロ VBA 100本ノック


サンプルファイルです。
https://excel-ubara.com/vba100sample/VBA100_94.xlsm
https://excel-ubara.com/vba100sample/VBA100_94.zip

マクロ VBA 100本ノック

マクロ VBA 100本ノック


VBA作成タイム

この下に頂いた回答へのリンクと解説を掲載しています。
途中まででも良いので、できるだけ自分でVBAを書いてみましょう。


他の人の回答および解説を見て、書いたVBAを見直してみましょう。


頂いた回答

解説

セル結合は今まで何問か出ているので扱いは問題ないと思います。
セル結合の先頭セルで結合範囲を判定してrowspan、colspanを指定し、結合された他のセルはスキップする部分で工夫が必要になります。
ここだけ意識してVBAを書けは他は流れに沿って記述すれば完成すると思います。

Function VBA100_94_01(ByVal aRng As Range, Optional ByVal aHeader As Long = 0)
  Dim sHtml As String, thtd As String
  Dim i As Long, j As Long, mRow As Long, mCol As Long
  
  sHtml = Concat("<table border=""1"">", vbCrLf)
  sHtml = Concat(sHtml, Indent(1), IIf(aHeader > 0, "<thead>", "<tbody>"), vbCrLf)
  thtd = IIf(aHeader > 0, "th", "td")
  
  For i = 1 To aRng.Rows.Count
    sHtml = Concat(sHtml, Indent(2), "<tr>", vbCrLf)
    For j = 1 To aRng.Columns.Count
      If aRng.Cells(i, j).Address = aRng.Cells(i, j).MergeArea(1).Address Then
        mRow = aRng.Cells(i, j).MergeArea.Rows.Count
        mCol = aRng.Cells(i, j).MergeArea.Columns.Count
        
        sHtml = Concat(sHtml, Indent(3), "<", thtd)
        If mRow > 1 Then sHtml = Concat(sHtml, " rowspan=""", mRow, """")
        If mCol > 1 Then sHtml = Concat(sHtml, " colspan=""", mCol, """")
        sHtml = Concat(sHtml, ">")
        
        sHtml = Concat(sHtml, IIf(aRng.Cells(i, j).Value = "", "&nbsp;", aRng.Cells(i, j).Value))
        sHtml = Concat(sHtml, "</", thtd, ">", vbCrLf)
      End If
    Next
    sHtml = Concat(sHtml, Indent(2), "</tr>", vbCrLf)
    
    If i = aHeader Then
      sHtml = Concat(sHtml, Indent(1), "</thead>", vbCrLf)
      sHtml = Concat(sHtml, Indent(1), "<tbody>", vbCrLf)
      thtd = "td"
    End If
  Next
  
  sHtml = Concat(sHtml, Indent(1), "</tbody>", vbCrLf)
  sHtml = Concat(sHtml, "</table>")
  VBA100_94_01 = sHtml
End Function

Function Concat(ParamArray prm()) As String
  Dim v
  For Each v In prm
    Concat = Concat & v
  Next
End Function

Function Indent(ByVal aNum As Long) As String
  Indent = Space(4 * aNum)
End Function


HTML文字列作成部分が見た的にうっとうしかったので、ConcatとIndentを作成してみました。
今回も復習を兼ねた総合練習問題になります。
補足はありません。
記事にはVBAコードを掲載しました。


補足

補足はありません。


サイト内関連ページ

11本目:セル結合の警告
セル結合されているセルにコメントで警告文を出す問題です。ツイッター連動企画です。ツイートでの見やすさを考慮して、ブック・シート指定等を適宜省略しています。VBAテスト用のサンプルデータは、VBA100本ノックの目次ページからもダウンロードできます。
12本目:セル結合の解除
セル結合されているセルの結合を解除して、入っていた数値を均等に割り振る問題です。ツイッター連動企画です。ツイートでの見やすさを考慮して、ブック・シート指定等を適宜省略しています。VBAテスト用のサンプルデータは、VBA100本ノックの目次ページからもダウンロードできます。
25本目:マトリックス表をDB形式に変換
縦横のマトリックス表をデータベース形式の縦に展開する問題です。ツイッター連動企画です。ツイートでの見やすさを考慮して、ブック・シート指定等を適宜省略しています。VBAテスト用のサンプルデータは、VBA100本ノックの目次ページからもダウンロードできます。




同じテーマ「VBA100本ノック」の記事

91本目:時間計算(残業時間の月間合計)
92本目:セルの色を16進で返す関数
93本目:複数ブックを連結して再分割
94本目:表範囲からHTMLのtableタグを作成
95本目:図形のテキストを検索するフォーム作成
96本目:Accessデータを取得(マスタ結合&抽出)
97本目:Accessデータを取得(グループ集計)
98本目:席替えルールが守られているか確認
99本目:自動席替え(行列と前後左右が全て違うように)
100本目:WEBから100本ノックのリストを取得
魔球編:組み合わせ問題


新着記事NEW ・・・新着記事一覧を見る

還暦のVBA:VBAまでたどりつけるか… (2021-09-29)
VLOOKUPを使うことを基本としてシートを設計すべきか|エクセル雑感(2021-08-17)
コンピューターはブラックボックスで良い|エクセル雑感(2021-08-14)
小文字"abc"を大文字"ABC"に変換する方法|エクセル雑感(2021-08-13)
ADOでテキストデータを集計する|VBAサンプル集(2021-08-04)
VBA学習のお勧めコース|エクセル雑感(2021-08-01)
エクセル馬名ダービー|エクセル雑感(2021-07-21)
在庫を減らせ!毎日棚卸ししろ!|エクセル雑感(2021-07-05)
日付型と通貨型のValueとValue2について|エクセル雑感(2021-06-26)
DXってなんだ? ITと何が違うの?|エクセル雑感(2021-06-24)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.Excelショートカットキー一覧|Excelリファレンス
3.変数宣言のDimとデータ型|VBA入門
4.RangeとCellsの使い方|VBA入門
5.繰り返し処理(For Next)|VBA入門
6.マクロって何?VBAって何?|VBA入門
7.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
8.Range以外の指定方法(Cells,Rows,Columns)|VBA入門
9.セルに文字を入れるとは(Range,Value)|VBA入門
10.並べ替え(Sort)|VBA入門




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。



このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
本文下部へ